Pileus Git - ~andy/linux/blob - arch/tile/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3 #include <asm/cache.h>
   4 #include <asm/thread_info.h>
   5 #include <hv/hypervisor.h>
   6
   7 /* Text loads starting from the supervisor interrupt vector address. */
   8 #define TEXT_OFFSET MEM_SV_INTRPT
   9
  10 OUTPUT_ARCH(tile)
  11 ENTRY(_start)
  12 jiffies = jiffies_64;
  13
  14 PHDRS
  15 {
  16   intrpt1 PT_LOAD ;
  17   text PT_LOAD ;
  18   data PT_LOAD ;
  19 }
  20 SECTIONS
  21 {
  22   /* Text is loaded with a different VA than data; start with text. */
  23   #undef LOAD_OFFSET
  24   #define LOAD_OFFSET TEXT_OFFSET
  25
  26   /* Interrupt vectors */
  27   .intrpt1 (LOAD_OFFSET) : AT ( 0 )   /* put at the start of physical memory */
  28   {
  29     _text = .;
  30     *(.intrpt1)
  31   } :intrpt1 =0
  32
  33   /* Hypervisor call vectors */
  34   #include "hvglue.lds"
  35
  36   /* Now the real code */
  37   . = ALIGN(0x20000);
  38   _stext = .;
  39   .text : AT (ADDR(.text) - LOAD_OFFSET) {
  40     HEAD_TEXT
  41     SCHED_TEXT
  42     LOCK_TEXT
  43     __fix_text_end = .;   /* tile-cpack won't rearrange before this */
  44     TEXT_TEXT
  45     *(.text.*)
  46     *(.coldtext*)
  47     *(.fixup)
  48     *(.gnu.warning)
  49   } :text =0
  50   _etext = .;
  51
  52   /* "Init" is divided into two areas with very different virtual addresses. */
  53   INIT_TEXT_SECTION(PAGE_SIZE)
  54
  55   /* Now we skip back to PAGE_OFFSET for the data. */
  56   . = (. - TEXT_OFFSET + PAGE_OFFSET);
  57   #undef LOAD_OFFSET
  58   #define LOAD_OFFSET PAGE_OFFSET
  59
  60   . = ALIGN(PAGE_SIZE);
  61   __init_begin = .;
  62   VMLINUX_SYMBOL(_sinitdata) = .;
  63   INIT_DATA_SECTION(16) :data =0
  64   PERCPU_SECTION(L2_CACHE_BYTES)
  65   . = ALIGN(PAGE_SIZE);
  66   VMLINUX_SYMBOL(_einitdata) = .;
  67   __init_end = .;
  68
  69   _sdata = .;                   /* Start of data section */
  70
  71   RO_DATA_SECTION(PAGE_SIZE)
  72
  73   /* initially writeable, then read-only */
  74   . = ALIGN(PAGE_SIZE);
  75   __w1data_begin = .;
  76   .w1data : AT(ADDR(.w1data) - LOAD_OFFSET) {
  77     VMLINUX_SYMBOL(__w1data_begin) = .;
  78     *(.w1data)
  79     VMLINUX_SYMBOL(__w1data_end) = .;
  80   }
  81
  82   RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  83
  84   _edata = .;
  85
  86   EXCEPTION_TABLE(L2_CACHE_BYTES)
  87   NOTES
  88
  89
  90   BSS_SECTION(8, PAGE_SIZE, 1)
  91   _end = . ;
  92
  93   STABS_DEBUG
  94   DWARF_DEBUG
  95
  96   DISCARDS
  97 }