Pileus Git - ~andy/linux/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         subq $MCOUNT_INSN_SIZE, %rsi
 139
 140         call    prepare_ftrace_return
 141
 142         MCOUNT_RESTORE_FRAME
 143
 144         retq
 145 END(ftrace_graph_caller)
 146
 147 GLOBAL(return_to_handler)
 148         subq  $80, %rsp
 149
 150         movq %rax, (%rsp)
 151         movq %rcx, 8(%rsp)
 152         movq %rdx, 16(%rsp)
 153         movq %rsi, 24(%rsp)
 154         movq %rdi, 32(%rsp)
 155         movq %r8, 40(%rsp)
 156         movq %r9, 48(%rsp)
 157         movq %r10, 56(%rsp)
 158         movq %r11, 64(%rsp)
 159
 160         call ftrace_return_to_handler
 161
 162         movq %rax, 72(%rsp)
 163         movq 64(%rsp), %r11
 164         movq 56(%rsp), %r10
 165         movq 48(%rsp), %r9
 166         movq 40(%rsp), %r8
 167         movq 32(%rsp), %rdi
 168         movq 24(%rsp), %rsi
 169         movq 16(%rsp), %rdx
 170         movq 8(%rsp), %rcx
 171         movq (%rsp), %rax
 172         addq $72, %rsp
 173         retq
 174 #endif
 175
 176
 177 #ifndef CONFIG_PREEMPT
 178 #define retint_kernel retint_restore_args
 179 #endif
 180
 181 #ifdef CONFIG_PARAVIRT
 182 ENTRY(native_usergs_sysret64)
 183         swapgs
 184         sysretq
 185 ENDPROC(native_usergs_sysret64)
 186 #endif /* CONFIG_PARAVIRT */
 187
 188
 189 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 190 #ifdef CONFIG_TRACE_IRQFLAGS
 191         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 192         jnc  1f
 193         TRACE_IRQS_ON
 194 1:
 195 #endif
 196 .endm
 197
 198 /*
 199  * C code is not supposed to know about undefined top of stack. Every time
 200  * a C function with an pt_regs argument is called from the SYSCALL based
 201  * fast path FIXUP_TOP_OF_STACK is needed.
 202  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 203  * manipulation.
 204  */
 205
 206         /* %rsp:at FRAMEEND */
 207         .macro FIXUP_TOP_OF_STACK tmp offset=0
 208         movq PER_CPU_VAR(old_rsp),\tmp
 209         movq \tmp,RSP+\offset(%rsp)
 210         movq $__USER_DS,SS+\offset(%rsp)
 211         movq $__USER_CS,CS+\offset(%rsp)
 212         movq $-1,RCX+\offset(%rsp)
 213         movq R11+\offset(%rsp),\tmp  /* get eflags */
 214         movq \tmp,EFLAGS+\offset(%rsp)
 215         .endm
 216
 217         .macro RESTORE_TOP_OF_STACK tmp offset=0
 218         movq RSP+\offset(%rsp),\tmp
 219         movq \tmp,PER_CPU_VAR(old_rsp)
 220         movq EFLAGS+\offset(%rsp),\tmp
 221         movq \tmp,R11+\offset(%rsp)
 222         .endm
 223
 224         .macro FAKE_STACK_FRAME child_rip
 225         /* push in order ss, rsp, eflags, cs, rip */
 226         xorl %eax, %eax
 227         pushq $__KERNEL_DS /* ss */
 228         CFI_ADJUST_CFA_OFFSET   8
 229         /*CFI_REL_OFFSET        ss,0*/
 230         pushq %rax /* rsp */
 231         CFI_ADJUST_CFA_OFFSET   8
 232         CFI_REL_OFFSET  rsp,0
 233         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 234         CFI_ADJUST_CFA_OFFSET   8
 235         /*CFI_REL_OFFSET        rflags,0*/
 236         pushq $__KERNEL_CS /* cs */
 237         CFI_ADJUST_CFA_OFFSET   8
 238         /*CFI_REL_OFFSET        cs,0*/
 239         pushq \child_rip /* rip */
 240         CFI_ADJUST_CFA_OFFSET   8
 241         CFI_REL_OFFSET  rip,0
 242         pushq   %rax /* orig rax */
 243         CFI_ADJUST_CFA_OFFSET   8
 244         .endm
 245
 246         .macro UNFAKE_STACK_FRAME
 247         addq $8*6, %rsp
 248         CFI_ADJUST_CFA_OFFSET   -(6*8)
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro EMPTY_FRAME start=1 offset=0
 255         .if \start
 256         CFI_STARTPROC simple
 257         CFI_SIGNAL_FRAME
 258         CFI_DEF_CFA rsp,8+\offset
 259         .else
 260         CFI_DEF_CFA_OFFSET 8+\offset
 261         .endif
 262         .endm
 263
 264 /*
 265  * initial frame state for interrupts (and exceptions without error code)
 266  */
 267         .macro INTR_FRAME start=1 offset=0
 268         EMPTY_FRAME \start, SS+8+\offset-RIP
 269         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 270         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 271         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 272         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 273         CFI_REL_OFFSET rip, RIP+\offset-RIP
 274         .endm
 275
 276 /*
 277  * initial frame state for exceptions with error code (and interrupts
 278  * with vector already pushed)
 279  */
 280         .macro XCPT_FRAME start=1 offset=0
 281         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 282         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 283         .endm
 284
 285 /*
 286  * frame that enables calling into C.
 287  */
 288         .macro PARTIAL_FRAME start=1 offset=0
 289         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 290         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 291         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 292         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 293         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 294         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 295         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 296         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 297         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 298         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 299         .endm
 300
 301 /*
 302  * frame that enables passing a complete pt_regs to a C function.
 303  */
 304         .macro DEFAULT_FRAME start=1 offset=0
 305         PARTIAL_FRAME \start, R11+\offset-R15
 306         CFI_REL_OFFSET rbx, RBX+\offset
 307         CFI_REL_OFFSET rbp, RBP+\offset
 308         CFI_REL_OFFSET r12, R12+\offset
 309         CFI_REL_OFFSET r13, R13+\offset
 310         CFI_REL_OFFSET r14, R14+\offset
 311         CFI_REL_OFFSET r15, R15+\offset
 312         .endm
 313
 314 /* save partial stack frame */
 315 ENTRY(save_args)
 316         XCPT_FRAME
 317         cld
 318         movq_cfi rdi, RDI+16-ARGOFFSET
 319         movq_cfi rsi, RSI+16-ARGOFFSET
 320         movq_cfi rdx, RDX+16-ARGOFFSET
 321         movq_cfi rcx, RCX+16-ARGOFFSET
 322         movq_cfi rax, RAX+16-ARGOFFSET
 323         movq_cfi  r8,  R8+16-ARGOFFSET
 324         movq_cfi  r9,  R9+16-ARGOFFSET
 325         movq_cfi r10, R10+16-ARGOFFSET
 326         movq_cfi r11, R11+16-ARGOFFSET
 327
 328         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 329         movq_cfi rbp, 8         /* push %rbp */
 330         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 331         testl $3, CS(%rdi)
 332         je 1f
 333         SWAPGS
 334         /*
 335          * irq_count is used to check if a CPU is already on an interrupt stack
 336          * or not. While this is essentially redundant with preempt_count it is
 337          * a little cheaper to use a separate counter in the PDA (short of
 338          * moving irq_enter into assembly, which would be too much work)
 339          */
 340 1:      incl PER_CPU_VAR(irq_count)
 341         jne 2f
 342         popq_cfi %rax                   /* move return address... */
 343         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 344         EMPTY_FRAME 0
 345         pushq_cfi %rbp                  /* backlink for unwinder */
 346         pushq_cfi %rax                  /* ... to the new stack */
 347         /*
 348          * We entered an interrupt context - irqs are off:
 349          */
 350 2:      TRACE_IRQS_OFF
 351         ret
 352         CFI_ENDPROC
 353 END(save_args)
 354
 355 ENTRY(save_rest)
 356         PARTIAL_FRAME 1 REST_SKIP+8
 357         movq 5*8+16(%rsp), %r11 /* save return address */
 358         movq_cfi rbx, RBX+16
 359         movq_cfi rbp, RBP+16
 360         movq_cfi r12, R12+16
 361         movq_cfi r13, R13+16
 362         movq_cfi r14, R14+16
 363         movq_cfi r15, R15+16
 364         movq %r11, 8(%rsp)      /* return address */
 365         FIXUP_TOP_OF_STACK %r11, 16
 366         ret
 367         CFI_ENDPROC
 368 END(save_rest)
 369
 370 /* save complete stack frame */
 371         .pushsection .kprobes.text, "ax"
 372 ENTRY(save_paranoid)
 373         XCPT_FRAME 1 RDI+8
 374         cld
 375         movq_cfi rdi, RDI+8
 376         movq_cfi rsi, RSI+8
 377         movq_cfi rdx, RDX+8
 378         movq_cfi rcx, RCX+8
 379         movq_cfi rax, RAX+8
 380         movq_cfi r8, R8+8
 381         movq_cfi r9, R9+8
 382         movq_cfi r10, R10+8
 383         movq_cfi r11, R11+8
 384         movq_cfi rbx, RBX+8
 385         movq_cfi rbp, RBP+8
 386         movq_cfi r12, R12+8
 387         movq_cfi r13, R13+8
 388         movq_cfi r14, R14+8
 389         movq_cfi r15, R15+8
 390         movl $1,%ebx
 391         movl $MSR_GS_BASE,%ecx
 392         rdmsr
 393         testl %edx,%edx
 394         js 1f   /* negative -> in kernel */
 395         SWAPGS
 396         xorl %ebx,%ebx
 397 1:      ret
 398         CFI_ENDPROC
 399 END(save_paranoid)
 400         .popsection
 401
 402 /*
 403  * A newly forked process directly context switches into this address.
 404  *
 405  * rdi: prev task we switched from
 406  */
 407 ENTRY(ret_from_fork)
 408         DEFAULT_FRAME
 409
 410         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 411
 412         push kernel_eflags(%rip)
 413         CFI_ADJUST_CFA_OFFSET 8
 414         popf                                    # reset kernel eflags
 415         CFI_ADJUST_CFA_OFFSET -8
 416
 417         call schedule_tail                      # rdi: 'prev' task parameter
 418
 419         GET_THREAD_INFO(%rcx)
 420
 421         RESTORE_REST
 422
 423         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 424         je   int_ret_from_sys_call
 425
 426         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 427         jnz  int_ret_from_sys_call
 428
 429         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 430         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 431
 432         CFI_ENDPROC
 433 END(ret_from_fork)
 434
 435 /*
 436  * System call entry. Upto 6 arguments in registers are supported.
 437  *
 438  * SYSCALL does not save anything on the stack and does not change the
 439  * stack pointer.
 440  */
 441
 442 /*
 443  * Register setup:
 444  * rax  system call number
 445  * rdi  arg0
 446  * rcx  return address for syscall/sysret, C arg3
 447  * rsi  arg1
 448  * rdx  arg2
 449  * r10  arg3    (--> moved to rcx for C)
 450  * r8   arg4
 451  * r9   arg5
 452  * r11  eflags for syscall/sysret, temporary for C
 453  * r12-r15,rbp,rbx saved by C code, not touched.
 454  *
 455  * Interrupts are off on entry.
 456  * Only called from user space.
 457  *
 458  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 459  *      and report it properly in ps. Unfortunately we haven't.
 460  *
 461  * When user can change the frames always force IRET. That is because
 462  * it deals with uncanonical addresses better. SYSRET has trouble
 463  * with them due to bugs in both AMD and Intel CPUs.
 464  */
 465
 466 ENTRY(system_call)
 467         CFI_STARTPROC   simple
 468         CFI_SIGNAL_FRAME
 469         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 470         CFI_REGISTER    rip,rcx
 471         /*CFI_REGISTER  rflags,r11*/
 472         SWAPGS_UNSAFE_STACK
 473         /*
 474          * A hypervisor implementation might want to use a label
 475          * after the swapgs, so that it can do the swapgs
 476          * for the guest and jump here on syscall.
 477          */
 478 ENTRY(system_call_after_swapgs)
 479
 480         movq    %rsp,PER_CPU_VAR(old_rsp)
 481         movq    PER_CPU_VAR(kernel_stack),%rsp
 482         /*
 483          * No need to follow this irqs off/on section - it's straight
 484          * and short:
 485          */
 486         ENABLE_INTERRUPTS(CLBR_NONE)
 487         SAVE_ARGS 8,1
 488         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 489         movq  %rcx,RIP-ARGOFFSET(%rsp)
 490         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 491         GET_THREAD_INFO(%rcx)
 492         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 493         jnz tracesys
 494 system_call_fastpath:
 495         cmpq $__NR_syscall_max,%rax
 496         ja badsys
 497         movq %r10,%rcx
 498         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 499         movq %rax,RAX-ARGOFFSET(%rsp)
 500 /*
 501  * Syscall return path ending with SYSRET (fast path)
 502  * Has incomplete stack frame and undefined top of stack.
 503  */
 504 ret_from_sys_call:
 505         movl $_TIF_ALLWORK_MASK,%edi
 506         /* edi: flagmask */
 507 sysret_check:
 508         LOCKDEP_SYS_EXIT
 509         GET_THREAD_INFO(%rcx)
 510         DISABLE_INTERRUPTS(CLBR_NONE)
 511         TRACE_IRQS_OFF
 512         movl TI_flags(%rcx),%edx
 513         andl %edi,%edx
 514         jnz  sysret_careful
 515         CFI_REMEMBER_STATE
 516         /*
 517          * sysretq will re-enable interrupts:
 518          */
 519         TRACE_IRQS_ON
 520         movq RIP-ARGOFFSET(%rsp),%rcx
 521         CFI_REGISTER    rip,rcx
 522         RESTORE_ARGS 0,-ARG_SKIP,1
 523         /*CFI_REGISTER  rflags,r11*/
 524         movq    PER_CPU_VAR(old_rsp), %rsp
 525         USERGS_SYSRET64
 526
 527         CFI_RESTORE_STATE
 528         /* Handle reschedules */
 529         /* edx: work, edi: workmask */
 530 sysret_careful:
 531         bt $TIF_NEED_RESCHED,%edx
 532         jnc sysret_signal
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535         pushq %rdi
 536         CFI_ADJUST_CFA_OFFSET 8
 537         call schedule
 538         popq  %rdi
 539         CFI_ADJUST_CFA_OFFSET -8
 540         jmp sysret_check
 541
 542         /* Handle a signal */
 543 sysret_signal:
 544         TRACE_IRQS_ON
 545         ENABLE_INTERRUPTS(CLBR_NONE)
 546 #ifdef CONFIG_AUDITSYSCALL
 547         bt $TIF_SYSCALL_AUDIT,%edx
 548         jc sysret_audit
 549 #endif
 550         /* edx: work flags (arg3) */
 551         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 552         xorl %esi,%esi # oldset -> arg2
 553         SAVE_REST
 554         FIXUP_TOP_OF_STACK %r11
 555         call do_notify_resume
 556         RESTORE_TOP_OF_STACK %r11
 557         RESTORE_REST
 558         movl $_TIF_WORK_MASK,%edi
 559         /* Use IRET because user could have changed frame. This
 560            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 561         DISABLE_INTERRUPTS(CLBR_NONE)
 562         TRACE_IRQS_OFF
 563         jmp int_with_check
 564
 565 badsys:
 566         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 567         jmp ret_from_sys_call
 568
 569 #ifdef CONFIG_AUDITSYSCALL
 570         /*
 571          * Fast path for syscall audit without full syscall trace.
 572          * We just call audit_syscall_entry() directly, and then
 573          * jump back to the normal fast path.
 574          */
 575 auditsys:
 576         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 577         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 578         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 579         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 580         movq %rax,%rsi                  /* 2nd arg: syscall number */
 581         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 582         call audit_syscall_entry
 583         LOAD_ARGS 0             /* reload call-clobbered registers */
 584         jmp system_call_fastpath
 585
 586         /*
 587          * Return fast path for syscall audit.  Call audit_syscall_exit()
 588          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 589          * masked off.
 590          */
 591 sysret_audit:
 592         movq %rax,%rsi          /* second arg, syscall return value */
 593         cmpq $0,%rax            /* is it < 0? */
 594         setl %al                /* 1 if so, 0 if not */
 595         movzbl %al,%edi         /* zero-extend that into %edi */
 596         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 597         call audit_syscall_exit
 598         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 599         jmp sysret_check
 600 #endif  /* CONFIG_AUDITSYSCALL */
 601
 602         /* Do syscall tracing */
 603 tracesys:
 604 #ifdef CONFIG_AUDITSYSCALL
 605         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 606         jz auditsys
 607 #endif
 608         SAVE_REST
 609         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 610         FIXUP_TOP_OF_STACK %rdi
 611         movq %rsp,%rdi
 612         call syscall_trace_enter
 613         /*
 614          * Reload arg registers from stack in case ptrace changed them.
 615          * We don't reload %rax because syscall_trace_enter() returned
 616          * the value it wants us to use in the table lookup.
 617          */
 618         LOAD_ARGS ARGOFFSET, 1
 619         RESTORE_REST
 620         cmpq $__NR_syscall_max,%rax
 621         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 622         movq %r10,%rcx  /* fixup for C */
 623         call *sys_call_table(,%rax,8)
 624         movq %rax,RAX-ARGOFFSET(%rsp)
 625         /* Use IRET because user could have changed frame */
 626
 627 /*
 628  * Syscall return path ending with IRET.
 629  * Has correct top of stack, but partial stack frame.
 630  */
 631 GLOBAL(int_ret_from_sys_call)
 632         DISABLE_INTERRUPTS(CLBR_NONE)
 633         TRACE_IRQS_OFF
 634         testl $3,CS-ARGOFFSET(%rsp)
 635         je retint_restore_args
 636         movl $_TIF_ALLWORK_MASK,%edi
 637         /* edi: mask to check */
 638 GLOBAL(int_with_check)
 639         LOCKDEP_SYS_EXIT_IRQ
 640         GET_THREAD_INFO(%rcx)
 641         movl TI_flags(%rcx),%edx
 642         andl %edi,%edx
 643         jnz   int_careful
 644         andl    $~TS_COMPAT,TI_status(%rcx)
 645         jmp   retint_swapgs
 646
 647         /* Either reschedule or signal or syscall exit tracking needed. */
 648         /* First do a reschedule test. */
 649         /* edx: work, edi: workmask */
 650 int_careful:
 651         bt $TIF_NEED_RESCHED,%edx
 652         jnc  int_very_careful
 653         TRACE_IRQS_ON
 654         ENABLE_INTERRUPTS(CLBR_NONE)
 655         pushq %rdi
 656         CFI_ADJUST_CFA_OFFSET 8
 657         call schedule
 658         popq %rdi
 659         CFI_ADJUST_CFA_OFFSET -8
 660         DISABLE_INTERRUPTS(CLBR_NONE)
 661         TRACE_IRQS_OFF
 662         jmp int_with_check
 663
 664         /* handle signals and tracing -- both require a full stack frame */
 665 int_very_careful:
 666         TRACE_IRQS_ON
 667         ENABLE_INTERRUPTS(CLBR_NONE)
 668         SAVE_REST
 669         /* Check for syscall exit trace */
 670         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 671         jz int_signal
 672         pushq %rdi
 673         CFI_ADJUST_CFA_OFFSET 8
 674         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 675         call syscall_trace_leave
 676         popq %rdi
 677         CFI_ADJUST_CFA_OFFSET -8
 678         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 679         jmp int_restore_rest
 680
 681 int_signal:
 682         testl $_TIF_DO_NOTIFY_MASK,%edx
 683         jz 1f
 684         movq %rsp,%rdi          # &ptregs -> arg1
 685         xorl %esi,%esi          # oldset -> arg2
 686         call do_notify_resume
 687 1:      movl $_TIF_WORK_MASK,%edi
 688 int_restore_rest:
 689         RESTORE_REST
 690         DISABLE_INTERRUPTS(CLBR_NONE)
 691         TRACE_IRQS_OFF
 692         jmp int_with_check
 693         CFI_ENDPROC
 694 END(system_call)
 695
 696 /*
 697  * Certain special system calls that need to save a complete full stack frame.
 698  */
 699         .macro PTREGSCALL label,func,arg
 700 ENTRY(\label)
 701         PARTIAL_FRAME 1 8               /* offset 8: return address */
 702         subq $REST_SKIP, %rsp
 703         CFI_ADJUST_CFA_OFFSET REST_SKIP
 704         call save_rest
 705         DEFAULT_FRAME 0 8               /* offset 8: return address */
 706         leaq 8(%rsp), \arg      /* pt_regs pointer */
 707         call \func
 708         jmp ptregscall_common
 709         CFI_ENDPROC
 710 END(\label)
 711         .endm
 712
 713         PTREGSCALL stub_clone, sys_clone, %r8
 714         PTREGSCALL stub_fork, sys_fork, %rdi
 715         PTREGSCALL stub_vfork, sys_vfork, %rdi
 716         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 717         PTREGSCALL stub_iopl, sys_iopl, %rsi
 718
 719 ENTRY(ptregscall_common)
 720         DEFAULT_FRAME 1 8       /* offset 8: return address */
 721         RESTORE_TOP_OF_STACK %r11, 8
 722         movq_cfi_restore R15+8, r15
 723         movq_cfi_restore R14+8, r14
 724         movq_cfi_restore R13+8, r13
 725         movq_cfi_restore R12+8, r12
 726         movq_cfi_restore RBP+8, rbp
 727         movq_cfi_restore RBX+8, rbx
 728         ret $REST_SKIP          /* pop extended registers */
 729         CFI_ENDPROC
 730 END(ptregscall_common)
 731
 732 ENTRY(stub_execve)
 733         CFI_STARTPROC
 734         popq %r11
 735         CFI_ADJUST_CFA_OFFSET -8
 736         CFI_REGISTER rip, r11
 737         SAVE_REST
 738         FIXUP_TOP_OF_STACK %r11
 739         movq %rsp, %rcx
 740         call sys_execve
 741         RESTORE_TOP_OF_STACK %r11
 742         movq %rax,RAX(%rsp)
 743         RESTORE_REST
 744         jmp int_ret_from_sys_call
 745         CFI_ENDPROC
 746 END(stub_execve)
 747
 748 /*
 749  * sigreturn is special because it needs to restore all registers on return.
 750  * This cannot be done with SYSRET, so use the IRET return path instead.
 751  */
 752 ENTRY(stub_rt_sigreturn)
 753         CFI_STARTPROC
 754         addq $8, %rsp
 755         CFI_ADJUST_CFA_OFFSET   -8
 756         SAVE_REST
 757         movq %rsp,%rdi
 758         FIXUP_TOP_OF_STACK %r11
 759         call sys_rt_sigreturn
 760         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 761         RESTORE_REST
 762         jmp int_ret_from_sys_call
 763         CFI_ENDPROC
 764 END(stub_rt_sigreturn)
 765
 766 /*
 767  * Build the entry stubs and pointer table with some assembler magic.
 768  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 769  * single cache line on all modern x86 implementations.
 770  */
 771         .section .init.rodata,"a"
 772 ENTRY(interrupt)
 773         .text
 774         .p2align 5
 775         .p2align CONFIG_X86_L1_CACHE_SHIFT
 776 ENTRY(irq_entries_start)
 777         INTR_FRAME
 778 vector=FIRST_EXTERNAL_VECTOR
 779 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 780         .balign 32
 781   .rept 7
 782     .if vector < NR_VECTORS
 783       .if vector <> FIRST_EXTERNAL_VECTOR
 784         CFI_ADJUST_CFA_OFFSET -8
 785       .endif
 786 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 787         CFI_ADJUST_CFA_OFFSET 8
 788       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 789         jmp 2f
 790       .endif
 791       .previous
 792         .quad 1b
 793       .text
 794 vector=vector+1
 795     .endif
 796   .endr
 797 2:      jmp common_interrupt
 798 .endr
 799         CFI_ENDPROC
 800 END(irq_entries_start)
 801
 802 .previous
 803 END(interrupt)
 804 .previous
 805
 806 /*
 807  * Interrupt entry/exit.
 808  *
 809  * Interrupt entry points save only callee clobbered registers in fast path.
 810  *
 811  * Entry runs with interrupts off.
 812  */
 813
 814 /* 0(%rsp): ~(interrupt number) */
 815         .macro interrupt func
 816         subq $10*8, %rsp
 817         CFI_ADJUST_CFA_OFFSET 10*8
 818         call save_args
 819         PARTIAL_FRAME 0
 820         call \func
 821         .endm
 822
 823         /*
 824          * The interrupt stubs push (~vector+0x80) onto the stack and
 825          * then jump to common_interrupt.
 826          */
 827         .p2align CONFIG_X86_L1_CACHE_SHIFT
 828 common_interrupt:
 829         XCPT_FRAME
 830         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 831         interrupt do_IRQ
 832         /* 0(%rsp): old_rsp-ARGOFFSET */
 833 ret_from_intr:
 834         DISABLE_INTERRUPTS(CLBR_NONE)
 835         TRACE_IRQS_OFF
 836         decl PER_CPU_VAR(irq_count)
 837         leaveq
 838         CFI_DEF_CFA_REGISTER    rsp
 839         CFI_ADJUST_CFA_OFFSET   -8
 840 exit_intr:
 841         GET_THREAD_INFO(%rcx)
 842         testl $3,CS-ARGOFFSET(%rsp)
 843         je retint_kernel
 844
 845         /* Interrupt came from user space */
 846         /*
 847          * Has a correct top of stack, but a partial stack frame
 848          * %rcx: thread info. Interrupts off.
 849          */
 850 retint_with_reschedule:
 851         movl $_TIF_WORK_MASK,%edi
 852 retint_check:
 853         LOCKDEP_SYS_EXIT_IRQ
 854         movl TI_flags(%rcx),%edx
 855         andl %edi,%edx
 856         CFI_REMEMBER_STATE
 857         jnz  retint_careful
 858
 859 retint_swapgs:          /* return to user-space */
 860         /*
 861          * The iretq could re-enable interrupts:
 862          */
 863         DISABLE_INTERRUPTS(CLBR_ANY)
 864         TRACE_IRQS_IRETQ
 865         SWAPGS
 866         jmp restore_args
 867
 868 retint_restore_args:    /* return to kernel space */
 869         DISABLE_INTERRUPTS(CLBR_ANY)
 870         /*
 871          * The iretq could re-enable interrupts:
 872          */
 873         TRACE_IRQS_IRETQ
 874 restore_args:
 875         RESTORE_ARGS 0,8,0
 876
 877 irq_return:
 878         INTERRUPT_RETURN
 879
 880         .section __ex_table, "a"
 881         .quad irq_return, bad_iret
 882         .previous
 883
 884 #ifdef CONFIG_PARAVIRT
 885 ENTRY(native_iret)
 886         iretq
 887
 888         .section __ex_table,"a"
 889         .quad native_iret, bad_iret
 890         .previous
 891 #endif
 892
 893         .section .fixup,"ax"
 894 bad_iret:
 895         /*
 896          * The iret traps when the %cs or %ss being restored is bogus.
 897          * We've lost the original trap vector and error code.
 898          * #GPF is the most likely one to get for an invalid selector.
 899          * So pretend we completed the iret and took the #GPF in user mode.
 900          *
 901          * We are now running with the kernel GS after exception recovery.
 902          * But error_entry expects us to have user GS to match the user %cs,
 903          * so swap back.
 904          */
 905         pushq $0
 906
 907         SWAPGS
 908         jmp general_protection
 909
 910         .previous
 911
 912         /* edi: workmask, edx: work */
 913 retint_careful:
 914         CFI_RESTORE_STATE
 915         bt    $TIF_NEED_RESCHED,%edx
 916         jnc   retint_signal
 917         TRACE_IRQS_ON
 918         ENABLE_INTERRUPTS(CLBR_NONE)
 919         pushq %rdi
 920         CFI_ADJUST_CFA_OFFSET   8
 921         call  schedule
 922         popq %rdi
 923         CFI_ADJUST_CFA_OFFSET   -8
 924         GET_THREAD_INFO(%rcx)
 925         DISABLE_INTERRUPTS(CLBR_NONE)
 926         TRACE_IRQS_OFF
 927         jmp retint_check
 928
 929 retint_signal:
 930         testl $_TIF_DO_NOTIFY_MASK,%edx
 931         jz    retint_swapgs
 932         TRACE_IRQS_ON
 933         ENABLE_INTERRUPTS(CLBR_NONE)
 934         SAVE_REST
 935         movq $-1,ORIG_RAX(%rsp)
 936         xorl %esi,%esi          # oldset
 937         movq %rsp,%rdi          # &pt_regs
 938         call do_notify_resume
 939         RESTORE_REST
 940         DISABLE_INTERRUPTS(CLBR_NONE)
 941         TRACE_IRQS_OFF
 942         GET_THREAD_INFO(%rcx)
 943         jmp retint_with_reschedule
 944
 945 #ifdef CONFIG_PREEMPT
 946         /* Returning to kernel space. Check if we need preemption */
 947         /* rcx:  threadinfo. interrupts off. */
 948 ENTRY(retint_kernel)
 949         cmpl $0,TI_preempt_count(%rcx)
 950         jnz  retint_restore_args
 951         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 952         jnc  retint_restore_args
 953         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 954         jnc  retint_restore_args
 955         call preempt_schedule_irq
 956         jmp exit_intr
 957 #endif
 958
 959         CFI_ENDPROC
 960 END(common_interrupt)
 961
 962 /*
 963  * APIC interrupts.
 964  */
 965 .macro apicinterrupt num sym do_sym
 966 ENTRY(\sym)
 967         INTR_FRAME
 968         pushq $~(\num)
 969         CFI_ADJUST_CFA_OFFSET 8
 970         interrupt \do_sym
 971         jmp ret_from_intr
 972         CFI_ENDPROC
 973 END(\sym)
 974 .endm
 975
 976 #ifdef CONFIG_SMP
 977 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 978         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 979 #endif
 980
 981 #ifdef CONFIG_X86_UV
 982 apicinterrupt UV_BAU_MESSAGE \
 983         uv_bau_message_intr1 uv_bau_message_interrupt
 984 #endif
 985 apicinterrupt LOCAL_TIMER_VECTOR \
 986         apic_timer_interrupt smp_apic_timer_interrupt
 987 apicinterrupt GENERIC_INTERRUPT_VECTOR \
 988         generic_interrupt smp_generic_interrupt
 989
 990 #ifdef CONFIG_SMP
 991 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 992         invalidate_interrupt0 smp_invalidate_interrupt
 993 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 994         invalidate_interrupt1 smp_invalidate_interrupt
 995 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 996         invalidate_interrupt2 smp_invalidate_interrupt
 997 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 998         invalidate_interrupt3 smp_invalidate_interrupt
 999 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
