Pileus Git - ~andy/linux/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/rcu.h>
  60 #include <asm/smap.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72 #ifdef CONFIG_FUNCTION_TRACER
  73
  74 #ifdef CC_USING_FENTRY
  75 # define function_hook  __fentry__
  76 #else
  77 # define function_hook  mcount
  78 #endif
  79
  80 #ifdef CONFIG_DYNAMIC_FTRACE
  81
  82 ENTRY(function_hook)
  83         retq
  84 END(function_hook)
  85
  86 /* skip is set if stack has been adjusted */
  87 .macro ftrace_caller_setup skip=0
  88         MCOUNT_SAVE_FRAME \skip
  89
  90         /* Load the ftrace_ops into the 3rd parameter */
  91         leaq function_trace_op, %rdx
  92
  93         /* Load ip into the first parameter */
  94         movq RIP(%rsp), %rdi
  95         subq $MCOUNT_INSN_SIZE, %rdi
  96         /* Load the parent_ip into the second parameter */
  97 #ifdef CC_USING_FENTRY
  98         movq SS+16(%rsp), %rsi
  99 #else
 100         movq 8(%rbp), %rsi
 101 #endif
 102 .endm
 103
 104 ENTRY(ftrace_caller)
 105         /* Check if tracing was disabled (quick check) */
 106         cmpl $0, function_trace_stop
 107         jne  ftrace_stub
 108
 109         ftrace_caller_setup
 110         /* regs go into 4th parameter (but make it NULL) */
 111         movq $0, %rcx
 112
 113 GLOBAL(ftrace_call)
 114         call ftrace_stub
 115
 116         MCOUNT_RESTORE_FRAME
 117 ftrace_return:
 118
 119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 120 GLOBAL(ftrace_graph_call)
 121         jmp ftrace_stub
 122 #endif
 123
 124 GLOBAL(ftrace_stub)
 125         retq
 126 END(ftrace_caller)
 127
 128 ENTRY(ftrace_regs_caller)
 129         /* Save the current flags before compare (in SS location)*/
 130         pushfq
 131
 132         /* Check if tracing was disabled (quick check) */
 133         cmpl $0, function_trace_stop
 134         jne  ftrace_restore_flags
 135
 136         /* skip=8 to skip flags saved in SS */
 137         ftrace_caller_setup 8
 138
 139         /* Save the rest of pt_regs */
 140         movq %r15, R15(%rsp)
 141         movq %r14, R14(%rsp)
 142         movq %r13, R13(%rsp)
 143         movq %r12, R12(%rsp)
 144         movq %r11, R11(%rsp)
 145         movq %r10, R10(%rsp)
 146         movq %rbp, RBP(%rsp)
 147         movq %rbx, RBX(%rsp)
 148         /* Copy saved flags */
 149         movq SS(%rsp), %rcx
 150         movq %rcx, EFLAGS(%rsp)
 151         /* Kernel segments */
 152         movq $__KERNEL_DS, %rcx
 153         movq %rcx, SS(%rsp)
 154         movq $__KERNEL_CS, %rcx
 155         movq %rcx, CS(%rsp)
 156         /* Stack - skipping return address */
 157         leaq SS+16(%rsp), %rcx
 158         movq %rcx, RSP(%rsp)
 159
 160         /* regs go into 4th parameter */
 161         leaq (%rsp), %rcx
 162
 163 GLOBAL(ftrace_regs_call)
 164         call ftrace_stub
 165
 166         /* Copy flags back to SS, to restore them */
 167         movq EFLAGS(%rsp), %rax
 168         movq %rax, SS(%rsp)
 169
 170         /* Handlers can change the RIP */
 171         movq RIP(%rsp), %rax
 172         movq %rax, SS+8(%rsp)
 173
 174         /* restore the rest of pt_regs */
 175         movq R15(%rsp), %r15
 176         movq R14(%rsp), %r14
 177         movq R13(%rsp), %r13
 178         movq R12(%rsp), %r12
 179         movq R10(%rsp), %r10
 180         movq RBP(%rsp), %rbp
 181         movq RBX(%rsp), %rbx
 182
 183         /* skip=8 to skip flags saved in SS */
 184         MCOUNT_RESTORE_FRAME 8
 185
 186         /* Restore flags */
 187         popfq
 188
 189         jmp ftrace_return
 190 ftrace_restore_flags:
 191         popfq
 192         jmp  ftrace_stub
 193
 194 END(ftrace_regs_caller)
 195
 196
 197 #else /* ! CONFIG_DYNAMIC_FTRACE */
 198
 199 ENTRY(function_hook)
 200         cmpl $0, function_trace_stop
 201         jne  ftrace_stub
 202
 203         cmpq $ftrace_stub, ftrace_trace_function
 204         jnz trace
 205
 206 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 207         cmpq $ftrace_stub, ftrace_graph_return
 208         jnz ftrace_graph_caller
 209
 210         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 211         jnz ftrace_graph_caller
 212 #endif
 213
 214 GLOBAL(ftrace_stub)
 215         retq
 216
 217 trace:
 218         MCOUNT_SAVE_FRAME
 219
 220         movq RIP(%rsp), %rdi
 221 #ifdef CC_USING_FENTRY
 222         movq SS+16(%rsp), %rsi
 223 #else
 224         movq 8(%rbp), %rsi
 225 #endif
 226         subq $MCOUNT_INSN_SIZE, %rdi
 227
 228         call   *ftrace_trace_function
 229
 230         MCOUNT_RESTORE_FRAME
 231
 232         jmp ftrace_stub
 233 END(function_hook)
 234 #endif /* CONFIG_DYNAMIC_FTRACE */
 235 #endif /* CONFIG_FUNCTION_TRACER */
 236
 237 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 238 ENTRY(ftrace_graph_caller)
 239         MCOUNT_SAVE_FRAME
 240
 241 #ifdef CC_USING_FENTRY
 242         leaq SS+16(%rsp), %rdi
 243         movq $0, %rdx   /* No framepointers needed */
 244 #else
 245         leaq 8(%rbp), %rdi
 246         movq (%rbp), %rdx
 247 #endif
 248         movq RIP(%rsp), %rsi
 249         subq $MCOUNT_INSN_SIZE, %rsi
 250
 251         call    prepare_ftrace_return
 252
 253         MCOUNT_RESTORE_FRAME
 254
 255         retq
 256 END(ftrace_graph_caller)
 257
 258 GLOBAL(return_to_handler)
 259         subq  $24, %rsp
 260
 261         /* Save the return values */
 262         movq %rax, (%rsp)
 263         movq %rdx, 8(%rsp)
 264         movq %rbp, %rdi
 265
 266         call ftrace_return_to_handler
 267
 268         movq %rax, %rdi
 269         movq 8(%rsp), %rdx
 270         movq (%rsp), %rax
 271         addq $24, %rsp
 272         jmp *%rdi
 273 #endif
 274
 275
 276 #ifndef CONFIG_PREEMPT
 277 #define retint_kernel retint_restore_args
 278 #endif
 279
 280 #ifdef CONFIG_PARAVIRT
 281 ENTRY(native_usergs_sysret64)
 282         swapgs
 283         sysretq
 284 ENDPROC(native_usergs_sysret64)
 285 #endif /* CONFIG_PARAVIRT */
 286
 287
 288 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 289 #ifdef CONFIG_TRACE_IRQFLAGS
 290         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 291         jnc  1f
 292         TRACE_IRQS_ON
 293 1:
 294 #endif
 295 .endm
 296
 297 /*
 298  * When dynamic function tracer is enabled it will add a breakpoint
 299  * to all locations that it is about to modify, sync CPUs, update
 300  * all the code, sync CPUs, then remove the breakpoints. In this time
 301  * if lockdep is enabled, it might jump back into the debug handler
 302  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 303  *
 304  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 305  * make sure the stack pointer does not get reset back to the top
 306  * of the debug stack, and instead just reuses the current stack.
 307  */
 308 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 309
 310 .macro TRACE_IRQS_OFF_DEBUG
 311         call debug_stack_set_zero
 312         TRACE_IRQS_OFF
 313         call debug_stack_reset
 314 .endm
 315
 316 .macro TRACE_IRQS_ON_DEBUG
 317         call debug_stack_set_zero
 318         TRACE_IRQS_ON
 319         call debug_stack_reset
 320 .endm
 321
 322 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 323         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 324         jnc  1f
 325         TRACE_IRQS_ON_DEBUG
 326 1:
 327 .endm
 328
 329 #else
 330 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 331 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 332 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 333 #endif
 334
 335 /*
 336  * C code is not supposed to know about undefined top of stack. Every time
 337  * a C function with an pt_regs argument is called from the SYSCALL based
 338  * fast path FIXUP_TOP_OF_STACK is needed.
 339  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 340  * manipulation.
 341  */
 342
 343         /* %rsp:at FRAMEEND */
 344         .macro FIXUP_TOP_OF_STACK tmp offset=0
 345         movq PER_CPU_VAR(old_rsp),\tmp
 346         movq \tmp,RSP+\offset(%rsp)
 347         movq $__USER_DS,SS+\offset(%rsp)
 348         movq $__USER_CS,CS+\offset(%rsp)
 349         movq $-1,RCX+\offset(%rsp)
 350         movq R11+\offset(%rsp),\tmp  /* get eflags */
 351         movq \tmp,EFLAGS+\offset(%rsp)
 352         .endm
 353
 354         .macro RESTORE_TOP_OF_STACK tmp offset=0
 355         movq RSP+\offset(%rsp),\tmp
 356         movq \tmp,PER_CPU_VAR(old_rsp)
 357         movq EFLAGS+\offset(%rsp),\tmp
 358         movq \tmp,R11+\offset(%rsp)
 359         .endm
 360
 361         .macro FAKE_STACK_FRAME child_rip
 362         /* push in order ss, rsp, eflags, cs, rip */
 363         xorl %eax, %eax
 364         pushq_cfi $__KERNEL_DS /* ss */
 365         /*CFI_REL_OFFSET        ss,0*/
 366         pushq_cfi %rax /* rsp */
 367         CFI_REL_OFFSET  rsp,0
 368         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 369         /*CFI_REL_OFFSET        rflags,0*/
 370         pushq_cfi $__KERNEL_CS /* cs */
 371         /*CFI_REL_OFFSET        cs,0*/
 372         pushq_cfi \child_rip /* rip */
 373         CFI_REL_OFFSET  rip,0
 374         pushq_cfi %rax /* orig rax */
 375         .endm
 376
 377         .macro UNFAKE_STACK_FRAME
 378         addq $8*6, %rsp
 379         CFI_ADJUST_CFA_OFFSET   -(6*8)
 380         .endm
 381
 382 /*
 383  * initial frame state for interrupts (and exceptions without error code)
 384  */
 385         .macro EMPTY_FRAME start=1 offset=0
 386         .if \start
 387         CFI_STARTPROC simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA rsp,8+\offset
 390         .else
 391         CFI_DEF_CFA_OFFSET 8+\offset
 392         .endif
 393         .endm
 394
 395 /*
 396  * initial frame state for interrupts (and exceptions without error code)
 397  */
 398         .macro INTR_FRAME start=1 offset=0
 399         EMPTY_FRAME \start, SS+8+\offset-RIP
 400         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 401         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 402         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 403         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 404         CFI_REL_OFFSET rip, RIP+\offset-RIP
 405         .endm
 406
 407 /*
 408  * initial frame state for exceptions with error code (and interrupts
 409  * with vector already pushed)
 410  */
 411         .macro XCPT_FRAME start=1 offset=0
 412         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 413         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 414         .endm
 415
 416 /*
 417  * frame that enables calling into C.
 418  */
 419         .macro PARTIAL_FRAME start=1 offset=0
 420         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 421         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 430         .endm
 431
 432 /*
 433  * frame that enables passing a complete pt_regs to a C function.
 434  */
 435         .macro DEFAULT_FRAME start=1 offset=0
 436         PARTIAL_FRAME \start, R11+\offset-R15
 437         CFI_REL_OFFSET rbx, RBX+\offset
 438         CFI_REL_OFFSET rbp, RBP+\offset
 439         CFI_REL_OFFSET r12, R12+\offset
 440         CFI_REL_OFFSET r13, R13+\offset
 441         CFI_REL_OFFSET r14, R14+\offset
 442         CFI_REL_OFFSET r15, R15+\offset
 443         .endm
 444
 445 /* save partial stack frame */
 446         .macro SAVE_ARGS_IRQ
 447         cld
 448         /* start from rbp in pt_regs and jump over */
 449         movq_cfi rdi, (RDI-RBP)
 450         movq_cfi rsi, (RSI-RBP)
 451         movq_cfi rdx, (RDX-RBP)
 452         movq_cfi rcx, (RCX-RBP)
 453         movq_cfi rax, (RAX-RBP)
 454         movq_cfi  r8,  (R8-RBP)
 455         movq_cfi  r9,  (R9-RBP)
 456         movq_cfi r10, (R10-RBP)
 457         movq_cfi r11, (R11-RBP)
 458
 459         /* Save rbp so that we can unwind from get_irq_regs() */
 460         movq_cfi rbp, 0
 461
 462         /* Save previous stack value */
 463         movq %rsp, %rsi
 464
 465         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 466         testl $3, CS-RBP(%rsi)
 467         je 1f
 468         SWAPGS
 469         /*
 470          * irq_count is used to check if a CPU is already on an interrupt stack
 471          * or not. While this is essentially redundant with preempt_count it is
 472          * a little cheaper to use a separate counter in the PDA (short of
 473          * moving irq_enter into assembly, which would be too much work)
 474          */
 475 1:      incl PER_CPU_VAR(irq_count)
 476         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 477         CFI_DEF_CFA_REGISTER    rsi
 478
 479         /* Store previous stack value */
 480         pushq %rsi
 481         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 482                         0x77 /* DW_OP_breg7 */, 0, \
 483                         0x06 /* DW_OP_deref */, \
 484                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 485                         0x22 /* DW_OP_plus */
 486         /* We entered an interrupt context - irqs are off: */
 487         TRACE_IRQS_OFF
 488         .endm
 489
 490 ENTRY(save_rest)
 491         PARTIAL_FRAME 1 (REST_SKIP+8)
 492         movq 5*8+16(%rsp), %r11 /* save return address */
 493         movq_cfi rbx, RBX+16
 494         movq_cfi rbp, RBP+16
 495         movq_cfi r12, R12+16
 496         movq_cfi r13, R13+16
 497         movq_cfi r14, R14+16
 498         movq_cfi r15, R15+16
 499         movq %r11, 8(%rsp)      /* return address */
 500         FIXUP_TOP_OF_STACK %r11, 16
 501         ret
 502         CFI_ENDPROC
 503 END(save_rest)
 504
 505 /* save complete stack frame */
 506         .pushsection .kprobes.text, "ax"
 507 ENTRY(save_paranoid)
 508         XCPT_FRAME 1 RDI+8
 509         cld
 510         movq_cfi rdi, RDI+8
 511         movq_cfi rsi, RSI+8
 512         movq_cfi rdx, RDX+8
 513         movq_cfi rcx, RCX+8
 514         movq_cfi rax, RAX+8
 515         movq_cfi r8, R8+8
 516         movq_cfi r9, R9+8
 517         movq_cfi r10, R10+8
 518         movq_cfi r11, R11+8
 519         movq_cfi rbx, RBX+8
 520         movq_cfi rbp, RBP+8
 521         movq_cfi r12, R12+8
 522         movq_cfi r13, R13+8
 523         movq_cfi r14, R14+8
 524         movq_cfi r15, R15+8
 525         movl $1,%ebx
 526         movl $MSR_GS_BASE,%ecx
 527         rdmsr
 528         testl %edx,%edx
 529         js 1f   /* negative -> in kernel */
 530         SWAPGS
 531         xorl %ebx,%ebx
 532 1:      ret
 533         CFI_ENDPROC
 534 END(save_paranoid)
 535         .popsection
 536
 537 /*
 538  * A newly forked process directly context switches into this address.
 539  *
 540  * rdi: prev task we switched from
 541  */
 542 ENTRY(ret_from_fork)
 543         DEFAULT_FRAME
 544
 545         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 546
 547         pushq_cfi $0x0002
 548         popfq_cfi                               # reset kernel eflags
 549
 550         call schedule_tail                      # rdi: 'prev' task parameter
 551
 552         GET_THREAD_INFO(%rcx)
 553
 554         RESTORE_REST
 555
 556         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 557         jz   1f
 558
 559         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 560         jnz  int_ret_from_sys_call
 561
 562         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 563         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 564
 565 1:
 566         subq $REST_SKIP, %rsp   # move the stack pointer back
 567         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 568         movq %rbp, %rdi
 569         call *%rbx
 570         # exit
 571         mov %eax, %edi
 572         call do_exit
 573         ud2                     # padding for call trace
 574
 575         CFI_ENDPROC
 576 END(ret_from_fork)
 577
 578 /*
 579  * System call entry. Up to 6 arguments in registers are supported.
 580  *
 581  * SYSCALL does not save anything on the stack and does not change the
 582  * stack pointer.  However, it does mask the flags register for us, so
 583  * CLD and CLAC are not needed.
 584  */
 585
 586 /*
 587  * Register setup:
 588  * rax  system call number
 589  * rdi  arg0
 590  * rcx  return address for syscall/sysret, C arg3
 591  * rsi  arg1
 592  * rdx  arg2
 593  * r10  arg3    (--> moved to rcx for C)
 594  * r8   arg4
 595  * r9   arg5
 596  * r11  eflags for syscall/sysret, temporary for C
 597  * r12-r15,rbp,rbx saved by C code, not touched.
 598  *
 599  * Interrupts are off on entry.
 600  * Only called from user space.
 601  *
 602  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 603  *      and report it properly in ps. Unfortunately we haven't.
 604  *
 605  * When user can change the frames always force IRET. That is because
 606  * it deals with uncanonical addresses better. SYSRET has trouble
 607  * with them due to bugs in both AMD and Intel CPUs.
 608  */
 609
 610 ENTRY(system_call)
 611         CFI_STARTPROC   simple
 612         CFI_SIGNAL_FRAME
 613         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 614         CFI_REGISTER    rip,rcx
 615         /*CFI_REGISTER  rflags,r11*/
 616         SWAPGS_UNSAFE_STACK
 617         /*
 618          * A hypervisor implementation might want to use a label
 619          * after the swapgs, so that it can do the swapgs
 620          * for the guest and jump here on syscall.
 621          */
 622 GLOBAL(system_call_after_swapgs)
 623
 624         movq    %rsp,PER_CPU_VAR(old_rsp)
 625         movq    PER_CPU_VAR(kernel_stack),%rsp
 626         /*
 627          * No need to follow this irqs off/on section - it's straight
 628          * and short:
 629          */
 630         ENABLE_INTERRUPTS(CLBR_NONE)
 631         SAVE_ARGS 8,0
 632         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 633         movq  %rcx,RIP-ARGOFFSET(%rsp)
 634         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 635         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 636         jnz tracesys
 637 system_call_fastpath:
 638 #if __SYSCALL_MASK == ~0
 639         cmpq $__NR_syscall_max,%rax
 640 #else
 641         andl $__SYSCALL_MASK,%eax
 642         cmpl $__NR_syscall_max,%eax
 643 #endif
 644         ja badsys
 645         movq %r10,%rcx
 646         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 647         movq %rax,RAX-ARGOFFSET(%rsp)
 648 /*
 649  * Syscall return path ending with SYSRET (fast path)
 650  * Has incomplete stack frame and undefined top of stack.
 651  */
 652 ret_from_sys_call:
 653         movl $_TIF_ALLWORK_MASK,%edi
 654         /* edi: flagmask */
 655 sysret_check:
 656         LOCKDEP_SYS_EXIT
 657         DISABLE_INTERRUPTS(CLBR_NONE)
 658         TRACE_IRQS_OFF
 659         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 660         andl %edi,%edx
 661         jnz  sysret_careful
 662         CFI_REMEMBER_STATE
 663         /*
 664          * sysretq will re-enable interrupts:
 665          */
 666         TRACE_IRQS_ON
 667         movq RIP-ARGOFFSET(%rsp),%rcx
 668         CFI_REGISTER    rip,rcx
 669         RESTORE_ARGS 1,-ARG_SKIP,0
 670         /*CFI_REGISTER  rflags,r11*/
 671         movq    PER_CPU_VAR(old_rsp), %rsp
 672         USERGS_SYSRET64
 673
 674         CFI_RESTORE_STATE
 675         /* Handle reschedules */
 676         /* edx: work, edi: workmask */
 677 sysret_careful:
 678         bt $TIF_NEED_RESCHED,%edx
 679         jnc sysret_signal
 680         TRACE_IRQS_ON
 681         ENABLE_INTERRUPTS(CLBR_NONE)
 682         pushq_cfi %rdi
 683         SCHEDULE_USER
 684         popq_cfi %rdi
 685         jmp sysret_check
 686
 687         /* Handle a signal */
 688 sysret_signal:
 689         TRACE_IRQS_ON
 690         ENABLE_INTERRUPTS(CLBR_NONE)
 691 #ifdef CONFIG_AUDITSYSCALL
 692         bt $TIF_SYSCALL_AUDIT,%edx
 693         jc sysret_audit
 694 #endif
 695         /*
 696          * We have a signal, or exit tracing or single-step.
 697          * These all wind up with the iret return path anyway,
 698          * so just join that path right now.
 699          */
 700         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 701         jmp int_check_syscall_exit_work
 702
 703 badsys:
 704         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 705         jmp ret_from_sys_call
 706
 707 #ifdef CONFIG_AUDITSYSCALL
 708         /*
 709          * Fast path for syscall audit without full syscall trace.
 710          * We just call __audit_syscall_entry() directly, and then
 711          * jump back to the normal fast path.
 712          */
 713 auditsys:
 714         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 715         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 716         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 717         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 718         movq %rax,%rsi                  /* 2nd arg: syscall number */
 719         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 720         call __audit_syscall_entry
 721         LOAD_ARGS 0             /* reload call-clobbered registers */
 722         jmp system_call_fastpath
 723
 724         /*
 725          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 726          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 727          * masked off.
 728          */
 729 sysret_audit:
 730         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 731         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 732         setbe %al               /* 1 if so, 0 if not */
 733         movzbl %al,%edi         /* zero-extend that into %edi */
 734         call __audit_syscall_exit
 735         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 736         jmp sysret_check
 737 #endif  /* CONFIG_AUDITSYSCALL */
 738
 739         /* Do syscall tracing */
 740 tracesys:
 741 #ifdef CONFIG_AUDITSYSCALL
 742         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 743         jz auditsys
 744 #endif
 745         SAVE_REST
 746         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 747         FIXUP_TOP_OF_STACK %rdi
 748         movq %rsp,%rdi
 749         call syscall_trace_enter
 750         /*
 751          * Reload arg registers from stack in case ptrace changed them.
 752          * We don't reload %rax because syscall_trace_enter() returned
 753          * the value it wants us to use in the table lookup.
 754          */
 755         LOAD_ARGS ARGOFFSET, 1
 756         RESTORE_REST
 757 #if __SYSCALL_MASK == ~0
 758         cmpq $__NR_syscall_max,%rax
 759 #else
 760         andl $__SYSCALL_MASK,%eax
 761         cmpl $__NR_syscall_max,%eax
 762 #endif
 763         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 764         movq %r10,%rcx  /* fixup for C */
 765         call *sys_call_table(,%rax,8)
 766         movq %rax,RAX-ARGOFFSET(%rsp)
 767         /* Use IRET because user could have changed frame */
 768
 769 /*
 770  * Syscall return path ending with IRET.
 771  * Has correct top of stack, but partial stack frame.
 772  */
 773 GLOBAL(int_ret_from_sys_call)
 774         DISABLE_INTERRUPTS(CLBR_NONE)
 775         TRACE_IRQS_OFF
 776         movl $_TIF_ALLWORK_MASK,%edi
 777         /* edi: mask to check */
 778 GLOBAL(int_with_check)
 779         LOCKDEP_SYS_EXIT_IRQ
 780         GET_THREAD_INFO(%rcx)
 781         movl TI_flags(%rcx),%edx
 782         andl %edi,%edx
 783         jnz   int_careful
 784         andl    $~TS_COMPAT,TI_status(%rcx)
 785         jmp   retint_swapgs
 786
 787         /* Either reschedule or signal or syscall exit tracking needed. */
 788         /* First do a reschedule test. */
 789         /* edx: work, edi: workmask */
 790 int_careful:
 791         bt $TIF_NEED_RESCHED,%edx
 792         jnc  int_very_careful
 793         TRACE_IRQS_ON
 794         ENABLE_INTERRUPTS(CLBR_NONE)
 795         pushq_cfi %rdi
 796         SCHEDULE_USER
 797         popq_cfi %rdi
 798         DISABLE_INTERRUPTS(CLBR_NONE)
 799         TRACE_IRQS_OFF
 800         jmp int_with_check
 801
 802         /* handle signals and tracing -- both require a full stack frame */
 803 int_very_careful:
 804         TRACE_IRQS_ON
 805         ENABLE_INTERRUPTS(CLBR_NONE)
 806 int_check_syscall_exit_work:
 807         SAVE_REST
 808         /* Check for syscall exit trace */
 809         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 810         jz int_signal
 811         pushq_cfi %rdi
 812         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 813         call syscall_trace_leave
 814         popq_cfi %rdi
 815         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 816         jmp int_restore_rest
 817
 818 int_signal:
 819         testl $_TIF_DO_NOTIFY_MASK,%edx
 820         jz 1f
 821         movq %rsp,%rdi          # &ptregs -> arg1
 822         xorl %esi,%esi          # oldset -> arg2
 823         call do_notify_resume
 824 1:      movl $_TIF_WORK_MASK,%edi
 825 int_restore_rest:
 826         RESTORE_REST
 827         DISABLE_INTERRUPTS(CLBR_NONE)
 828         TRACE_IRQS_OFF
 829         jmp int_with_check
 830         CFI_ENDPROC
 831 END(system_call)
 832
 833 /*
 834  * Certain special system calls that need to save a complete full stack frame.
 835  */
 836         .macro PTREGSCALL label,func,arg
 837 ENTRY(\label)
 838         PARTIAL_FRAME 1 8               /* offset 8: return address */
 839         subq $REST_SKIP, %rsp
 840         CFI_ADJUST_CFA_OFFSET REST_SKIP
 841         call save_rest
 842         DEFAULT_FRAME 0 8               /* offset 8: return address */
 843         leaq 8(%rsp), \arg      /* pt_regs pointer */
 844         call \func
 845         jmp ptregscall_common
 846         CFI_ENDPROC
 847 END(\label)
 848         .endm
 849
 850         PTREGSCALL stub_clone, sys_clone, %r8
 851         PTREGSCALL stub_fork, sys_fork, %rdi
 852         PTREGSCALL stub_vfork, sys_vfork, %rdi
 853         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 854         PTREGSCALL stub_iopl, sys_iopl, %rsi
 855
 856 ENTRY(ptregscall_common)
 857         DEFAULT_FRAME 1 8       /* offset 8: return address */
 858         RESTORE_TOP_OF_STACK %r11, 8
 859         movq_cfi_restore R15+8, r15
 860         movq_cfi_restore R14+8, r14
 861         movq_cfi_restore R13+8, r13
 862         movq_cfi_restore R12+8, r12
 863         movq_cfi_restore RBP+8, rbp
 864         movq_cfi_restore RBX+8, rbx
 865         ret $REST_SKIP          /* pop extended registers */
 866         CFI_ENDPROC
 867 END(ptregscall_common)
 868
 869 ENTRY(stub_execve)
 870         CFI_STARTPROC
 871         addq $8, %rsp
 872         PARTIAL_FRAME 0
 873         SAVE_REST
 874         FIXUP_TOP_OF_STACK %r11
 875         call sys_execve
 876         RESTORE_TOP_OF_STACK %r11
 877         movq %rax,RAX(%rsp)
 878         RESTORE_REST
 879         jmp int_ret_from_sys_call
 880         CFI_ENDPROC
 881 END(stub_execve)
 882
 883 /*
 884  * sigreturn is special because it needs to restore all registers on return.
 885  * This cannot be done with SYSRET, so use the IRET return path instead.
 886  */
 887 ENTRY(stub_rt_sigreturn)
 888         CFI_STARTPROC
 889         addq $8, %rsp
 890         PARTIAL_FRAME 0
 891         SAVE_REST
 892         movq %rsp,%rdi
 893         FIXUP_TOP_OF_STACK %r11
 894         call sys_rt_sigreturn
 895         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 896         RESTORE_REST
 897         jmp int_ret_from_sys_call
 898         CFI_ENDPROC
 899 END(stub_rt_sigreturn)
 900
 901 #ifdef CONFIG_X86_X32_ABI
 902         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
 903
 904 ENTRY(stub_x32_rt_sigreturn)
 905         CFI_STARTPROC
 906         addq $8, %rsp
 907         PARTIAL_FRAME 0
 908         SAVE_REST
 909         movq %rsp,%rdi
 910         FIXUP_TOP_OF_STACK %r11
 911         call sys32_x32_rt_sigreturn
 912         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 913         RESTORE_REST
 914         jmp int_ret_from_sys_call
 915         CFI_ENDPROC
 916 END(stub_x32_rt_sigreturn)
 917
 918 ENTRY(stub_x32_execve)
 919         CFI_STARTPROC
 920         addq $8, %rsp
 921         PARTIAL_FRAME 0
 922         SAVE_REST
 923         FIXUP_TOP_OF_STACK %r11
 924         call compat_sys_execve
 925         RESTORE_TOP_OF_STACK %r11
 926         movq %rax,RAX(%rsp)
 927         RESTORE_REST
 928         jmp int_ret_from_sys_call
 929         CFI_ENDPROC
 930 END(stub_x32_execve)
 931
 932 #endif
 933
 934 /*
 935  * Build the entry stubs and pointer table with some assembler magic.
 936  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 937  * single cache line on all modern x86 implementations.
 938  */
 939         .section .init.rodata,"a"
 940 ENTRY(interrupt)
 941         .section .entry.text
 942         .p2align 5
 943         .p2align CONFIG_X86_L1_CACHE_SHIFT
 944 ENTRY(irq_entries_start)
 945         INTR_FRAME
 946 vector=FIRST_EXTERNAL_VECTOR
 947 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 948         .balign 32
 949   .rept 7
 950     .if vector < NR_VECTORS
 951       .if vector <> FIRST_EXTERNAL_VECTOR
 952         CFI_ADJUST_CFA_OFFSET -8
 953       .endif
 954 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 955       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 956         jmp 2f
 957       .endif
 958       .previous
 959         .quad 1b
 960       .section .entry.text
 961 vector=vector+1
 962     .endif
 963   .endr
 964 2:      jmp common_interrupt
 965 .endr
 966         CFI_ENDPROC
 967 END(irq_entries_start)
 968
 969 .previous
 970 END(interrupt)
 971 .previous
 972
 973 /*
 974  * Interrupt entry/exit.
 975  *
 976  * Interrupt entry points save only callee clobbered registers in fast path.
 977  *
 978  * Entry runs with interrupts off.
 979  */
 980
 981 /* 0(%rsp): ~(interrupt number) */
 982         .macro interrupt func
 983         /* reserve pt_regs for scratch regs and rbp */
 984         subq $ORIG_RAX-RBP, %rsp
 985         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 986         SAVE_ARGS_IRQ
 987         call \func
 988         .endm
 989
 990 /*
 991  * Interrupt entry/exit should be protected against kprobes
 992  */
 993         .pushsection .kprobes.text, "ax"
 994         /*
 995          * The interrupt stubs push (~vector+0x80) onto the stack and
 996          * then jump to common_interrupt.
 997          */
 998         .p2align CONFIG_X86_L1_CACHE_SHIFT
 999 common_interrupt:
