Pileus Git - ~andy/linux/blob - arch/x86/tools/distill.awk

   1 #!/bin/awk -f
   2 # Usage: objdump -d a.out | awk -f distill.awk | ./test_get_len
   3 # Distills the disassembly as follows:
   4 # - Removes all lines except the disassembled instructions.
   5 # - For instructions that exceed 1 line (7 bytes), crams all the hex bytes
   6 # into a single line.
   7 # - Remove bad(or prefix only) instructions
   8
   9 BEGIN {
  10         prev_addr = ""
  11         prev_hex = ""
  12         prev_mnemonic = ""
  13         bad_expr = "(\\(bad\\)|^rex|^.byte|^rep(z|nz)$|^lock$|^es$|^cs$|^ss$|^ds$|^fs$|^gs$|^data(16|32)$|^addr(16|32|64))"
  14         fwait_expr = "^9b "
  15         fwait_str="9b\tfwait"
  16 }
  17
  18 /^ *[0-9a-f]+:/ {
  19         if (split($0, field, "\t") < 3) {
  20                 # This is a continuation of the same insn.
  21                 prev_hex = prev_hex field[2]
  22         } else {
  23                 # Skip bad instructions
  24                 if (match(prev_mnemonic, bad_expr))
  25                         prev_addr = ""
  26                 # Split fwait from other f* instructions
  27                 if (match(prev_hex, fwait_expr) && prev_mnemonic != "fwait") {
  28                         printf "%s\t%s\n", prev_addr, fwait_str
  29                         sub(fwait_expr, "", prev_hex)
  30                 }
  31                 if (prev_addr != "")
  32                         printf "%s\t%s\t%s\n", prev_addr, prev_hex, prev_mnemonic
  33                 prev_addr = field[1]
  34                 prev_hex = field[2]
  35                 prev_mnemonic = field[3]
  36         }
  37 }
  38
  39 END {
  40         if (prev_addr != "")
  41                 printf "%s\t%s\t%s\n", prev_addr, prev_hex, prev_mnemonic
  42 }