1000         invalidate_interrupt4 smp_invalidate_interrupt
1001 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1002         invalidate_interrupt5 smp_invalidate_interrupt
1003 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1004         invalidate_interrupt6 smp_invalidate_interrupt
1005 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1006         invalidate_interrupt7 smp_invalidate_interrupt
1007 #endif
1008
1009 apicinterrupt THRESHOLD_APIC_VECTOR \
1010         threshold_interrupt mce_threshold_interrupt
1011 apicinterrupt THERMAL_APIC_VECTOR \
1012         thermal_interrupt smp_thermal_interrupt
1013
1014 #ifdef CONFIG_SMP
1015 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1016         call_function_single_interrupt smp_call_function_single_interrupt
1017 apicinterrupt CALL_FUNCTION_VECTOR \
1018         call_function_interrupt smp_call_function_interrupt
1019 apicinterrupt RESCHEDULE_VECTOR \
1020         reschedule_interrupt smp_reschedule_interrupt
1021 #endif
1022
1023 apicinterrupt ERROR_APIC_VECTOR \
1024         error_interrupt smp_error_interrupt
1025 apicinterrupt SPURIOUS_APIC_VECTOR \
1026         spurious_interrupt smp_spurious_interrupt
1027
1028 #ifdef CONFIG_PERF_COUNTERS
1029 apicinterrupt LOCAL_PERF_VECTOR \
1030         perf_counter_interrupt smp_perf_counter_interrupt
1031 apicinterrupt LOCAL_PENDING_VECTOR \
1032         perf_pending_interrupt smp_perf_pending_interrupt
1033 #endif
1034
1035 /*
1036  * Exception entry points.
1037  */
1038 .macro zeroentry sym do_sym
1039 ENTRY(\sym)
1040         INTR_FRAME
1041         PARAVIRT_ADJUST_EXCEPTION_FRAME
1042         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1043         subq $15*8,%rsp
1044         CFI_ADJUST_CFA_OFFSET 15*8
1045         call error_entry
1046         DEFAULT_FRAME 0
1047         movq %rsp,%rdi          /* pt_regs pointer */
1048         xorl %esi,%esi          /* no error code */
1049         call \do_sym
1050         jmp error_exit          /* %ebx: no swapgs flag */
1051         CFI_ENDPROC
1052 END(\sym)
1053 .endm
1054
1055 .macro paranoidzeroentry sym do_sym
1056 ENTRY(\sym)
1057         INTR_FRAME
1058         PARAVIRT_ADJUST_EXCEPTION_FRAME
1059         pushq $-1               /* ORIG_RAX: no syscall to restart */
1060         CFI_ADJUST_CFA_OFFSET 8
1061         subq $15*8, %rsp
1062         call save_paranoid
1063         TRACE_IRQS_OFF
1064         movq %rsp,%rdi          /* pt_regs pointer */
1065         xorl %esi,%esi          /* no error code */
1066         call \do_sym
1067         jmp paranoid_exit       /* %ebx: no swapgs flag */
1068         CFI_ENDPROC
1069 END(\sym)
1070 .endm
1071
1072 .macro paranoidzeroentry_ist sym do_sym ist
1073 ENTRY(\sym)
1074         INTR_FRAME
1075         PARAVIRT_ADJUST_EXCEPTION_FRAME
1076         pushq $-1               /* ORIG_RAX: no syscall to restart */
1077         CFI_ADJUST_CFA_OFFSET 8
1078         subq $15*8, %rsp
1079         call save_paranoid
1080         TRACE_IRQS_OFF
1081         movq %rsp,%rdi          /* pt_regs pointer */
1082         xorl %esi,%esi          /* no error code */
1083         PER_CPU(init_tss, %rbp)
1084         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1085         call \do_sym
1086         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1087         jmp paranoid_exit       /* %ebx: no swapgs flag */
1088         CFI_ENDPROC
1089 END(\sym)
1090 .endm
1091
1092 .macro errorentry sym do_sym
1093 ENTRY(\sym)
1094         XCPT_FRAME
1095         PARAVIRT_ADJUST_EXCEPTION_FRAME
1096         subq $15*8,%rsp
1097         CFI_ADJUST_CFA_OFFSET 15*8
1098         call error_entry
1099         DEFAULT_FRAME 0
1100         movq %rsp,%rdi                  /* pt_regs pointer */
1101         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1102         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1103         call \do_sym
1104         jmp error_exit                  /* %ebx: no swapgs flag */
1105         CFI_ENDPROC
1106 END(\sym)
1107 .endm
1108
1109         /* error code is on the stack already */
1110 .macro paranoiderrorentry sym do_sym
1111 ENTRY(\sym)
1112         XCPT_FRAME
1113         PARAVIRT_ADJUST_EXCEPTION_FRAME
1114         subq $15*8,%rsp
1115         CFI_ADJUST_CFA_OFFSET 15*8
1116         call save_paranoid
1117         DEFAULT_FRAME 0
1118         TRACE_IRQS_OFF
1119         movq %rsp,%rdi                  /* pt_regs pointer */
1120         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1121         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1122         call \do_sym
1123         jmp paranoid_exit               /* %ebx: no swapgs flag */
1124         CFI_ENDPROC
1125 END(\sym)
1126 .endm
1127
1128 zeroentry divide_error do_divide_error
1129 zeroentry overflow do_overflow
1130 zeroentry bounds do_bounds
1131 zeroentry invalid_op do_invalid_op
1132 zeroentry device_not_available do_device_not_available
1133 paranoiderrorentry double_fault do_double_fault
1134 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1135 errorentry invalid_TSS do_invalid_TSS
1136 errorentry segment_not_present do_segment_not_present
1137 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1138 zeroentry coprocessor_error do_coprocessor_error
1139 errorentry alignment_check do_alignment_check
1140 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1141
1142         /* Reload gs selector with exception handling */
1143         /* edi:  new selector */
1144 ENTRY(native_load_gs_index)
1145         CFI_STARTPROC
1146         pushf
1147         CFI_ADJUST_CFA_OFFSET 8
1148         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1149         SWAPGS
1150 gs_change:
1151         movl %edi,%gs
1152 2:      mfence          /* workaround */
1153         SWAPGS
1154         popf
1155         CFI_ADJUST_CFA_OFFSET -8
1156         ret
1157         CFI_ENDPROC
1158 END(native_load_gs_index)
1159
1160         .section __ex_table,"a"
1161         .align 8
1162         .quad gs_change,bad_gs
1163         .previous
1164         .section .fixup,"ax"
1165         /* running with kernelgs */
1166 bad_gs:
1167         SWAPGS                  /* switch back to user gs */
1168         xorl %eax,%eax
1169         movl %eax,%gs
1170         jmp  2b
1171         .previous
1172
1173 /*
1174  * Create a kernel thread.
1175  *
1176  * C extern interface:
1177  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1178  *
1179  * asm input arguments:
1180  *      rdi: fn, rsi: arg, rdx: flags
1181  */
1182 ENTRY(kernel_thread)
1183         CFI_STARTPROC
1184         FAKE_STACK_FRAME $child_rip
1185         SAVE_ALL
1186
1187         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1188         movq %rdx,%rdi
1189         orq  kernel_thread_flags(%rip),%rdi
1190         movq $-1, %rsi
1191         movq %rsp, %rdx
1192
1193         xorl %r8d,%r8d
1194         xorl %r9d,%r9d
1195
1196         # clone now
1197         call do_fork
1198         movq %rax,RAX(%rsp)
1199         xorl %edi,%edi
1200
1201         /*
1202          * It isn't worth to check for reschedule here,
1203          * so internally to the x86_64 port you can rely on kernel_thread()
1204          * not to reschedule the child before returning, this avoids the need
1205          * of hacks for example to fork off the per-CPU idle tasks.
1206          * [Hopefully no generic code relies on the reschedule -AK]
1207          */
1208         RESTORE_ALL
1209         UNFAKE_STACK_FRAME
1210         ret
1211         CFI_ENDPROC
1212 END(kernel_thread)
1213
1214 ENTRY(child_rip)
1215         pushq $0                # fake return address
1216         CFI_STARTPROC
1217         /*
1218          * Here we are in the child and the registers are set as they were
1219          * at kernel_thread() invocation in the parent.
1220          */
1221         movq %rdi, %rax
1222         movq %rsi, %rdi
1223         call *%rax
1224         # exit
1225         mov %eax, %edi
1226         call do_exit
1227         ud2                     # padding for call trace
1228         CFI_ENDPROC
1229 END(child_rip)
1230
1231 /*
1232  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1233  *
1234  * C extern interface:
1235  *       extern long execve(char *name, char **argv, char **envp)
1236  *
1237  * asm input arguments:
1238  *      rdi: name, rsi: argv, rdx: envp
1239  *
1240  * We want to fallback into:
1241  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1242  *
1243  * do_sys_execve asm fallback arguments:
1244  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1245  */
1246 ENTRY(kernel_execve)
1247         CFI_STARTPROC
1248         FAKE_STACK_FRAME $0
1249         SAVE_ALL
1250         movq %rsp,%rcx
1251         call sys_execve
1252         movq %rax, RAX(%rsp)
1253         RESTORE_REST
1254         testq %rax,%rax
1255         je int_ret_from_sys_call
1256         RESTORE_ARGS
1257         UNFAKE_STACK_FRAME
1258         ret
1259         CFI_ENDPROC
1260 END(kernel_execve)
1261
1262 /* Call softirq on interrupt stack. Interrupts are off. */
1263 ENTRY(call_softirq)
1264         CFI_STARTPROC
1265         push %rbp
1266         CFI_ADJUST_CFA_OFFSET   8
1267         CFI_REL_OFFSET rbp,0
1268         mov  %rsp,%rbp
1269         CFI_DEF_CFA_REGISTER rbp
1270         incl PER_CPU_VAR(irq_count)
1271         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1272         push  %rbp                      # backlink for old unwinder
1273         call __do_softirq
1274         leaveq
1275         CFI_DEF_CFA_REGISTER    rsp
1276         CFI_ADJUST_CFA_OFFSET   -8
1277         decl PER_CPU_VAR(irq_count)
1278         ret
1279         CFI_ENDPROC
1280 END(call_softirq)
1281
1282 #ifdef CONFIG_XEN
1283 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1284
1285 /*
1286  * A note on the "critical region" in our callback handler.
1287  * We want to avoid stacking callback handlers due to events occurring
1288  * during handling of the last event. To do this, we keep events disabled
1289  * until we've done all processing. HOWEVER, we must enable events before
1290  * popping the stack frame (can't be done atomically) and so it would still
1291  * be possible to get enough handler activations to overflow the stack.
1292  * Although unlikely, bugs of that kind are hard to track down, so we'd
1293  * like to avoid the possibility.
1294  * So, on entry to the handler we detect whether we interrupted an
1295  * existing activation in its critical region -- if so, we pop the current
1296  * activation and restart the handler using the previous one.
1297  */
1298 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1299         CFI_STARTPROC
1300 /*
1301  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1302  * see the correct pointer to the pt_regs
1303  */
1304         movq %rdi, %rsp            # we don't return, adjust the stack frame
1305         CFI_ENDPROC
1306         DEFAULT_FRAME
1307 11:     incl PER_CPU_VAR(irq_count)
1308         movq %rsp,%rbp
1309         CFI_DEF_CFA_REGISTER rbp
1310         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1311         pushq %rbp                      # backlink for old unwinder
1312         call xen_evtchn_do_upcall
1313         popq %rsp
1314         CFI_DEF_CFA_REGISTER rsp
1315         decl PER_CPU_VAR(irq_count)
1316         jmp  error_exit
1317         CFI_ENDPROC
1318 END(do_hypervisor_callback)
1319
1320 /*
1321  * Hypervisor uses this for application faults while it executes.
1322  * We get here for two reasons:
1323  *  1. Fault while reloading DS, ES, FS or GS
1324  *  2. Fault while executing IRET
1325  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1326  * registers that could be reloaded and zeroed the others.
1327  * Category 2 we fix up by killing the current process. We cannot use the
1328  * normal Linux return path in this case because if we use the IRET hypercall
1329  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1330  * We distinguish between categories by comparing each saved segment register
1331  * with its current contents: any discrepancy means we in category 1.
1332  */
1333 ENTRY(xen_failsafe_callback)
1334         INTR_FRAME 1 (6*8)
1335         /*CFI_REL_OFFSET gs,GS*/
1336         /*CFI_REL_OFFSET fs,FS*/
1337         /*CFI_REL_OFFSET es,ES*/
1338         /*CFI_REL_OFFSET ds,DS*/
1339         CFI_REL_OFFSET r11,8
1340         CFI_REL_OFFSET rcx,0
1341         movw %ds,%cx
1342         cmpw %cx,0x10(%rsp)
1343         CFI_REMEMBER_STATE
1344         jne 1f
1345         movw %es,%cx
1346         cmpw %cx,0x18(%rsp)
1347         jne 1f
1348         movw %fs,%cx
1349         cmpw %cx,0x20(%rsp)
1350         jne 1f
1351         movw %gs,%cx
1352         cmpw %cx,0x28(%rsp)
1353         jne 1f
1354         /* All segments match their saved values => Category 2 (Bad IRET). */
1355         movq (%rsp),%rcx
1356         CFI_RESTORE rcx
1357         movq 8(%rsp),%r11
1358         CFI_RESTORE r11
1359         addq $0x30,%rsp
1360         CFI_ADJUST_CFA_OFFSET -0x30
1361         pushq_cfi $0    /* RIP */
1362         pushq_cfi %r11
1363         pushq_cfi %rcx
1364         jmp general_protection
1365         CFI_RESTORE_STATE
1366 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1367         movq (%rsp),%rcx
1368         CFI_RESTORE rcx
1369         movq 8(%rsp),%r11
1370         CFI_RESTORE r11
1371         addq $0x30,%rsp
1372         CFI_ADJUST_CFA_OFFSET -0x30
1373         pushq_cfi $0
1374         SAVE_ALL
1375         jmp error_exit
1376         CFI_ENDPROC
1377 END(xen_failsafe_callback)
1378
1379 #endif /* CONFIG_XEN */
1380
1381 /*
1382  * Some functions should be protected against kprobes
1383  */
1384         .pushsection .kprobes.text, "ax"
1385
1386 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1387 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1388 paranoiderrorentry stack_segment do_stack_segment
1389 errorentry general_protection do_general_protection
1390 errorentry page_fault do_page_fault
1391 #ifdef CONFIG_X86_MCE
1392 paranoidzeroentry machine_check do_machine_check
1393 #endif
1394
1395         /*
1396          * "Paranoid" exit path from exception stack.
1397          * Paranoid because this is used by NMIs and cannot take
1398          * any kernel state for granted.
1399          * We don't do kernel preemption checks here, because only
1400          * NMI should be common and it does not enable IRQs and
1401          * cannot get reschedule ticks.
1402          *
1403          * "trace" is 0 for the NMI handler only, because irq-tracing
1404          * is fundamentally NMI-unsafe. (we cannot change the soft and
1405          * hard flags at once, atomically)
1406          */
1407
1408         /* ebx: no swapgs flag */
1409 ENTRY(paranoid_exit)
1410         INTR_FRAME
1411         DISABLE_INTERRUPTS(CLBR_NONE)
1412         TRACE_IRQS_OFF
1413         testl %ebx,%ebx                         /* swapgs needed? */
1414         jnz paranoid_restore
1415         testl $3,CS(%rsp)
1416         jnz   paranoid_userspace
1417 paranoid_swapgs:
1418         TRACE_IRQS_IRETQ 0
1419         SWAPGS_UNSAFE_STACK
1420         RESTORE_ALL 8
1421         jmp irq_return
1422 paranoid_restore:
1423         TRACE_IRQS_IRETQ 0
1424         RESTORE_ALL 8
1425         jmp irq_return
1426 paranoid_userspace:
1427         GET_THREAD_INFO(%rcx)
1428         movl TI_flags(%rcx),%ebx
1429         andl $_TIF_WORK_MASK,%ebx
1430         jz paranoid_swapgs
1431         movq %rsp,%rdi                  /* &pt_regs */
1432         call sync_regs
1433         movq %rax,%rsp                  /* switch stack for scheduling */
1434         testl $_TIF_NEED_RESCHED,%ebx
1435         jnz paranoid_schedule
1436         movl %ebx,%edx                  /* arg3: thread flags */
1437         TRACE_IRQS_ON
1438         ENABLE_INTERRUPTS(CLBR_NONE)
1439         xorl %esi,%esi                  /* arg2: oldset */
1440         movq %rsp,%rdi                  /* arg1: &pt_regs */
1441         call do_notify_resume
1442         DISABLE_INTERRUPTS(CLBR_NONE)
1443         TRACE_IRQS_OFF
1444         jmp paranoid_userspace
1445 paranoid_schedule:
1446         TRACE_IRQS_ON
1447         ENABLE_INTERRUPTS(CLBR_ANY)
1448         call schedule
1449         DISABLE_INTERRUPTS(CLBR_ANY)
1450         TRACE_IRQS_OFF
1451         jmp paranoid_userspace
1452         CFI_ENDPROC
1453 END(paranoid_exit)
1454
1455 /*
1456  * Exception entry point. This expects an error code/orig_rax on the stack.
1457  * returns in "no swapgs flag" in %ebx.
1458  */
1459 ENTRY(error_entry)
1460         XCPT_FRAME
1461         CFI_ADJUST_CFA_OFFSET 15*8
1462         /* oldrax contains error code */
1463         cld
1464         movq_cfi rdi, RDI+8
1465         movq_cfi rsi, RSI+8
1466         movq_cfi rdx, RDX+8
1467         movq_cfi rcx, RCX+8
1468         movq_cfi rax, RAX+8
1469         movq_cfi  r8,  R8+8
1470         movq_cfi  r9,  R9+8
1471         movq_cfi r10, R10+8
1472         movq_cfi r11, R11+8
1473         movq_cfi rbx, RBX+8
1474         movq_cfi rbp, RBP+8
1475         movq_cfi r12, R12+8
1476         movq_cfi r13, R13+8
1477         movq_cfi r14, R14+8
1478         movq_cfi r15, R15+8
1479         xorl %ebx,%ebx
1480         testl $3,CS+8(%rsp)
1481         je error_kernelspace
1482 error_swapgs:
1483         SWAPGS
1484 error_sti:
1485         TRACE_IRQS_OFF
1486         ret
1487         CFI_ENDPROC
1488
1489 /*
1490  * There are two places in the kernel that can potentially fault with
1491  * usergs. Handle them here. The exception handlers after iret run with
1492  * kernel gs again, so don't set the user space flag. B stepping K8s
1493  * sometimes report an truncated RIP for IRET exceptions returning to
1494  * compat mode. Check for these here too.
1495  */
1496 error_kernelspace:
1497         incl %ebx
1498         leaq irq_return(%rip),%rcx
1499         cmpq %rcx,RIP+8(%rsp)
1500         je error_swapgs
1501         movl %ecx,%ecx  /* zero extend */
1502         cmpq %rcx,RIP+8(%rsp)
1503         je error_swapgs
1504         cmpq $gs_change,RIP+8(%rsp)
1505         je error_swapgs
1506         jmp error_sti
1507 END(error_entry)
1508
1509
1510 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1511 ENTRY(error_exit)
1512         DEFAULT_FRAME
1513         movl %ebx,%eax
1514         RESTORE_REST
1515         DISABLE_INTERRUPTS(CLBR_NONE)
1516         TRACE_IRQS_OFF
1517         GET_THREAD_INFO(%rcx)
1518         testl %eax,%eax
1519         jne retint_kernel
1520         LOCKDEP_SYS_EXIT_IRQ
1521         movl TI_flags(%rcx),%edx
1522         movl $_TIF_WORK_MASK,%edi
1523         andl %edi,%edx
1524         jnz retint_careful
1525         jmp retint_swapgs
1526         CFI_ENDPROC
1527 END(error_exit)
1528
1529
1530         /* runs on exception stack */
1531 ENTRY(nmi)
1532         INTR_FRAME
1533         PARAVIRT_ADJUST_EXCEPTION_FRAME
1534         pushq_cfi $-1
1535         subq $15*8, %rsp
1536         CFI_ADJUST_CFA_OFFSET 15*8
1537         call save_paranoid
1538         DEFAULT_FRAME 0
1539         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1540         movq %rsp,%rdi
1541         movq $-1,%rsi
1542         call do_nmi
1543 #ifdef CONFIG_TRACE_IRQFLAGS
1544         /* paranoidexit; without TRACE_IRQS_OFF */
1545         /* ebx: no swapgs flag */
1546         DISABLE_INTERRUPTS(CLBR_NONE)
1547         testl %ebx,%ebx                         /* swapgs needed? */
1548         jnz nmi_restore
1549         testl $3,CS(%rsp)
1550         jnz nmi_userspace
1551 nmi_swapgs:
1552         SWAPGS_UNSAFE_STACK
1553 nmi_restore:
1554         RESTORE_ALL 8
1555         jmp irq_return
1556 nmi_userspace:
1557         GET_THREAD_INFO(%rcx)
1558         movl TI_flags(%rcx),%ebx
1559         andl $_TIF_WORK_MASK,%ebx
1560         jz nmi_swapgs
1561         movq %rsp,%rdi                  /* &pt_regs */
1562         call sync_regs
1563         movq %rax,%rsp                  /* switch stack for scheduling */
1564         testl $_TIF_NEED_RESCHED,%ebx
1565         jnz nmi_schedule
1566         movl %ebx,%edx                  /* arg3: thread flags */
1567         ENABLE_INTERRUPTS(CLBR_NONE)
1568         xorl %esi,%esi                  /* arg2: oldset */
1569         movq %rsp,%rdi                  /* arg1: &pt_regs */
1570         call do_notify_resume
1571         DISABLE_INTERRUPTS(CLBR_NONE)
1572         jmp nmi_userspace
1573 nmi_schedule:
1574         ENABLE_INTERRUPTS(CLBR_ANY)
1575         call schedule
1576         DISABLE_INTERRUPTS(CLBR_ANY)
1577         jmp nmi_userspace
1578         CFI_ENDPROC
1579 #else
1580         jmp paranoid_exit
1581         CFI_ENDPROC
1582 #endif
1583 END(nmi)
1584
1585 ENTRY(ignore_sysret)
1586         CFI_STARTPROC
1587         mov $-ENOSYS,%eax
1588         sysret
1589         CFI_ENDPROC
1590 END(ignore_sysret)
1591
1592 /*
1593  * End of kprobes section
1594  */
1595         .popsection