Pileus Git - ~andy/linux/blob - arch/x86/boot/header.S

   1 /*
   2  *      header.S
   3  *
   4  *      Copyright (C) 1991, 1992 Linus Torvalds
   5  *
   6  *      Based on bootsect.S and setup.S
   7  *      modified by more people than can be counted
   8  *
   9  *      Rewritten as a common file by H. Peter Anvin (Apr 2007)
  10  *
  11  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
  12  * addresses must be multiplied by 16 to obtain their respective linear
  13  * addresses. To avoid confusion, linear addresses are written using leading
  14  * hex while segment addresses are written as segment:offset.
  15  *
  16  */
  17
  18 #include <asm/segment.h>
  19 #include <generated/utsrelease.h>
  20 #include <asm/boot.h>
  21 #include <asm/e820.h>
  22 #include <asm/page_types.h>
  23 #include <asm/setup.h>
  24 #include "boot.h"
  25 #include "voffset.h"
  26 #include "zoffset.h"
  27
  28 BOOTSEG         = 0x07C0                /* original address of boot-sector */
  29 SYSSEG          = 0x1000                /* historical load address >> 4 */
  30
  31 #ifndef SVGA_MODE
  32 #define SVGA_MODE ASK_VGA
  33 #endif
  34
  35 #ifndef RAMDISK
  36 #define RAMDISK 0
  37 #endif
  38
  39 #ifndef ROOT_RDONLY
  40 #define ROOT_RDONLY 1
  41 #endif
  42
  43         .code16
  44         .section ".bstext", "ax"
  45
  46         .global bootsect_start
  47 bootsect_start:
  48 #ifdef CONFIG_EFI_STUB
  49         # "MZ", MS-DOS header
  50         .byte 0x4d
  51         .byte 0x5a
  52 #endif
  53
  54         # Normalize the start address
  55         ljmp    $BOOTSEG, $start2
  56
  57 start2:
  58         movw    %cs, %ax
  59         movw    %ax, %ds
  60         movw    %ax, %es
  61         movw    %ax, %ss
  62         xorw    %sp, %sp
  63         sti
  64         cld
  65
  66         movw    $bugger_off_msg, %si
  67
  68 msg_loop:
  69         lodsb
  70         andb    %al, %al
  71         jz      bs_die
  72         movb    $0xe, %ah
  73         movw    $7, %bx
  74         int     $0x10
  75         jmp     msg_loop
  76
  77 bs_die:
  78         # Allow the user to press a key, then reboot
  79         xorw    %ax, %ax
  80         int     $0x16
  81         int     $0x19
  82
  83         # int 0x19 should never return.  In case it does anyway,
  84         # invoke the BIOS reset code...
  85         ljmp    $0xf000,$0xfff0
  86
  87 #ifdef CONFIG_EFI_STUB
  88         .org    0x3c
  89         #
  90         # Offset to the PE header.
  91         #
  92         .long   pe_header
  93 #endif /* CONFIG_EFI_STUB */
  94
  95         .section ".bsdata", "a"
  96 bugger_off_msg:
  97         .ascii  "Direct booting from floppy is no longer supported.\r\n"
  98         .ascii  "Please use a boot loader program instead.\r\n"
  99         .ascii  "\n"
 100         .ascii  "Remove disk and press any key to reboot . . .\r\n"
 101         .byte   0
 102
 103 #ifdef CONFIG_EFI_STUB
 104 pe_header:
 105         .ascii  "PE"
 106         .word   0
 107
 108 coff_header:
 109 #ifdef CONFIG_X86_32
 110         .word   0x14c                           # i386
 111 #else
 112         .word   0x8664                          # x86-64
 113 #endif
 114         .word   2                               # nr_sections
 115         .long   0                               # TimeDateStamp
 116         .long   0                               # PointerToSymbolTable
 117         .long   1                               # NumberOfSymbols
 118         .word   section_table - optional_header # SizeOfOptionalHeader
 119 #ifdef CONFIG_X86_32
 120         .word   0x306                           # Characteristics.
 121                                                 # IMAGE_FILE_32BIT_MACHINE |
 122                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 123                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 124                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 125 #else
 126         .word   0x206                           # Characteristics
 127                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 128                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 129                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 130 #endif
 131
 132 optional_header:
 133 #ifdef CONFIG_X86_32
 134         .word   0x10b                           # PE32 format
 135 #else
 136         .word   0x20b                           # PE32+ format
 137 #endif
 138         .byte   0x02                            # MajorLinkerVersion
 139         .byte   0x14                            # MinorLinkerVersion
 140
 141         # Filled in by build.c
 142         .long   0                               # SizeOfCode
 143
 144         .long   0                               # SizeOfInitializedData
 145         .long   0                               # SizeOfUninitializedData
 146
 147         # Filled in by build.c
 148         .long   0x0000                          # AddressOfEntryPoint
 149
 150         .long   0x0000                          # BaseOfCode
 151 #ifdef CONFIG_X86_32
 152         .long   0                               # data
 153 #endif
 154
 155 extra_header_fields:
 156 #ifdef CONFIG_X86_32
 157         .long   0                               # ImageBase
 158 #else
 159         .quad   0                               # ImageBase
 160 #endif
 161         .long   0x1000                          # SectionAlignment
 162         .long   0x200                           # FileAlignment
 163         .word   0                               # MajorOperatingSystemVersion
 164         .word   0                               # MinorOperatingSystemVersion
 165         .word   0                               # MajorImageVersion
 166         .word   0                               # MinorImageVersion
 167         .word   0                               # MajorSubsystemVersion
 168         .word   0                               # MinorSubsystemVersion
 169         .long   0                               # Win32VersionValue
 170
 171         #
 172         # The size of the bzImage is written in tools/build.c
 173         #
 174         .long   0                               # SizeOfImage
 175
 176         .long   0x200                           # SizeOfHeaders
 177         .long   0                               # CheckSum
 178         .word   0xa                             # Subsystem (EFI application)
 179         .word   0                               # DllCharacteristics
 180 #ifdef CONFIG_X86_32
 181         .long   0                               # SizeOfStackReserve
 182         .long   0                               # SizeOfStackCommit
 183         .long   0                               # SizeOfHeapReserve
 184         .long   0                               # SizeOfHeapCommit
 185 #else
 186         .quad   0                               # SizeOfStackReserve
 187         .quad   0                               # SizeOfStackCommit
 188         .quad   0                               # SizeOfHeapReserve
 189         .quad   0                               # SizeOfHeapCommit
 190 #endif
 191         .long   0                               # LoaderFlags
 192         .long   0x1                             # NumberOfRvaAndSizes
 193
 194         .quad   0                               # ExportTable
 195         .quad   0                               # ImportTable
 196         .quad   0                               # ResourceTable
 197         .quad   0                               # ExceptionTable
 198         .quad   0                               # CertificationTable
 199         .quad   0                               # BaseRelocationTable
 200
 201         # Section table
 202 section_table:
 203         .ascii  ".text"
 204         .byte   0
 205         .byte   0
 206         .byte   0
 207         .long   0
 208         .long   0x0                             # startup_{32,64}
 209         .long   0                               # Size of initialized data
 210                                                 # on disk
 211         .long   0x0                             # startup_{32,64}
 212         .long   0                               # PointerToRelocations
 213         .long   0                               # PointerToLineNumbers
 214         .word   0                               # NumberOfRelocations
 215         .word   0                               # NumberOfLineNumbers
 216         .long   0x60500020                      # Characteristics (section flags)
 217
 218         #
 219         # The EFI application loader requires a relocation section
 220         # because EFI applications are relocatable and not having
 221         # this section seems to confuse it. But since we don't need
 222         # the loader to fixup any relocs for us just fill it with a
 223         # single dummy reloc.
 224         #
 225         .ascii  ".reloc"
 226         .byte   0
 227         .byte   0
 228         .long   reloc_end - reloc_start
 229         .long   reloc_start
 230         .long   reloc_end - reloc_start         # SizeOfRawData
 231         .long   reloc_start                     # PointerToRawData
 232         .long   0                               # PointerToRelocations
 233         .long   0                               # PointerToLineNumbers
 234         .word   0                               # NumberOfRelocations
 235         .word   0                               # NumberOfLineNumbers
 236         .long   0x42100040                      # Characteristics (section flags)
 237 #endif /* CONFIG_EFI_STUB */
 238
 239         # Kernel attributes; used by setup.  This is part 1 of the
 240         # header, from the old boot sector.
 241
 242         .section ".header", "a"
 243         .globl  hdr
 244 hdr:
 245 setup_sects:    .byte 0                 /* Filled in by build.c */
 246 root_flags:     .word ROOT_RDONLY
 247 syssize:        .long 0                 /* Filled in by build.c */
 248 ram_size:       .word 0                 /* Obsolete */
 249 vid_mode:       .word SVGA_MODE
 250 root_dev:       .word 0                 /* Filled in by build.c */
 251 boot_flag:      .word 0xAA55
 252
 253         # offset 512, entry point
 254
 255         .globl  _start
 256 _start:
 257                 # Explicitly enter this as bytes, or the assembler
 258                 # tries to generate a 3-byte jump here, which causes
 259                 # everything else to push off to the wrong offset.
 260                 .byte   0xeb            # short (2-byte) jump
 261                 .byte   start_of_setup-1f
 262 1:
 263
 264         # Part 2 of the header, from the old setup.S
 265
 266                 .ascii  "HdrS"          # header signature
 267                 .word   0x020a          # header version number (>= 0x0105)
 268                                         # or else old loadlin-1.5 will fail)
 269                 .globl realmode_swtch
 270 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
 271 start_sys_seg:  .word   SYSSEG          # obsolete and meaningless, but just
 272                                         # in case something decided to "use" it
 273                 .word   kernel_version-512 # pointing to kernel version string
 274                                         # above section of header is compatible
 275                                         # with loadlin-1.5 (header v1.5). Don't
 276                                         # change it.
 277
 278 type_of_loader: .byte   0               # 0 means ancient bootloader, newer
 279                                         # bootloaders know to change this.
 280                                         # See Documentation/x86/boot.txt for
 281                                         # assigned ids
 282
 283 # flags, unused bits must be zero (RFU) bit within loadflags
 284 loadflags:
 285 LOADED_HIGH     = 1                     # If set, the kernel is loaded high
 286 CAN_USE_HEAP    = 0x80                  # If set, the loader also has set
 287                                         # heap_end_ptr to tell how much
 288                                         # space behind setup.S can be used for
 289                                         # heap purposes.
 290                                         # Only the loader knows what is free
 291                 .byte   LOADED_HIGH
 292
 293 setup_move_size: .word  0x8000          # size to move, when setup is not
 294                                         # loaded at 0x90000. We will move setup
 295                                         # to 0x90000 then just before jumping
 296                                         # into the kernel. However, only the
 297                                         # loader knows how much data behind
 298                                         # us also needs to be loaded.
 299
 300 code32_start:                           # here loaders can put a different
 301                                         # start address for 32-bit code.
 302                 .long   0x100000        # 0x100000 = default for big kernel
 303
 304 ramdisk_image:  .long   0               # address of loaded ramdisk image
 305                                         # Here the loader puts the 32-bit
 306                                         # address where it loaded the image.
 307                                         # This only will be read by the kernel.
 308
 309 ramdisk_size:   .long   0               # its size in bytes
 310
 311 bootsect_kludge:
 312                 .long   0               # obsolete
 313
 314 heap_end_ptr:   .word   _end+STACK_SIZE-512
 315                                         # (Header version 0x0201 or later)
 316                                         # space from here (exclusive) down to
 317                                         # end of setup code can be used by setup
 318                                         # for local heap purposes.
 319
 320 ext_loader_ver:
 321                 .byte   0               # Extended boot loader version
 322 ext_loader_type:
 323                 .byte   0               # Extended boot loader type
 324
 325 cmd_line_ptr:   .long   0               # (Header version 0x0202 or later)
 326                                         # If nonzero, a 32-bit pointer
 327                                         # to the kernel command line.
 328                                         # The command line should be
 329                                         # located between the start of
 330                                         # setup and the end of low
 331                                         # memory (0xa0000), or it may
 332                                         # get overwritten before it
 333                                         # gets read.  If this field is
 334                                         # used, there is no longer
 335                                         # anything magical about the
 336                                         # 0x90000 segment; the setup
 337                                         # can be located anywhere in
 338                                         # low memory 0x10000 or higher.
 339
 340 ramdisk_max:    .long 0x7fffffff
 341                                         # (Header version 0x0203 or later)
 342                                         # The highest safe address for
 343                                         # the contents of an initrd
 344                                         # The current kernel allows up to 4 GB,
 345                                         # but leave it at 2 GB to avoid
 346                                         # possible bootloader bugs.
 347
 348 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 349                                                 #required for protected mode
 350                                                 #kernel
 351 #ifdef CONFIG_RELOCATABLE
 352 relocatable_kernel:    .byte 1
 353 #else
 354 relocatable_kernel:    .byte 0
 355 #endif
 356 min_alignment:          .byte MIN_KERNEL_ALIGN_LG2      # minimum alignment
 357 pad3:                   .word 0
 358
 359 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 360                                                 #added with boot protocol
 361                                                 #version 2.06
 362
 363 hardware_subarch:       .long 0                 # subarchitecture, added with 2.07
 364                                                 # default to 0 for normal x86 PC
 365
 366 hardware_subarch_data:  .quad 0
 367
 368 payload_offset:         .long ZO_input_data
 369 payload_length:         .long ZO_z_input_len
 370
 371 setup_data:             .quad 0                 # 64-bit physical pointer to
 372                                                 # single linked list of
 373                                                 # struct setup_data
 374
 375 pref_address:           .quad LOAD_PHYSICAL_ADDR        # preferred load addr
 376
 377 #define ZO_INIT_SIZE    (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
 378 #define VO_INIT_SIZE    (VO__end - VO__text)
 379 #if ZO_INIT_SIZE > VO_INIT_SIZE
 380 #define INIT_SIZE ZO_INIT_SIZE
 381 #else
 382 #define INIT_SIZE VO_INIT_SIZE
 383 #endif
 384 init_size:              .long INIT_SIZE         # kernel initialization size
 385
 386 # End of setup header #####################################################
 387
 388         .section ".entrytext", "ax"
 389 start_of_setup:
 390 #ifdef SAFE_RESET_DISK_CONTROLLER
 391 # Reset the disk controller.
 392         movw    $0x0000, %ax            # Reset disk controller
 393         movb    $0x80, %dl              # All disks
 394         int     $0x13
 395 #endif
 396
 397 # Force %es = %ds
 398         movw    %ds, %ax
 399         movw    %ax, %es
 400         cld
 401
 402 # Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
 403 # which happened to work by accident for the old code.  Recalculate the stack
 404 # pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
 405 # stack behind its own code, so we can't blindly put it directly past the heap.
 406
 407         movw    %ss, %dx
 408         cmpw    %ax, %dx        # %ds == %ss?
 409         movw    %sp, %dx
 410         je      2f              # -> assume %sp is reasonably set
 411
 412         # Invalid %ss, make up a new stack
 413         movw    $_end, %dx
 414         testb   $CAN_USE_HEAP, loadflags
 415         jz      1f
 416         movw    heap_end_ptr, %dx
 417 1:      addw    $STACK_SIZE, %dx
 418         jnc     2f
 419         xorw    %dx, %dx        # Prevent wraparound
 420
 421 2:      # Now %dx should point to the end of our stack space
 422         andw    $~3, %dx        # dword align (might as well...)
 423         jnz     3f
 424         movw    $0xfffc, %dx    # Make sure we're not zero
 425 3:      movw    %ax, %ss
 426         movzwl  %dx, %esp       # Clear upper half of %esp
 427         sti                     # Now we should have a working stack
 428
 429 # We will have entered with %cs = %ds+0x20, normalize %cs so
 430 # it is on par with the other segments.
 431         pushw   %ds
 432         pushw   $6f
 433         lretw
 434 6:
 435
 436 # Check signature at end of setup
 437         cmpl    $0x5a5aaa55, setup_sig
 438         jne     setup_bad
 439
 440 # Zero the bss
 441         movw    $__bss_start, %di
 442         movw    $_end+3, %cx
 443         xorl    %eax, %eax
 444         subw    %di, %cx
 445         shrw    $2, %cx
 446         rep; stosl
 447
 448 # Jump to C code (should not return)
 449         calll   main
 450
 451 # Setup corrupt somehow...
 452 setup_bad:
 453         movl    $setup_corrupt, %eax
 454         calll   puts
 455         # Fall through...
 456
 457         .globl  die
 458         .type   die, @function
 459 die:
 460         hlt
 461         jmp     die
 462
 463         .size   die, .-die
 464
 465         .section ".initdata", "a"
 466 setup_corrupt:
 467         .byte   7
 468         .string "No setup signature found...\n"
 469
 470         .data
 471 dummy:  .long   0
 472
 473         .section .reloc
 474 reloc_start:
 475         .long   dummy - reloc_start
 476         .long   10
 477         .word   0
 478 reloc_end: