Pileus Git - ~andy/linux/blob - arch/s390/kernel/entry64.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/cache.h>
  14 #include <asm/errno.h>
  15 #include <asm/ptrace.h>
  16 #include <asm/thread_info.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/unistd.h>
  19 #include <asm/page.h>
  20 #include <asm/sigp.h>
  21
  22 __PT_R0      =  __PT_GPRS
  23 __PT_R1      =  __PT_GPRS + 8
  24 __PT_R2      =  __PT_GPRS + 16
  25 __PT_R3      =  __PT_GPRS + 24
  26 __PT_R4      =  __PT_GPRS + 32
  27 __PT_R5      =  __PT_GPRS + 40
  28 __PT_R6      =  __PT_GPRS + 48
  29 __PT_R7      =  __PT_GPRS + 56
  30 __PT_R8      =  __PT_GPRS + 64
  31 __PT_R9      =  __PT_GPRS + 72
  32 __PT_R10     =  __PT_GPRS + 80
  33 __PT_R11     =  __PT_GPRS + 88
  34 __PT_R12     =  __PT_GPRS + 96
  35 __PT_R13     =  __PT_GPRS + 104
  36 __PT_R14     =  __PT_GPRS + 112
  37 __PT_R15     =  __PT_GPRS + 120
  38
  39 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  40 STACK_SIZE  = 1 << STACK_SHIFT
  41
  42 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  43                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  44 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  45                  _TIF_MCCK_PENDING)
  46 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  47                  _TIF_SYSCALL_TRACEPOINT)
  48 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
  49
  50 #define BASED(name) name-system_call(%r13)
  51
  52         .macro  TRACE_IRQS_ON
  53 #ifdef CONFIG_TRACE_IRQFLAGS
  54         basr    %r2,%r0
  55         brasl   %r14,trace_hardirqs_on_caller
  56 #endif
  57         .endm
  58
  59         .macro  TRACE_IRQS_OFF
  60 #ifdef CONFIG_TRACE_IRQFLAGS
  61         basr    %r2,%r0
  62         brasl   %r14,trace_hardirqs_off_caller
  63 #endif
  64         .endm
  65
  66         .macro  LOCKDEP_SYS_EXIT
  67 #ifdef CONFIG_LOCKDEP
  68         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  69         jz      .+10
  70         brasl   %r14,lockdep_sys_exit
  71 #endif
  72         .endm
  73
  74         .macro SPP newpp
  75 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  76         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_SPP
  77         jz      .+8
  78         .insn   s,0xb2800000,\newpp
  79 #endif
  80         .endm
  81
  82         .macro  HANDLE_SIE_INTERCEPT scratch
  83 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
  84         tmhh    %r8,0x0001              # interrupting from user ?
  85         jnz     .+42
  86         lgr     \scratch,%r9
  87         slg     \scratch,BASED(.Lsie_loop)
  88         clg     \scratch,BASED(.Lsie_length)
  89         jhe     .+22
  90         lg      %r9,BASED(.Lsie_loop)
  91         SPP     BASED(.Lhost_id)        # set host id
  92 #endif
  93         .endm
  94
  95         .macro  CHECK_STACK stacksize,savearea
  96 #ifdef CONFIG_CHECK_STACK
  97         tml     %r15,\stacksize - CONFIG_STACK_GUARD
  98         lghi    %r14,\savearea
  99         jz      stack_overflow
 100 #endif
 101         .endm
 102
 103         .macro  SWITCH_ASYNC savearea,stack,shift
 104         tmhh    %r8,0x0001              # interrupting from user ?
 105         jnz     1f
 106         lgr     %r14,%r9
 107         slg     %r14,BASED(.Lcritical_start)
 108         clg     %r14,BASED(.Lcritical_length)
 109         jhe     0f
 110         lghi    %r11,\savearea          # inside critical section, do cleanup
 111         brasl   %r14,cleanup_critical
 112         tmhh    %r8,0x0001              # retest problem state after cleanup
 113         jnz     1f
 114 0:      lg      %r14,\stack             # are we already on the target stack?
 115         slgr    %r14,%r15
 116         srag    %r14,%r14,\shift
 117         jnz     1f
 118         CHECK_STACK 1<<\shift,\savearea
 119         j       2f
 120 1:      lg      %r15,\stack             # load target stack
 121 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 122         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 123         .endm
 124
 125         .macro UPDATE_VTIME scratch,enter_timer
 126         lg      \scratch,__LC_EXIT_TIMER
 127         slg     \scratch,\enter_timer
 128         alg     \scratch,__LC_USER_TIMER
 129         stg     \scratch,__LC_USER_TIMER
 130         lg      \scratch,__LC_LAST_UPDATE_TIMER
 131         slg     \scratch,__LC_EXIT_TIMER
 132         alg     \scratch,__LC_SYSTEM_TIMER
 133         stg     \scratch,__LC_SYSTEM_TIMER
 134         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 135         .endm
 136
 137         .macro  LAST_BREAK scratch
 138         srag    \scratch,%r10,23
 139         jz      .+10
 140         stg     %r10,__TI_last_break(%r12)
 141         .endm
 142
 143         .macro REENABLE_IRQS
 144         stg     %r8,__LC_RETURN_PSW
 145         ni      __LC_RETURN_PSW,0xbf
 146         ssm     __LC_RETURN_PSW
 147         .endm
 148
 149         .macro STCK savearea
 150 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
 151         .insn   s,0xb27c0000,\savearea          # store clock fast
 152 #else
 153         .insn   s,0xb2050000,\savearea          # store clock
 154 #endif
 155         .endm
 156
 157         .section .kprobes.text, "ax"
 158
 159 /*
 160  * Scheduler resume function, called by switch_to
 161  *  gpr2 = (task_struct *) prev
 162  *  gpr3 = (task_struct *) next
 163  * Returns:
 164  *  gpr2 = prev
 165  */
 166 ENTRY(__switch_to)
 167         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 168         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 169         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
 170         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
 171         lgr     %r15,%r5
 172         aghi    %r15,STACK_SIZE                 # end of kernel stack of next
 173         stg     %r3,__LC_CURRENT                # store task struct of next
 174         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 175         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
 176         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 177         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
 178         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 179         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 180         jz      0f
 181         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 182         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
 183 0:      lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 184         br      %r14
 185
 186 __critical_start:
 187 /*
 188  * SVC interrupt handler routine. System calls are synchronous events and
 189  * are executed with interrupts enabled.
 190  */
 191
 192 ENTRY(system_call)
 193         stpt    __LC_SYNC_ENTER_TIMER
 194 sysc_stmg:
 195         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 196         lg      %r10,__LC_LAST_BREAK
 197         lg      %r12,__LC_THREAD_INFO
 198         larl    %r13,system_call
 199 sysc_per:
 200         lg      %r15,__LC_KERNEL_STACK
 201         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 202         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 203 sysc_vtime:
 204         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
 205         LAST_BREAK %r13
 206         stmg    %r0,%r7,__PT_R0(%r11)
 207         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 208         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
 209         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 210 sysc_do_svc:
 211         oi      __TI_flags+7(%r12),_TIF_SYSCALL
 212         llgh    %r8,__PT_INT_CODE+2(%r11)
 213         slag    %r8,%r8,2                       # shift and test for svc 0
 214         jnz     sysc_nr_ok
 215         # svc 0: system call number in %r1
 216         llgfr   %r1,%r1                         # clear high word in r1
 217         cghi    %r1,NR_syscalls
 218         jnl     sysc_nr_ok
 219         sth     %r1,__PT_INT_CODE+2(%r11)
 220         slag    %r8,%r1,2
 221 sysc_nr_ok:
 222         larl    %r10,sys_call_table             # 64 bit system call table
 223 #ifdef CONFIG_COMPAT
 224         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)
 225         jno     sysc_noemu
 226         larl    %r10,sys_call_table_emu         # 31 bit system call table
 227 sysc_noemu:
 228 #endif
 229         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 230         stg     %r2,__PT_ORIG_GPR2(%r11)
 231         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 232         lgf     %r9,0(%r8,%r10)                 # get system call add.
 233         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 234         jnz     sysc_tracesys
 235         basr    %r14,%r9                        # call sys_xxxx
 236         stg     %r2,__PT_R2(%r11)               # store return value
 237
 238 sysc_return:
 239         LOCKDEP_SYS_EXIT
 240 sysc_tif:
 241         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 242         jno     sysc_restore
 243         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
 244         jnz     sysc_work                       # check for work
 245         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
 246 sysc_restore:
 247         lg      %r14,__LC_VDSO_PER_CPU
 248         lmg     %r0,%r10,__PT_R0(%r11)
 249         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 250         stpt    __LC_EXIT_TIMER
 251         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 252         lmg     %r11,%r15,__PT_R11(%r11)
 253         lpswe   __LC_RETURN_PSW
 254 sysc_done:
 255
 256 #
 257 # One of the work bits is on. Find out which one.
 258 #
 259 sysc_work:
 260         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 261         jo      sysc_mcck_pending
 262         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 263         jo      sysc_reschedule
 264         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 265         jo      sysc_sigpending
 266         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 267         jo      sysc_notify_resume
 268         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
 269         jo      sysc_singlestep
 270         j       sysc_return             # beware of critical section cleanup
 271
 272 #
 273 # _TIF_NEED_RESCHED is set, call schedule
 274 #
 275 sysc_reschedule:
 276         larl    %r14,sysc_return
 277         jg      schedule
 278
 279 #
 280 # _TIF_MCCK_PENDING is set, call handler
 281 #
 282 sysc_mcck_pending:
 283         larl    %r14,sysc_return
 284         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 285
 286 #
 287 # _TIF_SIGPENDING is set, call do_signal
 288 #
 289 sysc_sigpending:
 290         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 291         lgr     %r2,%r11                # pass pointer to pt_regs
 292         brasl   %r14,do_signal
 293         tm      __TI_flags+7(%r12),_TIF_SYSCALL
 294         jno     sysc_return
 295         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
 296         lghi    %r8,0                   # svc 0 returns -ENOSYS
 297         lh      %r1,__PT_INT_CODE+2(%r11)       # load new svc number
 298         cghi    %r1,NR_syscalls
 299         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 300         slag    %r8,%r1,2
 301         j       sysc_nr_ok              # restart svc
 302
 303 #
 304 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 305 #
 306 sysc_notify_resume:
 307         lgr     %r2,%r11                # pass pointer to pt_regs
 308         larl    %r14,sysc_return
 309         jg      do_notify_resume
 310
 311 #
 312 # _TIF_PER_TRAP is set, call do_per_trap
 313 #
 314 sysc_singlestep:
 315         ni      __TI_flags+7(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
 316         lgr     %r2,%r11                # pass pointer to pt_regs
 317         larl    %r14,sysc_return
 318         jg      do_per_trap
 319
 320 #
 321 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 322 # and after the system call
 323 #
 324 sysc_tracesys:
 325         lgr     %r2,%r11                # pass pointer to pt_regs
 326         la      %r3,0
 327         llgh    %r0,__PT_INT_CODE+2(%r11)
 328         stg     %r0,__PT_R2(%r11)
 329         brasl   %r14,do_syscall_trace_enter
 330         lghi    %r0,NR_syscalls
 331         clgr    %r0,%r2
 332         jnh     sysc_tracenogo
 333         sllg    %r8,%r2,2
 334         lgf     %r9,0(%r8,%r10)
 335 sysc_tracego:
 336         lmg     %r3,%r7,__PT_R3(%r11)
 337         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 338         lg      %r2,__PT_ORIG_GPR2(%r11)
 339         basr    %r14,%r9                # call sys_xxx
 340         stg     %r2,__PT_R2(%r11)       # store return value
 341 sysc_tracenogo:
 342         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
 343         jz      sysc_return
 344         lgr     %r2,%r11                # pass pointer to pt_regs
 345         larl    %r14,sysc_return
 346         jg      do_syscall_trace_exit
 347
 348 #
 349 # a new process exits the kernel with ret_from_fork
 350 #
 351 ENTRY(ret_from_fork)
 352         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 353         lg      %r12,__LC_THREAD_INFO
 354         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 355         je      1f
 356         brasl   %r14,schedule_tail
 357         TRACE_IRQS_ON
 358         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 359         j       sysc_tracenogo
 360 1:      # it's a kernel thread
 361         stg     %r15,__PT_R15(%r11)     # store stack pointer for new kthread
 362         brasl   %r14,schedule_tail
 363         TRACE_IRQS_ON
 364         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 365         lmg     %r9,%r11,__PT_R9(%r11)  # load gprs
 366 ENTRY(kernel_thread_starter)
 367         la      %r2,0(%r10)
 368         basr    %r14,%r9
 369         la      %r2,0
 370         br      %r11                    # do_exit
 371
 372 ENTRY(ret_from_kernel_execve)
 373         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 374         lgr     %r15,%r2
 375         lgr     %r11,%r2
 376         aghi    %r15,-STACK_FRAME_OVERHEAD
 377         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 378         lg      %r12,__LC_THREAD_INFO
 379         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 380         j       sysc_return
 381
 382 /*
 383  * Program check handler routine
 384  */
 385
 386 ENTRY(pgm_check_handler)
 387         stpt    __LC_SYNC_ENTER_TIMER
 388         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 389         lg      %r10,__LC_LAST_BREAK
 390         lg      %r12,__LC_THREAD_INFO
 391         larl    %r13,system_call
 392         lmg     %r8,%r9,__LC_PGM_OLD_PSW
 393         HANDLE_SIE_INTERCEPT %r14
 394         tmhh    %r8,0x0001              # test problem state bit
 395         jnz     1f                      # -> fault in user space
 396         tmhh    %r8,0x4000              # PER bit set in old PSW ?
 397         jnz     0f                      # -> enabled, can't be a double fault
 398         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 399         jnz     pgm_svcper              # -> single stepped svc
 400 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 401         j       2f
 402 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
 403         LAST_BREAK %r14
 404         lg      %r15,__LC_KERNEL_STACK
 405 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 406         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 407         stmg    %r0,%r7,__PT_R0(%r11)
 408         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 409         stmg    %r8,%r9,__PT_PSW(%r11)
 410         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 411         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
 412         stg     %r10,__PT_ARGS(%r11)
 413         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 414         jz      0f
 415         lg      %r1,__TI_task(%r12)
 416         tmhh    %r8,0x0001              # kernel per event ?
 417         jz      pgm_kprobe
 418         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 419         mvc     __THREAD_per_address(8,%r1),__LC_PER_ADDRESS
 420         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
 421         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
 422 0:      REENABLE_IRQS
 423         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 424         larl    %r1,pgm_check_table
 425         llgh    %r10,__PT_INT_CODE+2(%r11)
 426         nill    %r10,0x007f
 427         sll     %r10,3
 428         je      sysc_return
 429         lg      %r1,0(%r10,%r1)         # load address of handler routine
 430         lgr     %r2,%r11                # pass pointer to pt_regs
 431         basr    %r14,%r1                # branch to interrupt-handler
 432         j       sysc_return
 433
 434 #
 435 # PER event in supervisor state, must be kprobes
 436 #
 437 pgm_kprobe:
 438         REENABLE_IRQS
 439         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 440         lgr     %r2,%r11                # pass pointer to pt_regs
 441         brasl   %r14,do_per_trap
 442         j       sysc_return
 443
 444 #
 445 # single stepped system call
 446 #
 447 pgm_svcper:
 448         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
 449         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
 450         larl    %r14,sysc_per
 451         stg     %r14,__LC_RETURN_PSW+8
 452         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 453
 454 /*
 455  * IO interrupt handler routine
 456  */
 457 ENTRY(io_int_handler)
 458         STCK    __LC_INT_CLOCK
 459         stpt    __LC_ASYNC_ENTER_TIMER
 460         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 461         lg      %r10,__LC_LAST_BREAK
 462         lg      %r12,__LC_THREAD_INFO
 463         larl    %r13,system_call
 464         lmg     %r8,%r9,__LC_IO_OLD_PSW
 465         HANDLE_SIE_INTERCEPT %r14
 466         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 467         tmhh    %r8,0x0001              # interrupting from user?
 468         jz      io_skip
 469         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 470         LAST_BREAK %r14
 471 io_skip:
 472         stmg    %r0,%r7,__PT_R0(%r11)
 473         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 474         stmg    %r8,%r9,__PT_PSW(%r11)
 475         TRACE_IRQS_OFF
 476         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 477         lgr     %r2,%r11                # pass pointer to pt_regs
 478         brasl   %r14,do_IRQ
 479 io_return:
 480         LOCKDEP_SYS_EXIT
 481         TRACE_IRQS_ON
 482 io_tif:
 483         tm      __TI_flags+7(%r12),_TIF_WORK_INT
 484         jnz     io_work                 # there is work to do (signals etc.)
 485 io_restore:
 486         lg      %r14,__LC_VDSO_PER_CPU
 487         lmg     %r0,%r10,__PT_R0(%r11)
 488         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 489         stpt    __LC_EXIT_TIMER
 490         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 491         lmg     %r11,%r15,__PT_R11(%r11)
 492         lpswe   __LC_RETURN_PSW
 493 io_done:
 494
 495 #
 496 # There is work todo, find out in which context we have been interrupted:
 497 # 1) if we return to user space we can do all _TIF_WORK_INT work
 498 # 2) if we return to kernel code and kvm is enabled check if we need to
 499 #    modify the psw to leave SIE
 500 # 3) if we return to kernel code and preemptive scheduling is enabled check
 501 #    the preemption counter and if it is zero call preempt_schedule_irq
 502 # Before any work can be done, a switch to the kernel stack is required.
 503 #
 504 io_work:
 505         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 506         jo      io_work_user            # yes -> do resched & signal
 507 #ifdef CONFIG_PREEMPT
 508         # check for preemptive scheduling
 509         icm     %r0,15,__TI_precount(%r12)
 510         jnz     io_restore              # preemption is disabled
 511         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 512         jno     io_restore
 513         # switch to kernel stack
 514         lg      %r1,__PT_R15(%r11)
 515         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 516         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 517         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 518         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 519         lgr     %r15,%r1
 520         # TRACE_IRQS_ON already done at io_return, call
 521         # TRACE_IRQS_OFF to keep things symmetrical
 522         TRACE_IRQS_OFF
 523         brasl   %r14,preempt_schedule_irq
 524         j       io_return
 525 #else
 526         j       io_restore
 527 #endif
 528
 529 #
 530 # Need to do work before returning to userspace, switch to kernel stack
 531 #
 532 io_work_user:
 533         lg      %r1,__LC_KERNEL_STACK
 534         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 535         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 536         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 537         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 538         lgr     %r15,%r1
 539
 540 #
 541 # One of the work bits is on. Find out which one.
 542 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 543 #              and _TIF_MCCK_PENDING
 544 #
 545 io_work_tif:
 546         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 547         jo      io_mcck_pending
 548         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
 549         jo      io_reschedule
 550         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
 551         jo      io_sigpending
 552         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
 553         jo      io_notify_resume
 554         j       io_return               # beware of critical section cleanup
 555
 556 #
 557 # _TIF_MCCK_PENDING is set, call handler
 558 #
 559 io_mcck_pending:
 560         # TRACE_IRQS_ON already done at io_return
 561         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 562         TRACE_IRQS_OFF
 563         j       io_return
 564
 565 #
 566 # _TIF_NEED_RESCHED is set, call schedule
 567 #
 568 io_reschedule:
 569         # TRACE_IRQS_ON already done at io_return
 570         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 571         brasl   %r14,schedule           # call scheduler
 572         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 573         TRACE_IRQS_OFF
 574         j       io_return
 575
 576 #
 577 # _TIF_SIGPENDING or is set, call do_signal
 578 #
 579 io_sigpending:
 580         # TRACE_IRQS_ON already done at io_return
 581         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 582         lgr     %r2,%r11                # pass pointer to pt_regs
 583         brasl   %r14,do_signal
 584         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 585         TRACE_IRQS_OFF
 586         j       io_return
 587
 588 #
 589 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 590 #
 591 io_notify_resume:
 592         # TRACE_IRQS_ON already done at io_return
 593         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 594         lgr     %r2,%r11                # pass pointer to pt_regs
 595         brasl   %r14,do_notify_resume
 596         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 597         TRACE_IRQS_OFF
 598         j       io_return
 599
 600 /*
 601  * External interrupt handler routine
 602  */
 603 ENTRY(ext_int_handler)
 604         STCK    __LC_INT_CLOCK
 605         stpt    __LC_ASYNC_ENTER_TIMER
 606         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 607         lg      %r10,__LC_LAST_BREAK
 608         lg      %r12,__LC_THREAD_INFO
 609         larl    %r13,system_call
 610         lmg     %r8,%r9,__LC_EXT_OLD_PSW
 611         HANDLE_SIE_INTERCEPT %r14
 612         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 613         tmhh    %r8,0x0001              # interrupting from user ?
 614         jz      ext_skip
 615         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
 616         LAST_BREAK %r14
 617 ext_skip:
 618         stmg    %r0,%r7,__PT_R0(%r11)
 619         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 620         stmg    %r8,%r9,__PT_PSW(%r11)
 621         TRACE_IRQS_OFF
 622         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 623         lghi    %r1,4096
 624         lgr     %r2,%r11                # pass pointer to pt_regs
 625         llgf    %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
 626         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
 627         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
 628         brasl   %r14,do_extint
 629         j       io_return
 630
 631 /*
 632  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 633  */
 634 ENTRY(psw_idle)
 635         stg     %r3,__SF_EMPTY(%r15)
 636         larl    %r1,psw_idle_lpsw+4
 637         stg     %r1,__SF_EMPTY+8(%r15)
 638         STCK    __CLOCK_IDLE_ENTER(%r2)
 639         stpt    __TIMER_IDLE_ENTER(%r2)
 640 psw_idle_lpsw:
 641         lpswe   __SF_EMPTY(%r15)
 642         br      %r14
 643 psw_idle_end:
 644
 645 __critical_end:
 646
 647 /*
 648  * Machine check handler routines
 649  */
 650 ENTRY(mcck_int_handler)
 651         STCK    __LC_MCCK_CLOCK
 652         la      %r1,4095                # revalidate r1
 653         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 654         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 655         lg      %r10,__LC_LAST_BREAK
 656         lg      %r12,__LC_THREAD_INFO
 657         larl    %r13,system_call
 658         lmg     %r8,%r9,__LC_MCK_OLD_PSW
 659         HANDLE_SIE_INTERCEPT %r14
 660         tm      __LC_MCCK_CODE,0x80     # system damage?
 661         jo      mcck_panic              # yes -> rest of mcck code invalid
 662         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
 663         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 664         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 665         jo      3f
 666         la      %r14,__LC_SYNC_ENTER_TIMER
 667         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 668         jl      0f
 669         la      %r14,__LC_ASYNC_ENTER_TIMER
 670 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 671         jl      1f
 672         la      %r14,__LC_EXIT_TIMER
 673 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 674         jl      2f
 675         la      %r14,__LC_LAST_UPDATE_TIMER
 676 2:      spt     0(%r14)
 677         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 678 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 679         jno     mcck_panic              # no -> skip cleanup critical
 680         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
 681         tm      %r8,0x0001              # interrupting from user ?
 682         jz      mcck_skip
 683         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
 684         LAST_BREAK %r14
 685 mcck_skip:
 686         lghi    %r14,__LC_GPREGS_SAVE_AREA
 687         mvc     __PT_R0(128,%r11),0(%r14)
 688         stmg    %r8,%r9,__PT_PSW(%r11)
 689         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 690         lgr     %r2,%r11                # pass pointer to pt_regs
 691         brasl   %r14,s390_do_machine_check
 692         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 693         jno     mcck_return
 694         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 695         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 696         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 697         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 698         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 699         lgr     %r15,%r1
 700         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 701         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
 702         jno     mcck_return
 703         TRACE_IRQS_OFF
 704         brasl   %r14,s390_handle_mcck
 705         TRACE_IRQS_ON
 706 mcck_return:
 707         lg      %r14,__LC_VDSO_PER_CPU
 708         lmg     %r0,%r10,__PT_R0(%r11)
 709         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
 710         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 711         jno     0f
 712         stpt    __LC_EXIT_TIMER
 713         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 714 0:      lmg     %r11,%r15,__PT_R11(%r11)
 715         lpswe   __LC_RETURN_MCCK_PSW
 716
 717 mcck_panic:
 718         lg      %r14,__LC_PANIC_STACK
 719         slgr    %r14,%r15
 720         srag    %r14,%r14,PAGE_SHIFT
 721         jz      0f
 722         lg      %r15,__LC_PANIC_STACK
 723 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 724         j       mcck_skip
 725
 726 #
 727 # PSW restart interrupt handler
 728 #
 729 ENTRY(restart_int_handler)
 730         stg     %r15,__LC_SAVE_AREA_RESTART
 731         lg      %r15,__LC_RESTART_STACK
 732         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
 733         xc      0(__PT_SIZE,%r15),0(%r15)
 734         stmg    %r0,%r14,__PT_R0(%r15)
 735         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
 736         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
 737         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 738         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 739         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 740         lg      %r2,__LC_RESTART_DATA
 741         lg      %r3,__LC_RESTART_SOURCE
 742         ltgr    %r3,%r3                         # test source cpu address
 743         jm      1f                              # negative -> skip source stop
 744 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 745         brc     10,0b                           # wait for status stored
 746 1:      basr    %r14,%r1                        # call function
 747         stap    __SF_EMPTY(%r15)                # store cpu address
 748         llgh    %r3,__SF_EMPTY(%r15)
 749 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 750         brc     2,2b
 751 3:      j       3b
 752
 753         .section .kprobes.text, "ax"
 754
 755 #ifdef CONFIG_CHECK_STACK
 756 /*
 757  * The synchronous or the asynchronous stack overflowed. We are dead.
 758  * No need to properly save the registers, we are going to panic anyway.
 759  * Setup a pt_regs so that show_trace can provide a good call trace.
 760  */
 761 stack_overflow:
 762         lg      %r11,__LC_PANIC_STACK   # change to panic stack
 763         aghi    %r11,-__PT_SIZE         # create pt_regs
 764         stmg    %r0,%r7,__PT_R0(%r11)
 765         stmg    %r8,%r9,__PT_PSW(%r11)
 766         mvc     __PT_R8(64,%r11),0(%r14)
 767         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
 768         lgr     %r15,%r11
 769         aghi    %r15,-STACK_FRAME_OVERHEAD
 770         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 771         lgr     %r2,%r11                # pass pointer to pt_regs
 772         jg      kernel_stack_overflow
 773 #endif
 774
 775         .align  8
 776 cleanup_table:
 777         .quad   system_call
 778         .quad   sysc_do_svc
 779         .quad   sysc_tif
 780         .quad   sysc_restore
 781         .quad   sysc_done
 782         .quad   io_tif
 783         .quad   io_restore
 784         .quad   io_done
 785         .quad   psw_idle
 786         .quad   psw_idle_end
 787
 788 cleanup_critical:
 789         clg     %r9,BASED(cleanup_table)        # system_call
 790         jl      0f
 791         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
 792         jl      cleanup_system_call
 793         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
 794         jl      0f
 795         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
 796         jl      cleanup_sysc_tif
 797         clg     %r9,BASED(cleanup_table+32)     # sysc_done
 798         jl      cleanup_sysc_restore
 799         clg     %r9,BASED(cleanup_table+40)     # io_tif
 800         jl      0f
 801         clg     %r9,BASED(cleanup_table+48)     # io_restore
 802         jl      cleanup_io_tif
 803         clg     %r9,BASED(cleanup_table+56)     # io_done
 804         jl      cleanup_io_restore
 805         clg     %r9,BASED(cleanup_table+64)     # psw_idle
 806         jl      0f
 807         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
 808         jl      cleanup_idle
 809 0:      br      %r14
 810
 811
 812 cleanup_system_call:
 813         # check if stpt has been executed
 814         clg     %r9,BASED(cleanup_system_call_insn)
 815         jh      0f
 816         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 817         cghi    %r11,__LC_SAVE_AREA_ASYNC
 818         je      0f
 819         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 820 0:      # check if stmg has been executed
 821         clg     %r9,BASED(cleanup_system_call_insn+8)
 822         jh      0f
 823         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
 824 0:      # check if base register setup + TIF bit load has been done
 825         clg     %r9,BASED(cleanup_system_call_insn+16)
 826         jhe     0f
 827         # set up saved registers r10 and r12
 828         stg     %r10,16(%r11)           # r10 last break
 829         stg     %r12,32(%r11)           # r12 thread-info pointer
 830 0:      # check if the user time update has been done
 831         clg     %r9,BASED(cleanup_system_call_insn+24)
 832         jh      0f
 833         lg      %r15,__LC_EXIT_TIMER
 834         slg     %r15,__LC_SYNC_ENTER_TIMER
 835         alg     %r15,__LC_USER_TIMER
 836         stg     %r15,__LC_USER_TIMER
 837 0:      # check if the system time update has been done
 838         clg     %r9,BASED(cleanup_system_call_insn+32)
 839         jh      0f
 840         lg      %r15,__LC_LAST_UPDATE_TIMER
 841         slg     %r15,__LC_EXIT_TIMER
 842         alg     %r15,__LC_SYSTEM_TIMER
 843         stg     %r15,__LC_SYSTEM_TIMER
 844 0:      # update accounting time stamp
 845         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 846         # do LAST_BREAK
 847         lg      %r9,16(%r11)
 848         srag    %r9,%r9,23
 849         jz      0f
 850         mvc     __TI_last_break(8,%r12),16(%r11)
 851 0:      # set up saved register r11
 852         lg      %r15,__LC_KERNEL_STACK
 853         aghi    %r15,-__PT_SIZE
 854         stg     %r15,24(%r11)           # r11 pt_regs pointer
 855         # fill pt_regs
 856         mvc     __PT_R8(64,%r15),__LC_SAVE_AREA_SYNC
 857         stmg    %r0,%r7,__PT_R0(%r15)
 858         mvc     __PT_PSW(16,%r15),__LC_SVC_OLD_PSW
 859         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
 860         # setup saved register r15
 861         aghi    %r15,-STACK_FRAME_OVERHEAD
 862         stg     %r15,56(%r11)           # r15 stack pointer
 863         # set new psw address and exit
 864         larl    %r9,sysc_do_svc
 865         br      %r14
 866 cleanup_system_call_insn:
 867         .quad   system_call
 868         .quad   sysc_stmg
 869         .quad   sysc_per
 870         .quad   sysc_vtime+18
 871         .quad   sysc_vtime+42
 872
 873 cleanup_sysc_tif:
 874         larl    %r9,sysc_tif
 875         br      %r14
 876
 877 cleanup_sysc_restore:
 878         clg     %r9,BASED(cleanup_sysc_restore_insn)
 879         je      0f
 880         lg      %r9,24(%r11)            # get saved pointer to pt_regs
 881         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 882         mvc     0(64,%r11),__PT_R8(%r9)
 883         lmg     %r0,%r7,__PT_R0(%r9)
 884 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 885         br      %r14
 886 cleanup_sysc_restore_insn:
 887         .quad   sysc_done - 4
 888
 889 cleanup_io_tif:
 890         larl    %r9,io_tif
 891         br      %r14
 892
 893 cleanup_io_restore:
 894         clg     %r9,BASED(cleanup_io_restore_insn)
 895         je      0f
 896         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
 897         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
 898         mvc     0(64,%r11),__PT_R8(%r9)
 899         lmg     %r0,%r7,__PT_R0(%r9)
 900 0:      lmg     %r8,%r9,__LC_RETURN_PSW
 901         br      %r14
 902 cleanup_io_restore_insn:
 903         .quad   io_done - 4
 904
 905 cleanup_idle:
 906         # copy interrupt clock & cpu timer
 907         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 908         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
 909         cghi    %r11,__LC_SAVE_AREA_ASYNC
 910         je      0f
 911         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 912         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
 913 0:      # check if stck & stpt have been executed
 914         clg     %r9,BASED(cleanup_idle_insn)
 915         jhe     1f
 916         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
 917         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
 918 1:      # account system time going idle
 919         lg      %r9,__LC_STEAL_TIMER
 920         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
 921         slg     %r9,__LC_LAST_UPDATE_CLOCK
 922         stg     %r9,__LC_STEAL_TIMER
 923         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
 924         lg      %r9,__LC_SYSTEM_TIMER
 925         alg     %r9,__LC_LAST_UPDATE_TIMER
 926         slg     %r9,__TIMER_IDLE_ENTER(%r2)
 927         stg     %r9,__LC_SYSTEM_TIMER
 928         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
 929         # prepare return psw
 930         nihh    %r8,0xfffd              # clear wait state bit
 931         lg      %r9,48(%r11)            # return from psw_idle
 932         br      %r14
 933 cleanup_idle_insn:
 934         .quad   psw_idle_lpsw
 935
 936 /*
 937  * Integer constants
 938  */
 939         .align  8
 940 .Lcritical_start:
 941         .quad   __critical_start
 942 .Lcritical_length:
 943         .quad   __critical_end - __critical_start
 944
 945
 946 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 947 /*
 948  * sie64a calling convention:
 949  * %r2 pointer to sie control block
 950  * %r3 guest register save area
 951  */
 952 ENTRY(sie64a)
 953         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
 954         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
 955         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
 956         xc      __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
 957         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
 958 sie_loop:
 959         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 960         tm      __TI_flags+7(%r14),_TIF_EXIT_SIE
 961         jnz     sie_exit
 962         lg      %r14,__LC_GMAP                  # get gmap pointer
 963         ltgr    %r14,%r14
 964         jz      sie_gmap
 965         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
 966 sie_gmap:
 967         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 968         SPP     __SF_EMPTY(%r15)                # set guest id
 969         sie     0(%r14)
 970 sie_done:
 971         SPP     __SF_EMPTY+16(%r15)             # set host id
 972         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 973 sie_exit:
 974         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 975         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 976         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 977         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
 978         lghi    %r2,0
 979         br      %r14
 980 sie_fault:
 981         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 982         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
 983         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 984         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 985         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
 986         lghi    %r2,-EFAULT
 987         br      %r14
 988
 989         .align  8
 990 .Lsie_loop:
 991         .quad   sie_loop
 992 .Lsie_length:
 993         .quad   sie_done - sie_loop
 994 .Lhost_id:
 995         .quad   0
 996
 997         .section __ex_table,"a"
 998         .quad   sie_loop,sie_fault
 999         .previous
1000 #endif
1001
1002                 .section .rodata, "a"
1003 #define SYSCALL(esa,esame,emu)  .long esame
1004         .globl  sys_call_table
1005 sys_call_table:
1006 #include "syscalls.S"
1007 #undef SYSCALL
1008
1009 #ifdef CONFIG_COMPAT
1010
1011 #define SYSCALL(esa,esame,emu)  .long emu
1012 sys_call_table_emu:
1013 #include "syscalls.S"
1014 #undef SYSCALL
1015 #endif