Pileus Git - ~andy/linux/blob - arch/sparc/kernel/sys32.S

   1 /*
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <asm/errno.h>
  10
  11 /* NOTE: call as jump breaks return stack, we have to avoid that */
  12
  13         .text
  14
  15 #define SIGN1(STUB,SYSCALL,REG1) \
  16         .align  32; \
  17         .globl  STUB; \
  18 STUB:   sethi   %hi(SYSCALL), %g1; \
  19         jmpl    %g1 + %lo(SYSCALL), %g0; \
  20         sra     REG1, 0, REG1
  21
  22 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  23         .align  32; \
  24         .globl  STUB; \
  25 STUB:   sethi   %hi(SYSCALL), %g1; \
  26         sra     REG1, 0, REG1; \
  27         jmpl    %g1 + %lo(SYSCALL), %g0; \
  28         sra     REG2, 0, REG2
  29
  30 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  31         .align  32; \
  32         .globl  STUB; \
  33 STUB:   sra     REG1, 0, REG1; \
  34         sethi   %hi(SYSCALL), %g1; \
  35         sra     REG2, 0, REG2; \
  36         jmpl    %g1 + %lo(SYSCALL), %g0; \
  37         sra     REG3, 0, REG3
  38
  39 SIGN1(sys32_getrusage, compat_sys_getrusage, %o0)
  40 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  41 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  42 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  43 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  44 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  45 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  46 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  47 SIGN1(sys32_select, compat_sys_select, %o0)
  48 SIGN3(sys32_futex, compat_sys_futex, %o1, %o2, %o5)
  49 SIGN2(sys32_sendfile, compat_sys_sendfile, %o0, %o1)
  50 SIGN1(sys32_recvfrom, compat_sys_recvfrom, %o0)
  51 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
  52 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
  53 SIGN2(sys32_sync_file_range, compat_sync_file_range, %o0, %o5)
  54 SIGN1(sys32_vmsplice, compat_sys_vmsplice, %o0)
  55
  56         .globl          sys32_mmap2
  57 sys32_mmap2:
  58         sethi           %hi(sys_mmap), %g1
  59         jmpl            %g1 + %lo(sys_mmap), %g0
  60          sllx           %o5, 12, %o5
  61
  62         .align          32
  63         .globl          sys32_socketcall
  64 sys32_socketcall:       /* %o0=call, %o1=args */
  65         cmp             %o0, 1
  66         bl,pn           %xcc, do_einval
  67          cmp            %o0, 18
  68         bg,pn           %xcc, do_einval
  69          sub            %o0, 1, %o0
  70         sllx            %o0, 5, %o0
  71         sethi           %hi(__socketcall_table_begin), %g2
  72         or              %g2, %lo(__socketcall_table_begin), %g2
  73         jmpl            %g2 + %o0, %g0
  74          nop
  75 do_einval:
  76         retl
  77          mov            -EINVAL, %o0
  78
  79         .align          32
  80 __socketcall_table_begin:
  81
  82         /* Each entry is exactly 32 bytes. */
  83 do_sys_socket: /* sys_socket(int, int, int) */
  84 1:      ldswa           [%o1 + 0x0] %asi, %o0
  85         sethi           %hi(sys_socket), %g1
  86 2:      ldswa           [%o1 + 0x8] %asi, %o2
  87         jmpl            %g1 + %lo(sys_socket), %g0
  88 3:       ldswa          [%o1 + 0x4] %asi, %o1
  89         nop
  90         nop
  91         nop
  92 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
  93 4:      ldswa           [%o1 + 0x0] %asi, %o0
  94         sethi           %hi(sys_bind), %g1
  95 5:      ldswa           [%o1 + 0x8] %asi, %o2
  96         jmpl            %g1 + %lo(sys_bind), %g0
  97 6:       lduwa          [%o1 + 0x4] %asi, %o1
  98         nop
  99         nop
 100         nop
 101 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
 102 7:      ldswa           [%o1 + 0x0] %asi, %o0
 103         sethi           %hi(sys_connect), %g1
 104 8:      ldswa           [%o1 + 0x8] %asi, %o2
 105         jmpl            %g1 + %lo(sys_connect), %g0
 106 9:       lduwa          [%o1 + 0x4] %asi, %o1
 107         nop
 108         nop
 109         nop
 110 do_sys_listen: /* sys_listen(int, int) */
 111 10:     ldswa           [%o1 + 0x0] %asi, %o0
 112         sethi           %hi(sys_listen), %g1
 113         jmpl            %g1 + %lo(sys_listen), %g0
 114 11:      ldswa          [%o1 + 0x4] %asi, %o1
 115         nop
 116         nop
 117         nop
 118         nop
 119 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 120 12:     ldswa           [%o1 + 0x0] %asi, %o0
 121         sethi           %hi(sys_accept), %g1
 122 13:     lduwa           [%o1 + 0x8] %asi, %o2
 123         jmpl            %g1 + %lo(sys_accept), %g0
 124 14:      lduwa          [%o1 + 0x4] %asi, %o1
 125         nop
 126         nop
 127         nop
 128 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 129 15:     ldswa           [%o1 + 0x0] %asi, %o0
 130         sethi           %hi(sys_getsockname), %g1
 131 16:     lduwa           [%o1 + 0x8] %asi, %o2
 132         jmpl            %g1 + %lo(sys_getsockname), %g0
 133 17:      lduwa          [%o1 + 0x4] %asi, %o1
 134         nop
 135         nop
 136         nop
 137 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 138 18:     ldswa           [%o1 + 0x0] %asi, %o0
 139         sethi           %hi(sys_getpeername), %g1
 140 19:     lduwa           [%o1 + 0x8] %asi, %o2
 141         jmpl            %g1 + %lo(sys_getpeername), %g0
 142 20:      lduwa          [%o1 + 0x4] %asi, %o1
 143         nop
 144         nop
 145         nop
 146 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 147 21:     ldswa           [%o1 + 0x0] %asi, %o0
 148         sethi           %hi(sys_socketpair), %g1
 149 22:     ldswa           [%o1 + 0x8] %asi, %o2
 150 23:     lduwa           [%o1 + 0xc] %asi, %o3
 151         jmpl            %g1 + %lo(sys_socketpair), %g0
 152 24:      ldswa          [%o1 + 0x4] %asi, %o1
 153         nop
 154         nop
 155 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 156 25:     ldswa           [%o1 + 0x0] %asi, %o0
 157         sethi           %hi(sys_send), %g1
 158 26:     lduwa           [%o1 + 0x8] %asi, %o2
 159 27:     lduwa           [%o1 + 0xc] %asi, %o3
 160         jmpl            %g1 + %lo(sys_send), %g0
 161 28:      lduwa          [%o1 + 0x4] %asi, %o1
 162         nop
 163         nop
 164 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 165 29:     ldswa           [%o1 + 0x0] %asi, %o0
 166         sethi           %hi(sys_recv), %g1
 167 30:     lduwa           [%o1 + 0x8] %asi, %o2
 168 31:     lduwa           [%o1 + 0xc] %asi, %o3
 169         jmpl            %g1 + %lo(sys_recv), %g0
 170 32:      lduwa          [%o1 + 0x4] %asi, %o1
 171         nop
 172         nop
 173 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 174 33:     ldswa           [%o1 + 0x0] %asi, %o0
 175         sethi           %hi(sys_sendto), %g1
 176 34:     lduwa           [%o1 + 0x8] %asi, %o2
 177 35:     lduwa           [%o1 + 0xc] %asi, %o3
 178 36:     lduwa           [%o1 + 0x10] %asi, %o4
 179 37:     ldswa           [%o1 + 0x14] %asi, %o5
 180         jmpl            %g1 + %lo(sys_sendto), %g0
 181 38:      lduwa          [%o1 + 0x4] %asi, %o1
 182 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 183 39:     ldswa           [%o1 + 0x0] %asi, %o0
 184         sethi           %hi(sys_recvfrom), %g1
 185 40:     lduwa           [%o1 + 0x8] %asi, %o2
 186 41:     lduwa           [%o1 + 0xc] %asi, %o3
 187 42:     lduwa           [%o1 + 0x10] %asi, %o4
 188 43:     lduwa           [%o1 + 0x14] %asi, %o5
 189         jmpl            %g1 + %lo(sys_recvfrom), %g0
 190 44:      lduwa          [%o1 + 0x4] %asi, %o1
 191 do_sys_shutdown: /* sys_shutdown(int, int) */
 192 45:     ldswa           [%o1 + 0x0] %asi, %o0
 193         sethi           %hi(sys_shutdown), %g1
 194         jmpl            %g1 + %lo(sys_shutdown), %g0
 195 46:      ldswa          [%o1 + 0x4] %asi, %o1
 196         nop
 197         nop
 198         nop
 199         nop
 200 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 201 47:     ldswa           [%o1 + 0x0] %asi, %o0
 202         sethi           %hi(compat_sys_setsockopt), %g1
 203 48:     ldswa           [%o1 + 0x8] %asi, %o2
 204 49:     lduwa           [%o1 + 0xc] %asi, %o3
 205 50:     ldswa           [%o1 + 0x10] %asi, %o4
 206         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 207 51:      ldswa          [%o1 + 0x4] %asi, %o1
 208         nop
 209 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 210 52:     ldswa           [%o1 + 0x0] %asi, %o0
 211         sethi           %hi(compat_sys_getsockopt), %g1
 212 53:     ldswa           [%o1 + 0x8] %asi, %o2
 213 54:     lduwa           [%o1 + 0xc] %asi, %o3
 214 55:     lduwa           [%o1 + 0x10] %asi, %o4
 215         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 216 56:      ldswa          [%o1 + 0x4] %asi, %o1
 217         nop
 218 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 219 57:     ldswa           [%o1 + 0x0] %asi, %o0
 220         sethi           %hi(compat_sys_sendmsg), %g1
 221 58:     lduwa           [%o1 + 0x8] %asi, %o2
 222         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 223 59:      lduwa          [%o1 + 0x4] %asi, %o1
 224         nop
 225         nop
 226         nop
 227 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 228 60:     ldswa           [%o1 + 0x0] %asi, %o0
 229         sethi           %hi(compat_sys_recvmsg), %g1
 230 61:     lduwa           [%o1 + 0x8] %asi, %o2
 231         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 232 62:      lduwa          [%o1 + 0x4] %asi, %o1
 233         nop
 234         nop
 235         nop
 236 do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
 237 63:     ldswa           [%o1 + 0x0] %asi, %o0
 238         sethi           %hi(sys_accept4), %g1
 239 64:     lduwa           [%o1 + 0x8] %asi, %o2
 240 65:     ldswa           [%o1 + 0xc] %asi, %o3
 241         jmpl            %g1 + %lo(sys_accept4), %g0
 242 66:      lduwa          [%o1 + 0x4] %asi, %o1
 243         nop
 244         nop
 245
 246         .globl          sys32_fanotify_mark
 247 sys32_fanotify_mark:
 248         sethi           %hi(sys_fanotify_mark), %g1
 249         sllx            %o2, 32, %o2
 250         or              %o2, %o3, %o2
 251         mov             %o4, %o3
 252         jmpl            %g1 + %lo(sys_fanotify_mark), %g0
 253          mov            %o5, %o4
 254
 255         .section        __ex_table,"a"
 256         .align          4
 257         .word           1b, __retl_efault, 2b, __retl_efault
 258         .word           3b, __retl_efault, 4b, __retl_efault
 259         .word           5b, __retl_efault, 6b, __retl_efault
 260         .word           7b, __retl_efault, 8b, __retl_efault
 261         .word           9b, __retl_efault, 10b, __retl_efault
 262         .word           11b, __retl_efault, 12b, __retl_efault
 263         .word           13b, __retl_efault, 14b, __retl_efault
 264         .word           15b, __retl_efault, 16b, __retl_efault
 265         .word           17b, __retl_efault, 18b, __retl_efault
 266         .word           19b, __retl_efault, 20b, __retl_efault
 267         .word           21b, __retl_efault, 22b, __retl_efault
 268         .word           23b, __retl_efault, 24b, __retl_efault
 269         .word           25b, __retl_efault, 26b, __retl_efault
 270         .word           27b, __retl_efault, 28b, __retl_efault
 271         .word           29b, __retl_efault, 30b, __retl_efault
 272         .word           31b, __retl_efault, 32b, __retl_efault
 273         .word           33b, __retl_efault, 34b, __retl_efault
 274         .word           35b, __retl_efault, 36b, __retl_efault
 275         .word           37b, __retl_efault, 38b, __retl_efault
 276         .word           39b, __retl_efault, 40b, __retl_efault
 277         .word           41b, __retl_efault, 42b, __retl_efault
 278         .word           43b, __retl_efault, 44b, __retl_efault
 279         .word           45b, __retl_efault, 46b, __retl_efault
 280         .word           47b, __retl_efault, 48b, __retl_efault
 281         .word           49b, __retl_efault, 50b, __retl_efault
 282         .word           51b, __retl_efault, 52b, __retl_efault
 283         .word           53b, __retl_efault, 54b, __retl_efault
 284         .word           55b, __retl_efault, 56b, __retl_efault
 285         .word           57b, __retl_efault, 58b, __retl_efault
 286         .word           59b, __retl_efault, 60b, __retl_efault
 287         .word           61b, __retl_efault, 62b, __retl_efault
 288         .word           63b, __retl_efault, 64b, __retl_efault
 289         .word           65b, __retl_efault, 66b, __retl_efault
 290         .previous