1000         ASM_CLAC
1001         XCPT_FRAME
1002         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
1003         interrupt do_IRQ
1004         /* 0(%rsp): old_rsp-ARGOFFSET */
1005 ret_from_intr:
1006         DISABLE_INTERRUPTS(CLBR_NONE)
1007         TRACE_IRQS_OFF
1008         decl PER_CPU_VAR(irq_count)
1009
1010         /* Restore saved previous stack */
1011         popq %rsi
1012         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1013         leaq ARGOFFSET-RBP(%rsi), %rsp
1014         CFI_DEF_CFA_REGISTER    rsp
1015         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1016
1017 exit_intr:
1018         GET_THREAD_INFO(%rcx)
1019         testl $3,CS-ARGOFFSET(%rsp)
1020         je retint_kernel
1021
1022         /* Interrupt came from user space */
1023         /*
1024          * Has a correct top of stack, but a partial stack frame
1025          * %rcx: thread info. Interrupts off.
1026          */
1027 retint_with_reschedule:
1028         movl $_TIF_WORK_MASK,%edi
1029 retint_check:
1030         LOCKDEP_SYS_EXIT_IRQ
1031         movl TI_flags(%rcx),%edx
1032         andl %edi,%edx
1033         CFI_REMEMBER_STATE
1034         jnz  retint_careful
1035
1036 retint_swapgs:          /* return to user-space */
1037         /*
1038          * The iretq could re-enable interrupts:
1039          */
1040         DISABLE_INTERRUPTS(CLBR_ANY)
1041         TRACE_IRQS_IRETQ
1042         SWAPGS
1043         jmp restore_args
1044
1045 retint_restore_args:    /* return to kernel space */
1046         DISABLE_INTERRUPTS(CLBR_ANY)
1047         /*
1048          * The iretq could re-enable interrupts:
1049          */
1050         TRACE_IRQS_IRETQ
1051 restore_args:
1052         RESTORE_ARGS 1,8,1
1053
1054 irq_return:
1055         INTERRUPT_RETURN
1056         _ASM_EXTABLE(irq_return, bad_iret)
1057
1058 #ifdef CONFIG_PARAVIRT
1059 ENTRY(native_iret)
1060         iretq
1061         _ASM_EXTABLE(native_iret, bad_iret)
1062 #endif
1063
1064         .section .fixup,"ax"
1065 bad_iret:
1066         /*
1067          * The iret traps when the %cs or %ss being restored is bogus.
1068          * We've lost the original trap vector and error code.
1069          * #GPF is the most likely one to get for an invalid selector.
1070          * So pretend we completed the iret and took the #GPF in user mode.
1071          *
1072          * We are now running with the kernel GS after exception recovery.
1073          * But error_entry expects us to have user GS to match the user %cs,
1074          * so swap back.
1075          */
1076         pushq $0
1077
1078         SWAPGS
1079         jmp general_protection
1080
1081         .previous
1082
1083         /* edi: workmask, edx: work */
1084 retint_careful:
1085         CFI_RESTORE_STATE
1086         bt    $TIF_NEED_RESCHED,%edx
1087         jnc   retint_signal
1088         TRACE_IRQS_ON
1089         ENABLE_INTERRUPTS(CLBR_NONE)
1090         pushq_cfi %rdi
1091         SCHEDULE_USER
1092         popq_cfi %rdi
1093         GET_THREAD_INFO(%rcx)
1094         DISABLE_INTERRUPTS(CLBR_NONE)
1095         TRACE_IRQS_OFF
1096         jmp retint_check
1097
1098 retint_signal:
1099         testl $_TIF_DO_NOTIFY_MASK,%edx
1100         jz    retint_swapgs
1101         TRACE_IRQS_ON
1102         ENABLE_INTERRUPTS(CLBR_NONE)
1103         SAVE_REST
1104         movq $-1,ORIG_RAX(%rsp)
1105         xorl %esi,%esi          # oldset
1106         movq %rsp,%rdi          # &pt_regs
1107         call do_notify_resume
1108         RESTORE_REST
1109         DISABLE_INTERRUPTS(CLBR_NONE)
1110         TRACE_IRQS_OFF
1111         GET_THREAD_INFO(%rcx)
1112         jmp retint_with_reschedule
1113
1114 #ifdef CONFIG_PREEMPT
1115         /* Returning to kernel space. Check if we need preemption */
1116         /* rcx:  threadinfo. interrupts off. */
1117 ENTRY(retint_kernel)
1118         cmpl $0,TI_preempt_count(%rcx)
1119         jnz  retint_restore_args
1120         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1121         jnc  retint_restore_args
1122         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1123         jnc  retint_restore_args
1124         call preempt_schedule_irq
1125         jmp exit_intr
1126 #endif
1127
1128         CFI_ENDPROC
1129 END(common_interrupt)
1130 /*
1131  * End of kprobes section
1132  */
1133        .popsection
1134
1135 /*
1136  * APIC interrupts.
1137  */
1138 .macro apicinterrupt num sym do_sym
1139 ENTRY(\sym)
1140         ASM_CLAC
1141         INTR_FRAME
1142         pushq_cfi $~(\num)
1143 .Lcommon_\sym:
1144         interrupt \do_sym
1145         jmp ret_from_intr
1146         CFI_ENDPROC
1147 END(\sym)
1148 .endm
1149
1150 #ifdef CONFIG_SMP
1151 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1152         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1153 apicinterrupt REBOOT_VECTOR \
1154         reboot_interrupt smp_reboot_interrupt
1155 #endif
1156
1157 #ifdef CONFIG_X86_UV
1158 apicinterrupt UV_BAU_MESSAGE \
1159         uv_bau_message_intr1 uv_bau_message_interrupt
1160 #endif
1161 apicinterrupt LOCAL_TIMER_VECTOR \
1162         apic_timer_interrupt smp_apic_timer_interrupt
1163 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1164         x86_platform_ipi smp_x86_platform_ipi
1165
1166 apicinterrupt THRESHOLD_APIC_VECTOR \
1167         threshold_interrupt smp_threshold_interrupt
1168 apicinterrupt THERMAL_APIC_VECTOR \
1169         thermal_interrupt smp_thermal_interrupt
1170
1171 #ifdef CONFIG_SMP
1172 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1173         call_function_single_interrupt smp_call_function_single_interrupt
1174 apicinterrupt CALL_FUNCTION_VECTOR \
1175         call_function_interrupt smp_call_function_interrupt
1176 apicinterrupt RESCHEDULE_VECTOR \
1177         reschedule_interrupt smp_reschedule_interrupt
1178 #endif
1179
1180 apicinterrupt ERROR_APIC_VECTOR \
1181         error_interrupt smp_error_interrupt
1182 apicinterrupt SPURIOUS_APIC_VECTOR \
1183         spurious_interrupt smp_spurious_interrupt
1184
1185 #ifdef CONFIG_IRQ_WORK
1186 apicinterrupt IRQ_WORK_VECTOR \
1187         irq_work_interrupt smp_irq_work_interrupt
1188 #endif
1189
1190 /*
1191  * Exception entry points.
1192  */
1193 .macro zeroentry sym do_sym
1194 ENTRY(\sym)
1195         ASM_CLAC
1196         INTR_FRAME
1197         PARAVIRT_ADJUST_EXCEPTION_FRAME
1198         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1199         subq $ORIG_RAX-R15, %rsp
1200         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1201         call error_entry
1202         DEFAULT_FRAME 0
1203         movq %rsp,%rdi          /* pt_regs pointer */
1204         xorl %esi,%esi          /* no error code */
1205         call \do_sym
1206         jmp error_exit          /* %ebx: no swapgs flag */
1207         CFI_ENDPROC
1208 END(\sym)
1209 .endm
1210
1211 .macro paranoidzeroentry sym do_sym
1212 ENTRY(\sym)
1213         ASM_CLAC
1214         INTR_FRAME
1215         PARAVIRT_ADJUST_EXCEPTION_FRAME
1216         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1217         subq $ORIG_RAX-R15, %rsp
1218         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1219         call save_paranoid
1220         TRACE_IRQS_OFF
1221         movq %rsp,%rdi          /* pt_regs pointer */
1222         xorl %esi,%esi          /* no error code */
1223         call \do_sym
1224         jmp paranoid_exit       /* %ebx: no swapgs flag */
1225         CFI_ENDPROC
1226 END(\sym)
1227 .endm
1228
1229 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1230 .macro paranoidzeroentry_ist sym do_sym ist
1231 ENTRY(\sym)
1232         ASM_CLAC
1233         INTR_FRAME
1234         PARAVIRT_ADJUST_EXCEPTION_FRAME
1235         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1236         subq $ORIG_RAX-R15, %rsp
1237         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1238         call save_paranoid
1239         TRACE_IRQS_OFF_DEBUG
1240         movq %rsp,%rdi          /* pt_regs pointer */
1241         xorl %esi,%esi          /* no error code */
1242         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1243         call \do_sym
1244         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1245         jmp paranoid_exit       /* %ebx: no swapgs flag */
1246         CFI_ENDPROC
1247 END(\sym)
1248 .endm
1249
1250 .macro errorentry sym do_sym
1251 ENTRY(\sym)
1252         ASM_CLAC
1253         XCPT_FRAME
1254         PARAVIRT_ADJUST_EXCEPTION_FRAME
1255         subq $ORIG_RAX-R15, %rsp
1256         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1257         call error_entry
1258         DEFAULT_FRAME 0
1259         movq %rsp,%rdi                  /* pt_regs pointer */
1260         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1261         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1262         call \do_sym
1263         jmp error_exit                  /* %ebx: no swapgs flag */
1264         CFI_ENDPROC
1265 END(\sym)
1266 .endm
1267
1268         /* error code is on the stack already */
1269 .macro paranoiderrorentry sym do_sym
1270 ENTRY(\sym)
1271         ASM_CLAC
1272         XCPT_FRAME
1273         PARAVIRT_ADJUST_EXCEPTION_FRAME
1274         subq $ORIG_RAX-R15, %rsp
1275         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1276         call save_paranoid
1277         DEFAULT_FRAME 0
1278         TRACE_IRQS_OFF
1279         movq %rsp,%rdi                  /* pt_regs pointer */
1280         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1281         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1282         call \do_sym
1283         jmp paranoid_exit               /* %ebx: no swapgs flag */
1284         CFI_ENDPROC
1285 END(\sym)
1286 .endm
1287
1288 zeroentry divide_error do_divide_error
1289 zeroentry overflow do_overflow
1290 zeroentry bounds do_bounds
1291 zeroentry invalid_op do_invalid_op
1292 zeroentry device_not_available do_device_not_available
1293 paranoiderrorentry double_fault do_double_fault
1294 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1295 errorentry invalid_TSS do_invalid_TSS
1296 errorentry segment_not_present do_segment_not_present
1297 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1298 zeroentry coprocessor_error do_coprocessor_error
1299 errorentry alignment_check do_alignment_check
1300 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1301
1302
1303         /* Reload gs selector with exception handling */
1304         /* edi:  new selector */
1305 ENTRY(native_load_gs_index)
1306         CFI_STARTPROC
1307         pushfq_cfi
1308         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1309         SWAPGS
1310 gs_change:
1311         movl %edi,%gs
1312 2:      mfence          /* workaround */
1313         SWAPGS
1314         popfq_cfi
1315         ret
1316         CFI_ENDPROC
1317 END(native_load_gs_index)
1318
1319         _ASM_EXTABLE(gs_change,bad_gs)
1320         .section .fixup,"ax"
1321         /* running with kernelgs */
1322 bad_gs:
1323         SWAPGS                  /* switch back to user gs */
1324         xorl %eax,%eax
1325         movl %eax,%gs
1326         jmp  2b
1327         .previous
1328
1329 ENTRY(ret_from_kernel_execve)
1330         movq %rdi, %rsp
1331         movl $0, RAX(%rsp)
1332         // RESTORE_REST
1333         movq 0*8(%rsp), %r15
1334         movq 1*8(%rsp), %r14
1335         movq 2*8(%rsp), %r13
1336         movq 3*8(%rsp), %r12
1337         movq 4*8(%rsp), %rbp
1338         movq 5*8(%rsp), %rbx
1339         addq $(6*8), %rsp
1340         jmp int_ret_from_sys_call
1341 END(ret_from_kernel_execve)
1342
1343 /* Call softirq on interrupt stack. Interrupts are off. */
1344 ENTRY(call_softirq)
1345         CFI_STARTPROC
1346         pushq_cfi %rbp
1347         CFI_REL_OFFSET rbp,0
1348         mov  %rsp,%rbp
1349         CFI_DEF_CFA_REGISTER rbp
1350         incl PER_CPU_VAR(irq_count)
1351         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1352         push  %rbp                      # backlink for old unwinder
1353         call __do_softirq
1354         leaveq
1355         CFI_RESTORE             rbp
1356         CFI_DEF_CFA_REGISTER    rsp
1357         CFI_ADJUST_CFA_OFFSET   -8
1358         decl PER_CPU_VAR(irq_count)
1359         ret
1360         CFI_ENDPROC
1361 END(call_softirq)
1362
1363 #ifdef CONFIG_XEN
1364 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1365
1366 /*
1367  * A note on the "critical region" in our callback handler.
1368  * We want to avoid stacking callback handlers due to events occurring
1369  * during handling of the last event. To do this, we keep events disabled
1370  * until we've done all processing. HOWEVER, we must enable events before
1371  * popping the stack frame (can't be done atomically) and so it would still
1372  * be possible to get enough handler activations to overflow the stack.
1373  * Although unlikely, bugs of that kind are hard to track down, so we'd
1374  * like to avoid the possibility.
1375  * So, on entry to the handler we detect whether we interrupted an
1376  * existing activation in its critical region -- if so, we pop the current
1377  * activation and restart the handler using the previous one.
1378  */
1379 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1380         CFI_STARTPROC
1381 /*
1382  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1383  * see the correct pointer to the pt_regs
1384  */
1385         movq %rdi, %rsp            # we don't return, adjust the stack frame
1386         CFI_ENDPROC
1387         DEFAULT_FRAME
1388 11:     incl PER_CPU_VAR(irq_count)
1389         movq %rsp,%rbp
1390         CFI_DEF_CFA_REGISTER rbp
1391         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1392         pushq %rbp                      # backlink for old unwinder
1393         call xen_evtchn_do_upcall
1394         popq %rsp
1395         CFI_DEF_CFA_REGISTER rsp
1396         decl PER_CPU_VAR(irq_count)
1397         jmp  error_exit
1398         CFI_ENDPROC
1399 END(xen_do_hypervisor_callback)
1400
1401 /*
1402  * Hypervisor uses this for application faults while it executes.
1403  * We get here for two reasons:
1404  *  1. Fault while reloading DS, ES, FS or GS
1405  *  2. Fault while executing IRET
1406  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1407  * registers that could be reloaded and zeroed the others.
1408  * Category 2 we fix up by killing the current process. We cannot use the
1409  * normal Linux return path in this case because if we use the IRET hypercall
1410  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1411  * We distinguish between categories by comparing each saved segment register
1412  * with its current contents: any discrepancy means we in category 1.
1413  */
1414 ENTRY(xen_failsafe_callback)
1415         INTR_FRAME 1 (6*8)
1416         /*CFI_REL_OFFSET gs,GS*/
1417         /*CFI_REL_OFFSET fs,FS*/
1418         /*CFI_REL_OFFSET es,ES*/
1419         /*CFI_REL_OFFSET ds,DS*/
1420         CFI_REL_OFFSET r11,8
1421         CFI_REL_OFFSET rcx,0
1422         movw %ds,%cx
1423         cmpw %cx,0x10(%rsp)
1424         CFI_REMEMBER_STATE
1425         jne 1f
1426         movw %es,%cx
1427         cmpw %cx,0x18(%rsp)
1428         jne 1f
1429         movw %fs,%cx
1430         cmpw %cx,0x20(%rsp)
1431         jne 1f
1432         movw %gs,%cx
1433         cmpw %cx,0x28(%rsp)
1434         jne 1f
1435         /* All segments match their saved values => Category 2 (Bad IRET). */
1436         movq (%rsp),%rcx
1437         CFI_RESTORE rcx
1438         movq 8(%rsp),%r11
1439         CFI_RESTORE r11
1440         addq $0x30,%rsp
1441         CFI_ADJUST_CFA_OFFSET -0x30
1442         pushq_cfi $0    /* RIP */
1443         pushq_cfi %r11
1444         pushq_cfi %rcx
1445         jmp general_protection
1446         CFI_RESTORE_STATE
1447 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1448         movq (%rsp),%rcx
1449         CFI_RESTORE rcx
1450         movq 8(%rsp),%r11
1451         CFI_RESTORE r11
1452         addq $0x30,%rsp
1453         CFI_ADJUST_CFA_OFFSET -0x30
1454         pushq_cfi $0
1455         SAVE_ALL
1456         jmp error_exit
1457         CFI_ENDPROC
1458 END(xen_failsafe_callback)
1459
1460 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1461         xen_hvm_callback_vector xen_evtchn_do_upcall
1462
1463 #endif /* CONFIG_XEN */
1464
1465 /*
1466  * Some functions should be protected against kprobes
1467  */
1468         .pushsection .kprobes.text, "ax"
1469
1470 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1471 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1472 paranoiderrorentry stack_segment do_stack_segment
1473 #ifdef CONFIG_XEN
1474 zeroentry xen_debug do_debug
1475 zeroentry xen_int3 do_int3
1476 errorentry xen_stack_segment do_stack_segment
1477 #endif
1478 errorentry general_protection do_general_protection
1479 errorentry page_fault do_page_fault
1480 #ifdef CONFIG_KVM_GUEST
1481 errorentry async_page_fault do_async_page_fault
1482 #endif
1483 #ifdef CONFIG_X86_MCE
1484 paranoidzeroentry machine_check *machine_check_vector(%rip)
1485 #endif
1486
1487         /*
1488          * "Paranoid" exit path from exception stack.
1489          * Paranoid because this is used by NMIs and cannot take
1490          * any kernel state for granted.
1491          * We don't do kernel preemption checks here, because only
1492          * NMI should be common and it does not enable IRQs and
1493          * cannot get reschedule ticks.
1494          *
1495          * "trace" is 0 for the NMI handler only, because irq-tracing
1496          * is fundamentally NMI-unsafe. (we cannot change the soft and
1497          * hard flags at once, atomically)
1498          */
1499
1500         /* ebx: no swapgs flag */
1501 ENTRY(paranoid_exit)
1502         DEFAULT_FRAME
1503         DISABLE_INTERRUPTS(CLBR_NONE)
1504         TRACE_IRQS_OFF_DEBUG
1505         testl %ebx,%ebx                         /* swapgs needed? */
1506         jnz paranoid_restore
1507         testl $3,CS(%rsp)
1508         jnz   paranoid_userspace
1509 paranoid_swapgs:
1510         TRACE_IRQS_IRETQ 0
1511         SWAPGS_UNSAFE_STACK
1512         RESTORE_ALL 8
1513         jmp irq_return
1514 paranoid_restore:
1515         TRACE_IRQS_IRETQ_DEBUG 0
1516         RESTORE_ALL 8
1517         jmp irq_return
1518 paranoid_userspace:
1519         GET_THREAD_INFO(%rcx)
1520         movl TI_flags(%rcx),%ebx
1521         andl $_TIF_WORK_MASK,%ebx
1522         jz paranoid_swapgs
1523         movq %rsp,%rdi                  /* &pt_regs */
1524         call sync_regs
1525         movq %rax,%rsp                  /* switch stack for scheduling */
1526         testl $_TIF_NEED_RESCHED,%ebx
1527         jnz paranoid_schedule
1528         movl %ebx,%edx                  /* arg3: thread flags */
1529         TRACE_IRQS_ON
1530         ENABLE_INTERRUPTS(CLBR_NONE)
1531         xorl %esi,%esi                  /* arg2: oldset */
1532         movq %rsp,%rdi                  /* arg1: &pt_regs */
1533         call do_notify_resume
1534         DISABLE_INTERRUPTS(CLBR_NONE)
1535         TRACE_IRQS_OFF
1536         jmp paranoid_userspace
1537 paranoid_schedule:
1538         TRACE_IRQS_ON
1539         ENABLE_INTERRUPTS(CLBR_ANY)
1540         SCHEDULE_USER
1541         DISABLE_INTERRUPTS(CLBR_ANY)
1542         TRACE_IRQS_OFF
1543         jmp paranoid_userspace
1544         CFI_ENDPROC
1545 END(paranoid_exit)
1546
1547 /*
1548  * Exception entry point. This expects an error code/orig_rax on the stack.
1549  * returns in "no swapgs flag" in %ebx.
1550  */
1551 ENTRY(error_entry)
1552         XCPT_FRAME
1553         CFI_ADJUST_CFA_OFFSET 15*8
1554         /* oldrax contains error code */
1555         cld
1556         movq_cfi rdi, RDI+8
1557         movq_cfi rsi, RSI+8
1558         movq_cfi rdx, RDX+8
1559         movq_cfi rcx, RCX+8
1560         movq_cfi rax, RAX+8
1561         movq_cfi  r8,  R8+8
1562         movq_cfi  r9,  R9+8
1563         movq_cfi r10, R10+8
1564         movq_cfi r11, R11+8
1565         movq_cfi rbx, RBX+8
1566         movq_cfi rbp, RBP+8
1567         movq_cfi r12, R12+8
1568         movq_cfi r13, R13+8
1569         movq_cfi r14, R14+8
1570         movq_cfi r15, R15+8
1571         xorl %ebx,%ebx
1572         testl $3,CS+8(%rsp)
1573         je error_kernelspace
1574 error_swapgs:
1575         SWAPGS
1576 error_sti:
1577         TRACE_IRQS_OFF
1578         ret
1579
1580 /*
1581  * There are two places in the kernel that can potentially fault with
1582  * usergs. Handle them here. The exception handlers after iret run with
1583  * kernel gs again, so don't set the user space flag. B stepping K8s
1584  * sometimes report an truncated RIP for IRET exceptions returning to
1585  * compat mode. Check for these here too.
1586  */
1587 error_kernelspace:
1588         incl %ebx
1589         leaq irq_return(%rip),%rcx
1590         cmpq %rcx,RIP+8(%rsp)
1591         je error_swapgs
1592         movl %ecx,%eax  /* zero extend */
1593         cmpq %rax,RIP+8(%rsp)
1594         je bstep_iret
1595         cmpq $gs_change,RIP+8(%rsp)
1596         je error_swapgs
1597         jmp error_sti
1598
1599 bstep_iret:
1600         /* Fix truncated RIP */
1601         movq %rcx,RIP+8(%rsp)
1602         jmp error_swapgs
1603         CFI_ENDPROC
1604 END(error_entry)
1605
1606
1607 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1608 ENTRY(error_exit)
1609         DEFAULT_FRAME
1610         movl %ebx,%eax
1611         RESTORE_REST
1612         DISABLE_INTERRUPTS(CLBR_NONE)
1613         TRACE_IRQS_OFF
1614         GET_THREAD_INFO(%rcx)
1615         testl %eax,%eax
1616         jne retint_kernel
1617         LOCKDEP_SYS_EXIT_IRQ
1618         movl TI_flags(%rcx),%edx
1619         movl $_TIF_WORK_MASK,%edi
1620         andl %edi,%edx
1621         jnz retint_careful
1622         jmp retint_swapgs
1623         CFI_ENDPROC
1624 END(error_exit)
1625
1626 /*
1627  * Test if a given stack is an NMI stack or not.
1628  */
1629         .macro test_in_nmi reg stack nmi_ret normal_ret
1630         cmpq %\reg, \stack
1631         ja \normal_ret
1632         subq $EXCEPTION_STKSZ, %\reg
1633         cmpq %\reg, \stack
1634         jb \normal_ret
1635         jmp \nmi_ret
1636         .endm
1637
1638         /* runs on exception stack */
1639 ENTRY(nmi)
1640         INTR_FRAME
1641         PARAVIRT_ADJUST_EXCEPTION_FRAME
1642         /*
1643          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1644          * the iretq it performs will take us out of NMI context.
1645          * This means that we can have nested NMIs where the next
1646          * NMI is using the top of the stack of the previous NMI. We
1647          * can't let it execute because the nested NMI will corrupt the
1648          * stack of the previous NMI. NMI handlers are not re-entrant
1649          * anyway.
1650          *
1651          * To handle this case we do the following:
1652          *  Check the a special location on the stack that contains
1653          *  a variable that is set when NMIs are executing.
1654          *  The interrupted task's stack is also checked to see if it
1655          *  is an NMI stack.
1656          *  If the variable is not set and the stack is not the NMI
1657          *  stack then:
1658          *    o Set the special variable on the stack
1659          *    o Copy the interrupt frame into a "saved" location on the stack
1660          *    o Copy the interrupt frame into a "copy" location on the stack
1661          *    o Continue processing the NMI
1662          *  If the variable is set or the previous stack is the NMI stack:
1663          *    o Modify the "copy" location to jump to the repeate_nmi
1664          *    o return back to the first NMI
1665          *
1666          * Now on exit of the first NMI, we first clear the stack variable
1667          * The NMI stack will tell any nested NMIs at that point that it is
1668          * nested. Then we pop the stack normally with iret, and if there was
1669          * a nested NMI that updated the copy interrupt stack frame, a
1670          * jump will be made to the repeat_nmi code that will handle the second
1671          * NMI.
1672          */
1673
1674         /* Use %rdx as out temp variable throughout */
1675         pushq_cfi %rdx
1676         CFI_REL_OFFSET rdx, 0
1677
1678         /*
1679          * If %cs was not the kernel segment, then the NMI triggered in user
1680          * space, which means it is definitely not nested.
1681          */
1682         cmpl $__KERNEL_CS, 16(%rsp)
1683         jne first_nmi
1684
1685         /*
1686          * Check the special variable on the stack to see if NMIs are
1687          * executing.
1688          */
1689         cmpl $1, -8(%rsp)
1690         je nested_nmi
1691
1692         /*
1693          * Now test if the previous stack was an NMI stack.
1694          * We need the double check. We check the NMI stack to satisfy the
1695          * race when the first NMI clears the variable before returning.
1696          * We check the variable because the first NMI could be in a
1697          * breakpoint routine using a breakpoint stack.
1698          */
1699         lea 6*8(%rsp), %rdx
1700         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1701         CFI_REMEMBER_STATE
1702
1703 nested_nmi:
1704         /*
1705          * Do nothing if we interrupted the fixup in repeat_nmi.
1706          * It's about to repeat the NMI handler, so we are fine
1707          * with ignoring this one.
1708          */
1709         movq $repeat_nmi, %rdx
1710         cmpq 8(%rsp), %rdx
1711         ja 1f
1712         movq $end_repeat_nmi, %rdx
1713         cmpq 8(%rsp), %rdx
1714         ja nested_nmi_out
1715
1716 1:
1717         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1718         leaq -6*8(%rsp), %rdx
1719         movq %rdx, %rsp
1720         CFI_ADJUST_CFA_OFFSET 6*8
1721         pushq_cfi $__KERNEL_DS
1722         pushq_cfi %rdx
1723         pushfq_cfi
1724         pushq_cfi $__KERNEL_CS
1725         pushq_cfi $repeat_nmi
1726
1727         /* Put stack back */
1728         addq $(11*8), %rsp
1729         CFI_ADJUST_CFA_OFFSET -11*8
1730
1731 nested_nmi_out:
1732         popq_cfi %rdx
1733         CFI_RESTORE rdx
1734
1735         /* No need to check faults here */
1736         INTERRUPT_RETURN
1737
1738         CFI_RESTORE_STATE
1739 first_nmi:
1740         /*
1741          * Because nested NMIs will use the pushed location that we
1742          * stored in rdx, we must keep that space available.
1743          * Here's what our stack frame will look like:
1744          * +-------------------------+
1745          * | original SS             |
1746          * | original Return RSP     |
1747          * | original RFLAGS         |
1748          * | original CS             |
1749          * | original RIP            |
1750          * +-------------------------+
1751          * | temp storage for rdx    |
1752          * +-------------------------+
1753          * | NMI executing variable  |
1754          * +-------------------------+
1755          * | Saved SS                |
1756          * | Saved Return RSP        |
1757          * | Saved RFLAGS            |
1758          * | Saved CS                |
1759          * | Saved RIP               |
1760          * +-------------------------+
1761          * | copied SS               |
1762          * | copied Return RSP       |
1763          * | copied RFLAGS           |
1764          * | copied CS               |
1765          * | copied RIP              |
1766          * +-------------------------+
1767          * | pt_regs                 |
1768          * +-------------------------+
1769          *
1770          * The saved stack frame is used to fix up the copied stack frame
1771          * that a nested NMI may change to make the interrupted NMI iret jump
1772          * to the repeat_nmi. The original stack frame and the temp storage
1773          * is also used by nested NMIs and can not be trusted on exit.
1774          */
1775         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1776         movq (%rsp), %rdx
1777         CFI_RESTORE rdx
1778
1779         /* Set the NMI executing variable on the stack. */
1780         pushq_cfi $1
1781
1782         /* Copy the stack frame to the Saved frame */
1783         .rept 5
1784         pushq_cfi 6*8(%rsp)
1785         .endr
1786         CFI_DEF_CFA_OFFSET SS+8-RIP
1787
1788         /* Everything up to here is safe from nested NMIs */
1789
1790         /*
1791          * If there was a nested NMI, the first NMI's iret will return
1792          * here. But NMIs are still enabled and we can take another
1793          * nested NMI. The nested NMI checks the interrupted RIP to see
1794          * if it is between repeat_nmi and end_repeat_nmi, and if so
1795          * it will just return, as we are about to repeat an NMI anyway.
1796          * This makes it safe to copy to the stack frame that a nested
1797          * NMI will update.
1798          */
1799 repeat_nmi:
1800         /*
1801          * Update the stack variable to say we are still in NMI (the update
1802          * is benign for the non-repeat case, where 1 was pushed just above
1803          * to this very stack slot).
1804          */
1805         movq $1, 5*8(%rsp)
1806
1807         /* Make another copy, this one may be modified by nested NMIs */
1808         .rept 5
1809         pushq_cfi 4*8(%rsp)
1810         .endr
1811         CFI_DEF_CFA_OFFSET SS+8-RIP
1812 end_repeat_nmi:
1813
1814         /*
1815          * Everything below this point can be preempted by a nested
1816          * NMI if the first NMI took an exception and reset our iret stack
1817          * so that we repeat another NMI.
1818          */
1819         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1820         subq $ORIG_RAX-R15, %rsp
1821         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1822         /*
1823          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1824          * as we should not be calling schedule in NMI context.
1825          * Even with normal interrupts enabled. An NMI should not be
1826          * setting NEED_RESCHED or anything that normal interrupts and
1827          * exceptions might do.
1828          */
1829         call save_paranoid
1830         DEFAULT_FRAME 0
1831
1832         /*
1833          * Save off the CR2 register. If we take a page fault in the NMI then
1834          * it could corrupt the CR2 value. If the NMI preempts a page fault
1835          * handler before it was able to read the CR2 register, and then the
1836          * NMI itself takes a page fault, the page fault that was preempted
1837          * will read the information from the NMI page fault and not the
1838          * origin fault. Save it off and restore it if it changes.
1839          * Use the r12 callee-saved register.
1840          */
1841         movq %cr2, %r12
1842
1843         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1844         movq %rsp,%rdi
1845         movq $-1,%rsi
1846         call do_nmi
1847
1848         /* Did the NMI take a page fault? Restore cr2 if it did */
1849         movq %cr2, %rcx
1850         cmpq %rcx, %r12
1851         je 1f
1852         movq %r12, %cr2
1853 1:
1854
1855         testl %ebx,%ebx                         /* swapgs needed? */
1856         jnz nmi_restore
1857 nmi_swapgs:
1858         SWAPGS_UNSAFE_STACK
1859 nmi_restore:
1860         RESTORE_ALL 8
1861         /* Clear the NMI executing stack variable */
1862         movq $0, 10*8(%rsp)
1863         jmp irq_return
1864         CFI_ENDPROC
1865 END(nmi)
1866
1867 ENTRY(ignore_sysret)
1868         CFI_STARTPROC
1869         mov $-ENOSYS,%eax
1870         sysret
1871         CFI_ENDPROC
1872 END(ignore_sysret)
1873
1874 /*
1875  * End of kprobes section
1876  */
1877         .popsection