Pileus Git - ~andy/linux/blob - arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/irqflags.h>
  16 #include <linux/linkage.h>
  17
  18 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  19 #include <linux/elf-em.h>
  20 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  21 #define __AUDIT_ARCH_LE    0x40000000
  22
  23 #ifndef CONFIG_AUDITSYSCALL
  24 #define sysexit_audit ia32_ret_from_sys_call
  25 #define sysretl_audit ia32_ret_from_sys_call
  26 #endif
  27
  28         .section .entry.text, "ax"
  29
  30 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  31
  32         .macro IA32_ARG_FIXUP noebp=0
  33         movl    %edi,%r8d
  34         .if \noebp
  35         .else
  36         movl    %ebp,%r9d
  37         .endif
  38         xchg    %ecx,%esi
  39         movl    %ebx,%edi
  40         movl    %edx,%edx       /* zero extension */
  41         .endm
  42
  43         /* clobbers %eax */
  44         .macro  CLEAR_RREGS offset=0, _r9=rax
  45         xorl    %eax,%eax
  46         movq    %rax,\offset+R11(%rsp)
  47         movq    %rax,\offset+R10(%rsp)
  48         movq    %\_r9,\offset+R9(%rsp)
  49         movq    %rax,\offset+R8(%rsp)
  50         .endm
  51
  52         /*
  53          * Reload arg registers from stack in case ptrace changed them.
  54          * We don't reload %eax because syscall_trace_enter() returned
  55          * the %rax value we should see.  Instead, we just truncate that
  56          * value to 32 bits again as we did on entry from user mode.
  57          * If it's a new value set by user_regset during entry tracing,
  58          * this matches the normal truncation of the user-mode value.
  59          * If it's -1 to make us punt the syscall, then (u32)-1 is still
  60          * an appropriately invalid value.
  61          */
  62         .macro LOAD_ARGS32 offset, _r9=0
  63         .if \_r9
  64         movl \offset+16(%rsp),%r9d
  65         .endif
  66         movl \offset+40(%rsp),%ecx
  67         movl \offset+48(%rsp),%edx
  68         movl \offset+56(%rsp),%esi
  69         movl \offset+64(%rsp),%edi
  70         movl %eax,%eax                  /* zero extension */
  71         .endm
  72
  73         .macro CFI_STARTPROC32 simple
  74         CFI_STARTPROC   \simple
  75         CFI_UNDEFINED   r8
  76         CFI_UNDEFINED   r9
  77         CFI_UNDEFINED   r10
  78         CFI_UNDEFINED   r11
  79         CFI_UNDEFINED   r12
  80         CFI_UNDEFINED   r13
  81         CFI_UNDEFINED   r14
  82         CFI_UNDEFINED   r15
  83         .endm
  84
  85 #ifdef CONFIG_PARAVIRT
  86 ENTRY(native_usergs_sysret32)
  87         swapgs
  88         sysretl
  89 ENDPROC(native_usergs_sysret32)
  90
  91 ENTRY(native_irq_enable_sysexit)
  92         swapgs
  93         sti
  94         sysexit
  95 ENDPROC(native_irq_enable_sysexit)
  96 #endif
  97
  98 /*
  99  * 32bit SYSENTER instruction entry.
 100  *
 101  * Arguments:
 102  * %eax System call number.
 103  * %ebx Arg1
 104  * %ecx Arg2
 105  * %edx Arg3
 106  * %esi Arg4
 107  * %edi Arg5
 108  * %ebp user stack
 109  * 0(%ebp) Arg6
 110  *
 111  * Interrupts off.
 112  *
 113  * This is purely a fast path. For anything complicated we use the int 0x80
 114  * path below.  Set up a complete hardware stack frame to share code
 115  * with the int 0x80 path.
 116  */
 117 ENTRY(ia32_sysenter_target)
 118         CFI_STARTPROC32 simple
 119         CFI_SIGNAL_FRAME
 120         CFI_DEF_CFA     rsp,0
 121         CFI_REGISTER    rsp,rbp
 122         SWAPGS_UNSAFE_STACK
 123         movq    PER_CPU_VAR(kernel_stack), %rsp
 124         addq    $(KERNEL_STACK_OFFSET),%rsp
 125         /*
 126          * No need to follow this irqs on/off section: the syscall
 127          * disabled irqs, here we enable it straight after entry:
 128          */
 129         ENABLE_INTERRUPTS(CLBR_NONE)
 130         movl    %ebp,%ebp               /* zero extension */
 131         pushq_cfi $__USER32_DS
 132         /*CFI_REL_OFFSET ss,0*/
 133         pushq_cfi %rbp
 134         CFI_REL_OFFSET rsp,0
 135         pushfq_cfi
 136         /*CFI_REL_OFFSET rflags,0*/
 137         movl    TI_sysenter_return+THREAD_INFO(%rsp,3*8-KERNEL_STACK_OFFSET),%r10d
 138         CFI_REGISTER rip,r10
 139         pushq_cfi $__USER32_CS
 140         /*CFI_REL_OFFSET cs,0*/
 141         movl    %eax, %eax
 142         pushq_cfi %r10
 143         CFI_REL_OFFSET rip,0
 144         pushq_cfi %rax
 145         cld
 146         SAVE_ARGS 0,1,0
 147         /* no need to do an access_ok check here because rbp has been
 148            32bit zero extended */
 149 1:      movl    (%rbp),%ebp
 150         .section __ex_table,"a"
 151         .quad 1b,ia32_badarg
 152         .previous
 153         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 154         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 155         CFI_REMEMBER_STATE
 156         jnz  sysenter_tracesys
 157         cmpq    $(IA32_NR_syscalls-1),%rax
 158         ja      ia32_badsys
 159 sysenter_do_call:
 160         IA32_ARG_FIXUP
 161 sysenter_dispatch:
 162         call    *ia32_sys_call_table(,%rax,8)
 163         movq    %rax,RAX-ARGOFFSET(%rsp)
 164         DISABLE_INTERRUPTS(CLBR_NONE)
 165         TRACE_IRQS_OFF
 166         testl   $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 167         jnz     sysexit_audit
 168 sysexit_from_sys_call:
 169         andl    $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 170         /* clear IF, that popfq doesn't enable interrupts early */
 171         andl  $~0x200,EFLAGS-R11(%rsp)
 172         movl    RIP-R11(%rsp),%edx              /* User %eip */
 173         CFI_REGISTER rip,rdx
 174         RESTORE_ARGS 0,24,0,0,0,0
 175         xorq    %r8,%r8
 176         xorq    %r9,%r9
 177         xorq    %r10,%r10
 178         xorq    %r11,%r11
 179         popfq_cfi
 180         /*CFI_RESTORE rflags*/
 181         popq_cfi %rcx                           /* User %esp */
 182         CFI_REGISTER rsp,rcx
 183         TRACE_IRQS_ON
 184         ENABLE_INTERRUPTS_SYSEXIT32
 185
 186 #ifdef CONFIG_AUDITSYSCALL
 187         .macro auditsys_entry_common
 188         movl %esi,%r9d                  /* 6th arg: 4th syscall arg */
 189         movl %edx,%r8d                  /* 5th arg: 3rd syscall arg */
 190         /* (already in %ecx)               4th arg: 2nd syscall arg */
 191         movl %ebx,%edx                  /* 3rd arg: 1st syscall arg */
 192         movl %eax,%esi                  /* 2nd arg: syscall number */
 193         movl $AUDIT_ARCH_I386,%edi      /* 1st arg: audit arch */
 194         call audit_syscall_entry
 195         movl RAX-ARGOFFSET(%rsp),%eax   /* reload syscall number */
 196         cmpq $(IA32_NR_syscalls-1),%rax
 197         ja ia32_badsys
 198         movl %ebx,%edi                  /* reload 1st syscall arg */
 199         movl RCX-ARGOFFSET(%rsp),%esi   /* reload 2nd syscall arg */
 200         movl RDX-ARGOFFSET(%rsp),%edx   /* reload 3rd syscall arg */
 201         movl RSI-ARGOFFSET(%rsp),%ecx   /* reload 4th syscall arg */
 202         movl RDI-ARGOFFSET(%rsp),%r8d   /* reload 5th syscall arg */
 203         .endm
 204
 205         .macro auditsys_exit exit
 206         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 207         jnz ia32_ret_from_sys_call
 208         TRACE_IRQS_ON
 209         sti
 210         movl %eax,%esi          /* second arg, syscall return value */
 211         cmpl $0,%eax            /* is it < 0? */
 212         setl %al                /* 1 if so, 0 if not */
 213         movzbl %al,%edi         /* zero-extend that into %edi */
 214         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 215         call audit_syscall_exit
 216         movl RAX-ARGOFFSET(%rsp),%eax   /* reload syscall return value */
 217         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 218         cli
 219         TRACE_IRQS_OFF
 220         testl %edi,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 221         jz \exit
 222         CLEAR_RREGS -ARGOFFSET
 223         jmp int_with_check
 224         .endm
 225
 226 sysenter_auditsys:
 227         CFI_RESTORE_STATE
 228         auditsys_entry_common
 229         movl %ebp,%r9d                  /* reload 6th syscall arg */
 230         jmp sysenter_dispatch
 231
 232 sysexit_audit:
 233         auditsys_exit sysexit_from_sys_call
 234 #endif
 235
 236 sysenter_tracesys:
 237 #ifdef CONFIG_AUDITSYSCALL
 238         testl   $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 239         jz      sysenter_auditsys
 240 #endif
 241         SAVE_REST
 242         CLEAR_RREGS
 243         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 244         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 245         call    syscall_trace_enter
 246         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 247         RESTORE_REST
 248         cmpq    $(IA32_NR_syscalls-1),%rax
 249         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 250         jmp     sysenter_do_call
 251         CFI_ENDPROC
 252 ENDPROC(ia32_sysenter_target)
 253
 254 /*
 255  * 32bit SYSCALL instruction entry.
 256  *
 257  * Arguments:
 258  * %eax System call number.
 259  * %ebx Arg1
 260  * %ecx return EIP
 261  * %edx Arg3
 262  * %esi Arg4
 263  * %edi Arg5
 264  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 265  * %esp user stack
 266  * 0(%esp) Arg6
 267  *
 268  * Interrupts off.
 269  *
 270  * This is purely a fast path. For anything complicated we use the int 0x80
 271  * path below.  Set up a complete hardware stack frame to share code
 272  * with the int 0x80 path.
 273  */
 274 ENTRY(ia32_cstar_target)
 275         CFI_STARTPROC32 simple
 276         CFI_SIGNAL_FRAME
 277         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 278         CFI_REGISTER    rip,rcx
 279         /*CFI_REGISTER  rflags,r11*/
 280         SWAPGS_UNSAFE_STACK
 281         movl    %esp,%r8d
 282         CFI_REGISTER    rsp,r8
 283         movq    PER_CPU_VAR(kernel_stack),%rsp
 284         /*
 285          * No need to follow this irqs on/off section: the syscall
 286          * disabled irqs and here we enable it straight after entry:
 287          */
 288         ENABLE_INTERRUPTS(CLBR_NONE)
 289         SAVE_ARGS 8,0,0
 290         movl    %eax,%eax       /* zero extension */
 291         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 292         movq    %rcx,RIP-ARGOFFSET(%rsp)
 293         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 294         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 295         movl    %ebp,%ecx
 296         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 297         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 298         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 299         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 300         movq    %r8,RSP-ARGOFFSET(%rsp)
 301         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 302         /* no need to do an access_ok check here because r8 has been
 303            32bit zero extended */
 304         /* hardware stack frame is complete now */
 305 1:      movl    (%r8),%r9d
 306         .section __ex_table,"a"
 307         .quad 1b,ia32_badarg
 308         .previous
 309         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 310         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 311         CFI_REMEMBER_STATE
 312         jnz   cstar_tracesys
 313         cmpq $IA32_NR_syscalls-1,%rax
 314         ja  ia32_badsys
 315 cstar_do_call:
 316         IA32_ARG_FIXUP 1
 317 cstar_dispatch:
 318         call *ia32_sys_call_table(,%rax,8)
 319         movq %rax,RAX-ARGOFFSET(%rsp)
 320         DISABLE_INTERRUPTS(CLBR_NONE)
 321         TRACE_IRQS_OFF
 322         testl $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 323         jnz sysretl_audit
 324 sysretl_from_sys_call:
 325         andl $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 326         RESTORE_ARGS 0,-ARG_SKIP,0,0,0
 327         movl RIP-ARGOFFSET(%rsp),%ecx
 328         CFI_REGISTER rip,rcx
 329         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 330         /*CFI_REGISTER rflags,r11*/
 331         xorq    %r10,%r10
 332         xorq    %r9,%r9
 333         xorq    %r8,%r8
 334         TRACE_IRQS_ON
 335         movl RSP-ARGOFFSET(%rsp),%esp
 336         CFI_RESTORE rsp
 337         USERGS_SYSRET32
 338
 339 #ifdef CONFIG_AUDITSYSCALL
 340 cstar_auditsys:
 341         CFI_RESTORE_STATE
 342         movl %r9d,R9-ARGOFFSET(%rsp)    /* register to be clobbered by call */
 343         auditsys_entry_common
 344         movl R9-ARGOFFSET(%rsp),%r9d    /* reload 6th syscall arg */
 345         jmp cstar_dispatch
 346
 347 sysretl_audit:
 348         auditsys_exit sysretl_from_sys_call
 349 #endif
 350
 351 cstar_tracesys:
 352 #ifdef CONFIG_AUDITSYSCALL
 353         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 354         jz cstar_auditsys
 355 #endif
 356         xchgl %r9d,%ebp
 357         SAVE_REST
 358         CLEAR_RREGS 0, r9
 359         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 360         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 361         call syscall_trace_enter
 362         LOAD_ARGS32 ARGOFFSET, 1  /* reload args from stack in case ptrace changed it */
 363         RESTORE_REST
 364         xchgl %ebp,%r9d
 365         cmpq $(IA32_NR_syscalls-1),%rax
 366         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 367         jmp cstar_do_call
 368 END(ia32_cstar_target)
 369
 370 ia32_badarg:
 371         movq $-EFAULT,%rax
 372         jmp ia32_sysret
 373         CFI_ENDPROC
 374
 375 /*
 376  * Emulated IA32 system calls via int 0x80.
 377  *
 378  * Arguments:
 379  * %eax System call number.
 380  * %ebx Arg1
 381  * %ecx Arg2
 382  * %edx Arg3
 383  * %esi Arg4
 384  * %edi Arg5
 385  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 386  *
 387  * Notes:
 388  * Uses the same stack frame as the x86-64 version.
 389  * All registers except %eax must be saved (but ptrace may violate that)
 390  * Arguments are zero extended. For system calls that want sign extension and
 391  * take long arguments a wrapper is needed. Most calls can just be called
 392  * directly.
 393  * Assumes it is only called from user space and entered with interrupts off.
 394  */
 395
 396 ENTRY(ia32_syscall)
 397         CFI_STARTPROC32 simple
 398         CFI_SIGNAL_FRAME
 399         CFI_DEF_CFA     rsp,SS+8-RIP
 400         /*CFI_REL_OFFSET        ss,SS-RIP*/
 401         CFI_REL_OFFSET  rsp,RSP-RIP
 402         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 403         /*CFI_REL_OFFSET        cs,CS-RIP*/
 404         CFI_REL_OFFSET  rip,RIP-RIP
 405         PARAVIRT_ADJUST_EXCEPTION_FRAME
 406         SWAPGS
 407         /*
 408          * No need to follow this irqs on/off section: the syscall
 409          * disabled irqs and here we enable it straight after entry:
 410          */
 411         ENABLE_INTERRUPTS(CLBR_NONE)
 412         movl %eax,%eax
 413         pushq_cfi %rax
 414         cld
 415         /* note the registers are not zero extended to the sf.
 416            this could be a problem. */
 417         SAVE_ARGS 0,1,0
 418         orl $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 419         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 420         jnz ia32_tracesys
 421         cmpq $(IA32_NR_syscalls-1),%rax
 422         ja ia32_badsys
 423 ia32_do_call:
 424         IA32_ARG_FIXUP
 425         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 426 ia32_sysret:
 427         movq %rax,RAX-ARGOFFSET(%rsp)
 428 ia32_ret_from_sys_call:
 429         CLEAR_RREGS -ARGOFFSET
 430         jmp int_ret_from_sys_call
 431
 432 ia32_tracesys:
 433         SAVE_REST
 434         CLEAR_RREGS
 435         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 436         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 437         call syscall_trace_enter
 438         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 439         RESTORE_REST
 440         cmpq $(IA32_NR_syscalls-1),%rax
 441         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 442         jmp ia32_do_call
 443 END(ia32_syscall)
 444
 445 ia32_badsys:
 446         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 447         movq $-ENOSYS,%rax
 448         jmp ia32_sysret
 449
 450 quiet_ni_syscall:
 451         movq $-ENOSYS,%rax
 452         ret
 453         CFI_ENDPROC
 454
 455         .macro PTREGSCALL label, func, arg
 456         ALIGN
 457 GLOBAL(\label)
 458         leaq \func(%rip),%rax
 459         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 460         jmp  ia32_ptregs_common
 461         .endm
 462
 463         CFI_STARTPROC32
 464
 465         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 466         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 467         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 468         PTREGSCALL stub32_execve, sys32_execve, %rcx
 469         PTREGSCALL stub32_fork, sys_fork, %rdi
 470         PTREGSCALL stub32_clone, sys32_clone, %rdx
 471         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 472         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 473
 474         ALIGN
 475 ia32_ptregs_common:
 476         popq %r11
 477         CFI_ENDPROC
 478         CFI_STARTPROC32 simple
 479         CFI_SIGNAL_FRAME
 480         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 481         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 482         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 483         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 484         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 485         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 486         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 487 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 488 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 489         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 490 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 491         SAVE_REST
 492         call *%rax
 493         RESTORE_REST
 494         jmp  ia32_sysret        /* misbalances the return cache */
 495         CFI_ENDPROC
 496 END(ia32_ptregs_common)
 497
 498         .section .rodata,"a"
 499         .align 8
 500 ia32_sys_call_table:
 501         .quad sys_restart_syscall
 502         .quad sys_exit
 503         .quad stub32_fork
 504         .quad sys_read
 505         .quad sys_write
 506         .quad compat_sys_open           /* 5 */
 507         .quad sys_close
 508         .quad sys32_waitpid
 509         .quad sys_creat
 510         .quad sys_link
 511         .quad sys_unlink                /* 10 */
 512         .quad stub32_execve
 513         .quad sys_chdir
 514         .quad compat_sys_time
 515         .quad sys_mknod
 516         .quad sys_chmod         /* 15 */
 517         .quad sys_lchown16
 518         .quad quiet_ni_syscall                  /* old break syscall holder */
 519         .quad sys_stat
 520         .quad sys32_lseek
 521         .quad sys_getpid                /* 20 */
 522         .quad compat_sys_mount  /* mount  */
 523         .quad sys_oldumount     /* old_umount  */
 524         .quad sys_setuid16
 525         .quad sys_getuid16
 526         .quad compat_sys_stime  /* stime */             /* 25 */
 527         .quad compat_sys_ptrace /* ptrace */
 528         .quad sys_alarm
 529         .quad sys_fstat /* (old)fstat */
 530         .quad sys_pause
 531         .quad compat_sys_utime  /* 30 */
 532         .quad quiet_ni_syscall  /* old stty syscall holder */
 533         .quad quiet_ni_syscall  /* old gtty syscall holder */
 534         .quad sys_access
 535         .quad sys_nice
 536         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 537         .quad sys_sync
 538         .quad sys32_kill
 539         .quad sys_rename
 540         .quad sys_mkdir
 541         .quad sys_rmdir         /* 40 */
 542         .quad sys_dup
 543         .quad sys_pipe
 544         .quad compat_sys_times
 545         .quad quiet_ni_syscall                  /* old prof syscall holder */
 546         .quad sys_brk           /* 45 */
 547         .quad sys_setgid16
 548         .quad sys_getgid16
 549         .quad sys_signal
 550         .quad sys_geteuid16
 551         .quad sys_getegid16     /* 50 */
 552         .quad sys_acct
 553         .quad sys_umount                        /* new_umount */
 554         .quad quiet_ni_syscall                  /* old lock syscall holder */
 555         .quad compat_sys_ioctl
 556         .quad compat_sys_fcntl64                /* 55 */
 557         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 558         .quad sys_setpgid
 559         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 560         .quad sys_olduname
 561         .quad sys_umask         /* 60 */
 562         .quad sys_chroot
 563         .quad compat_sys_ustat
 564         .quad sys_dup2
 565         .quad sys_getppid
 566         .quad sys_getpgrp               /* 65 */
 567         .quad sys_setsid
 568         .quad sys32_sigaction
 569         .quad sys_sgetmask
 570         .quad sys_ssetmask
 571         .quad sys_setreuid16    /* 70 */
 572         .quad sys_setregid16
 573         .quad sys32_sigsuspend
 574         .quad compat_sys_sigpending
 575         .quad sys_sethostname
 576         .quad compat_sys_setrlimit      /* 75 */
 577         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 578         .quad compat_sys_getrusage
 579         .quad compat_sys_gettimeofday
 580         .quad compat_sys_settimeofday
 581         .quad sys_getgroups16   /* 80 */
 582         .quad sys_setgroups16
 583         .quad compat_sys_old_select
 584         .quad sys_symlink
 585         .quad sys_lstat
 586         .quad sys_readlink              /* 85 */
 587         .quad sys_uselib
 588         .quad sys_swapon
 589         .quad sys_reboot
 590         .quad compat_sys_old_readdir
 591         .quad sys32_mmap                /* 90 */
 592         .quad sys_munmap
 593         .quad sys_truncate
 594         .quad sys_ftruncate
 595         .quad sys_fchmod
 596         .quad sys_fchown16              /* 95 */
 597         .quad sys_getpriority
 598         .quad sys_setpriority
 599         .quad quiet_ni_syscall                  /* old profil syscall holder */
 600         .quad compat_sys_statfs
 601         .quad compat_sys_fstatfs                /* 100 */
 602         .quad sys_ioperm
 603         .quad compat_sys_socketcall
 604         .quad sys_syslog
 605         .quad compat_sys_setitimer
 606         .quad compat_sys_getitimer      /* 105 */
 607         .quad compat_sys_newstat
 608         .quad compat_sys_newlstat
 609         .quad compat_sys_newfstat
 610         .quad sys_uname
 611         .quad stub32_iopl               /* 110 */
 612         .quad sys_vhangup
 613         .quad quiet_ni_syscall  /* old "idle" system call */
 614         .quad sys32_vm86_warning        /* vm86old */
 615         .quad compat_sys_wait4
 616         .quad sys_swapoff               /* 115 */
 617         .quad compat_sys_sysinfo
 618         .quad sys32_ipc
 619         .quad sys_fsync
 620         .quad stub32_sigreturn
 621         .quad stub32_clone              /* 120 */
 622         .quad sys_setdomainname
 623         .quad sys_newuname
 624         .quad sys_modify_ldt
 625         .quad compat_sys_adjtimex
 626         .quad sys32_mprotect            /* 125 */
 627         .quad compat_sys_sigprocmask
 628         .quad quiet_ni_syscall          /* create_module */
 629         .quad sys_init_module
 630         .quad sys_delete_module
 631         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 632         .quad sys32_quotactl
 633         .quad sys_getpgid
 634         .quad sys_fchdir
 635         .quad quiet_ni_syscall  /* bdflush */
 636         .quad sys_sysfs         /* 135 */
 637         .quad sys_personality
 638         .quad quiet_ni_syscall  /* for afs_syscall */
 639         .quad sys_setfsuid16
 640         .quad sys_setfsgid16
 641         .quad sys_llseek                /* 140 */
 642         .quad compat_sys_getdents
 643         .quad compat_sys_select
 644         .quad sys_flock
 645         .quad sys_msync
 646         .quad compat_sys_readv          /* 145 */
 647         .quad compat_sys_writev
 648         .quad sys_getsid
 649         .quad sys_fdatasync
 650         .quad compat_sys_sysctl /* sysctl */
 651         .quad sys_mlock         /* 150 */
 652         .quad sys_munlock
 653         .quad sys_mlockall
 654         .quad sys_munlockall
 655         .quad sys_sched_setparam
 656         .quad sys_sched_getparam   /* 155 */
 657         .quad sys_sched_setscheduler
 658         .quad sys_sched_getscheduler
 659         .quad sys_sched_yield
 660         .quad sys_sched_get_priority_max
 661         .quad sys_sched_get_priority_min  /* 160 */
 662         .quad sys32_sched_rr_get_interval
 663         .quad compat_sys_nanosleep
 664         .quad sys_mremap
 665         .quad sys_setresuid16
 666         .quad sys_getresuid16   /* 165 */
 667         .quad sys32_vm86_warning        /* vm86 */
 668         .quad quiet_ni_syscall  /* query_module */
 669         .quad sys_poll
 670         .quad quiet_ni_syscall /* old nfsservctl */
 671         .quad sys_setresgid16   /* 170 */
 672         .quad sys_getresgid16
 673         .quad sys_prctl
 674         .quad stub32_rt_sigreturn
 675         .quad sys32_rt_sigaction
 676         .quad sys32_rt_sigprocmask      /* 175 */
 677         .quad sys32_rt_sigpending
 678         .quad compat_sys_rt_sigtimedwait
 679         .quad sys32_rt_sigqueueinfo
 680         .quad sys_rt_sigsuspend
 681         .quad sys32_pread               /* 180 */
 682         .quad sys32_pwrite
 683         .quad sys_chown16
 684         .quad sys_getcwd
 685         .quad sys_capget
 686         .quad sys_capset
 687         .quad stub32_sigaltstack
 688         .quad sys32_sendfile
 689         .quad quiet_ni_syscall          /* streams1 */
 690         .quad quiet_ni_syscall          /* streams2 */
 691         .quad stub32_vfork            /* 190 */
 692         .quad compat_sys_getrlimit
 693         .quad sys_mmap_pgoff
 694         .quad sys32_truncate64
 695         .quad sys32_ftruncate64
 696         .quad sys32_stat64              /* 195 */
 697         .quad sys32_lstat64
 698         .quad sys32_fstat64
 699         .quad sys_lchown
 700         .quad sys_getuid
 701         .quad sys_getgid                /* 200 */
 702         .quad sys_geteuid
 703         .quad sys_getegid
 704         .quad sys_setreuid
 705         .quad sys_setregid
 706         .quad sys_getgroups     /* 205 */
 707         .quad sys_setgroups
 708         .quad sys_fchown
 709         .quad sys_setresuid
 710         .quad sys_getresuid
 711         .quad sys_setresgid     /* 210 */
 712         .quad sys_getresgid
 713         .quad sys_chown
 714         .quad sys_setuid
 715         .quad sys_setgid
 716         .quad sys_setfsuid              /* 215 */
 717         .quad sys_setfsgid
 718         .quad sys_pivot_root
 719         .quad sys_mincore
 720         .quad sys_madvise
 721         .quad compat_sys_getdents64     /* 220 getdents64 */
 722         .quad compat_sys_fcntl64
 723         .quad quiet_ni_syscall          /* tux */
 724         .quad quiet_ni_syscall          /* security */
 725         .quad sys_gettid
 726         .quad sys32_readahead   /* 225 */
 727         .quad sys_setxattr
 728         .quad sys_lsetxattr
 729         .quad sys_fsetxattr
 730         .quad sys_getxattr
 731         .quad sys_lgetxattr     /* 230 */
 732         .quad sys_fgetxattr
 733         .quad sys_listxattr
 734         .quad sys_llistxattr
 735         .quad sys_flistxattr
 736         .quad sys_removexattr   /* 235 */
 737         .quad sys_lremovexattr
 738         .quad sys_fremovexattr
 739         .quad sys_tkill
 740         .quad sys_sendfile64
 741         .quad compat_sys_futex          /* 240 */
 742         .quad compat_sys_sched_setaffinity
 743         .quad compat_sys_sched_getaffinity
 744         .quad sys_set_thread_area
 745         .quad sys_get_thread_area
 746         .quad compat_sys_io_setup       /* 245 */
 747         .quad sys_io_destroy
 748         .quad compat_sys_io_getevents
 749         .quad compat_sys_io_submit
 750         .quad sys_io_cancel
 751         .quad sys32_fadvise64           /* 250 */
 752         .quad quiet_ni_syscall  /* free_huge_pages */
 753         .quad sys_exit_group
 754         .quad sys32_lookup_dcookie
 755         .quad sys_epoll_create
 756         .quad sys_epoll_ctl             /* 255 */
 757         .quad sys_epoll_wait
 758         .quad sys_remap_file_pages
 759         .quad sys_set_tid_address
 760         .quad compat_sys_timer_create
 761         .quad compat_sys_timer_settime  /* 260 */
 762         .quad compat_sys_timer_gettime
 763         .quad sys_timer_getoverrun
 764         .quad sys_timer_delete
 765         .quad compat_sys_clock_settime
 766         .quad compat_sys_clock_gettime  /* 265 */
 767         .quad compat_sys_clock_getres
 768         .quad compat_sys_clock_nanosleep
 769         .quad compat_sys_statfs64
 770         .quad compat_sys_fstatfs64
 771         .quad sys_tgkill                /* 270 */
 772         .quad compat_sys_utimes
 773         .quad sys32_fadvise64_64
 774         .quad quiet_ni_syscall  /* sys_vserver */
 775         .quad sys_mbind
 776         .quad compat_sys_get_mempolicy  /* 275 */
 777         .quad sys_set_mempolicy
 778         .quad compat_sys_mq_open
 779         .quad sys_mq_unlink
 780         .quad compat_sys_mq_timedsend
 781         .quad compat_sys_mq_timedreceive        /* 280 */
 782         .quad compat_sys_mq_notify
 783         .quad compat_sys_mq_getsetattr
 784         .quad compat_sys_kexec_load     /* reserved for kexec */
 785         .quad compat_sys_waitid
 786         .quad quiet_ni_syscall          /* 285: sys_altroot */
 787         .quad sys_add_key
 788         .quad sys_request_key
 789         .quad sys_keyctl
 790         .quad sys_ioprio_set
 791         .quad sys_ioprio_get            /* 290 */
 792         .quad sys_inotify_init
 793         .quad sys_inotify_add_watch
 794         .quad sys_inotify_rm_watch
 795         .quad sys_migrate_pages
 796         .quad compat_sys_openat         /* 295 */
 797         .quad sys_mkdirat
 798         .quad sys_mknodat
 799         .quad sys_fchownat
 800         .quad compat_sys_futimesat
 801         .quad sys32_fstatat             /* 300 */
 802         .quad sys_unlinkat
 803         .quad sys_renameat
 804         .quad sys_linkat
 805         .quad sys_symlinkat
 806         .quad sys_readlinkat            /* 305 */
 807         .quad sys_fchmodat
 808         .quad sys_faccessat
 809         .quad compat_sys_pselect6
 810         .quad compat_sys_ppoll
 811         .quad sys_unshare               /* 310 */
 812         .quad compat_sys_set_robust_list
 813         .quad compat_sys_get_robust_list
 814         .quad sys_splice
 815         .quad sys32_sync_file_range
 816         .quad sys_tee                   /* 315 */
 817         .quad compat_sys_vmsplice
 818         .quad compat_sys_move_pages
 819         .quad sys_getcpu
 820         .quad sys_epoll_pwait
 821         .quad compat_sys_utimensat      /* 320 */
 822         .quad compat_sys_signalfd
 823         .quad sys_timerfd_create
 824         .quad sys_eventfd
 825         .quad sys32_fallocate
 826         .quad compat_sys_timerfd_settime        /* 325 */
 827         .quad compat_sys_timerfd_gettime
 828         .quad compat_sys_signalfd4
 829         .quad sys_eventfd2
 830         .quad sys_epoll_create1
 831         .quad sys_dup3                          /* 330 */
 832         .quad sys_pipe2
 833         .quad sys_inotify_init1
 834         .quad compat_sys_preadv
 835         .quad compat_sys_pwritev
 836         .quad compat_sys_rt_tgsigqueueinfo      /* 335 */
 837         .quad sys_perf_event_open
 838         .quad compat_sys_recvmmsg
 839         .quad sys_fanotify_init
 840         .quad sys32_fanotify_mark
 841         .quad sys_prlimit64             /* 340 */
 842         .quad sys_name_to_handle_at
 843         .quad compat_sys_open_by_handle_at
 844         .quad compat_sys_clock_adjtime
 845         .quad sys_syncfs
 846         .quad compat_sys_sendmmsg       /* 345 */
 847         .quad sys_setns
 848         .quad compat_sys_process_vm_readv
 849         .quad compat_sys_process_vm_writev
 850 ia32_syscall_end: