Pileus Git - ~andy/linux/blob - arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36
  37 /*
  38  * System calls.
  39  */
  40         .section        ".toc","aw"
  41 .SYS_CALL_TABLE:
  42         .tc .sys_call_table[TC],.sys_call_table
  43
  44 /* This value is used to mark exception frames on the stack. */
  45 exception_marker:
  46         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  47
  48         .section        ".text"
  49         .align 7
  50
  51 #undef SHOW_SYSCALLS
  52
  53         .globl system_call_common
  54 system_call_common:
  55         andi.   r10,r12,MSR_PR
  56         mr      r10,r1
  57         addi    r1,r1,-INT_FRAME_SIZE
  58         beq-    1f
  59         ld      r1,PACAKSAVE(r13)
  60 1:      std     r10,0(r1)
  61         std     r11,_NIP(r1)
  62         std     r12,_MSR(r1)
  63         std     r0,GPR0(r1)
  64         std     r10,GPR1(r1)
  65         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  66         std     r2,GPR2(r1)
  67         std     r3,GPR3(r1)
  68         mfcr    r2
  69         std     r4,GPR4(r1)
  70         std     r5,GPR5(r1)
  71         std     r6,GPR6(r1)
  72         std     r7,GPR7(r1)
  73         std     r8,GPR8(r1)
  74         li      r11,0
  75         std     r11,GPR9(r1)
  76         std     r11,GPR10(r1)
  77         std     r11,GPR11(r1)
  78         std     r11,GPR12(r1)
  79         std     r11,_XER(r1)
  80         std     r11,_CTR(r1)
  81         std     r9,GPR13(r1)
  82         mflr    r10
  83         /*
  84          * This clears CR0.SO (bit 28), which is the error indication on
  85          * return from this system call.
  86          */
  87         rldimi  r2,r11,28,(63-28)
  88         li      r11,0xc01
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         std     r3,ORIG_GPR3(r1)
  92         std     r2,_CCR(r1)
  93         ld      r2,PACATOC(r13)
  94         addi    r9,r1,STACK_FRAME_OVERHEAD
  95         ld      r11,exception_marker@toc(r2)
  96         std     r11,-16(r9)             /* "regshere" marker */
  97 #if defined(CONFIG_VIRT_CPU_ACCOUNTING) && defined(CONFIG_PPC_SPLPAR)
  98 BEGIN_FW_FTR_SECTION
  99         beq     33f
 100         /* if from user, see if there are any DTL entries to process */
 101         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 102         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 103         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 104         cmpd    cr1,r11,r10
 105         beq+    cr1,33f
 106         bl      .accumulate_stolen_time
 107         REST_GPR(0,r1)
 108         REST_4GPRS(3,r1)
 109         REST_2GPRS(7,r1)
 110         addi    r9,r1,STACK_FRAME_OVERHEAD
 111 33:
 112 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 113 #endif /* CONFIG_VIRT_CPU_ACCOUNTING && CONFIG_PPC_SPLPAR */
 114
 115         /*
 116          * A syscall should always be called with interrupts enabled
 117          * so we just unconditionally hard-enable here. When some kind
 118          * of irq tracing is used, we additionally check that condition
 119          * is correct
 120          */
 121 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 122         lbz     r10,PACASOFTIRQEN(r13)
 123         xori    r10,r10,1
 124 1:      tdnei   r10,0
 125         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 126 #endif
 127
 128 #ifdef CONFIG_PPC_BOOK3E
 129         wrteei  1
 130 #else
 131         ld      r11,PACAKMSR(r13)
 132         ori     r11,r11,MSR_EE
 133         mtmsrd  r11,1
 134 #endif /* CONFIG_PPC_BOOK3E */
 135
 136         /* We do need to set SOFTE in the stack frame or the return
 137          * from interrupt will be painful
 138          */
 139         li      r10,1
 140         std     r10,SOFTE(r1)
 141
 142 #ifdef SHOW_SYSCALLS
 143         bl      .do_show_syscall
 144         REST_GPR(0,r1)
 145         REST_4GPRS(3,r1)
 146         REST_2GPRS(7,r1)
 147         addi    r9,r1,STACK_FRAME_OVERHEAD
 148 #endif
 149         clrrdi  r11,r1,THREAD_SHIFT
 150         ld      r10,TI_FLAGS(r11)
 151         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 152         bne-    syscall_dotrace
 153 .Lsyscall_dotrace_cont:
 154         cmpldi  0,r0,NR_syscalls
 155         bge-    syscall_enosys
 156
 157 system_call:                    /* label this so stack traces look sane */
 158 /*
 159  * Need to vector to 32 Bit or default sys_call_table here,
 160  * based on caller's run-mode / personality.
 161  */
 162         ld      r11,.SYS_CALL_TABLE@toc(2)
 163         andi.   r10,r10,_TIF_32BIT
 164         beq     15f
 165         addi    r11,r11,8       /* use 32-bit syscall entries */
 166         clrldi  r3,r3,32
 167         clrldi  r4,r4,32
 168         clrldi  r5,r5,32
 169         clrldi  r6,r6,32
 170         clrldi  r7,r7,32
 171         clrldi  r8,r8,32
 172 15:
 173         slwi    r0,r0,4
 174         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 175         mtctr   r10
 176         bctrl                   /* Call handler */
 177
 178 syscall_exit:
 179         std     r3,RESULT(r1)
 180 #ifdef SHOW_SYSCALLS
 181         bl      .do_show_syscall_exit
 182         ld      r3,RESULT(r1)
 183 #endif
 184         clrrdi  r12,r1,THREAD_SHIFT
 185
 186         ld      r8,_MSR(r1)
 187 #ifdef CONFIG_PPC_BOOK3S
 188         /* No MSR:RI on BookE */
 189         andi.   r10,r8,MSR_RI
 190         beq-    unrecov_restore
 191 #endif
 192         /*
 193          * Disable interrupts so current_thread_info()->flags can't change,
 194          * and so that we don't get interrupted after loading SRR0/1.
 195          */
 196 #ifdef CONFIG_PPC_BOOK3E
 197         wrteei  0
 198 #else
 199         ld      r10,PACAKMSR(r13)
 200         mtmsrd  r10,1
 201 #endif /* CONFIG_PPC_BOOK3E */
 202
 203         ld      r9,TI_FLAGS(r12)
 204         li      r11,-_LAST_ERRNO
 205         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 206         bne-    syscall_exit_work
 207         cmpld   r3,r11
 208         ld      r5,_CCR(r1)
 209         bge-    syscall_error
 210 .Lsyscall_error_cont:
 211         ld      r7,_NIP(r1)
 212 BEGIN_FTR_SECTION
 213         stdcx.  r0,0,r1                 /* to clear the reservation */
 214 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 215         andi.   r6,r8,MSR_PR
 216         ld      r4,_LINK(r1)
 217         /*
 218          * Clear RI before restoring r13.  If we are returning to
 219          * userspace and we take an exception after restoring r13,
 220          * we end up corrupting the userspace r13 value.
 221          */
 222 #ifdef CONFIG_PPC_BOOK3S
 223         /* No MSR:RI on BookE */
 224         li      r12,MSR_RI
 225         andc    r11,r10,r12
 226         mtmsrd  r11,1                   /* clear MSR.RI */
 227 #endif /* CONFIG_PPC_BOOK3S */
 228
 229         beq-    1f
 230         ACCOUNT_CPU_USER_EXIT(r11, r12)
 231         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 232 1:      ld      r2,GPR2(r1)
 233         ld      r1,GPR1(r1)
 234         mtlr    r4
 235         mtcr    r5
 236         mtspr   SPRN_SRR0,r7
 237         mtspr   SPRN_SRR1,r8
 238         RFI
 239         b       .       /* prevent speculative execution */
 240
 241 syscall_error:
 242         oris    r5,r5,0x1000    /* Set SO bit in CR */
 243         neg     r3,r3
 244         std     r5,_CCR(r1)
 245         b       .Lsyscall_error_cont
 246
 247 /* Traced system call support */
 248 syscall_dotrace:
 249         bl      .save_nvgprs
 250         addi    r3,r1,STACK_FRAME_OVERHEAD
 251         bl      .do_syscall_trace_enter
 252         /*
 253          * Restore argument registers possibly just changed.
 254          * We use the return value of do_syscall_trace_enter
 255          * for the call number to look up in the table (r0).
 256          */
 257         mr      r0,r3
 258         ld      r3,GPR3(r1)
 259         ld      r4,GPR4(r1)
 260         ld      r5,GPR5(r1)
 261         ld      r6,GPR6(r1)
 262         ld      r7,GPR7(r1)
 263         ld      r8,GPR8(r1)
 264         addi    r9,r1,STACK_FRAME_OVERHEAD
 265         clrrdi  r10,r1,THREAD_SHIFT
 266         ld      r10,TI_FLAGS(r10)
 267         b       .Lsyscall_dotrace_cont
 268
 269 syscall_enosys:
 270         li      r3,-ENOSYS
 271         b       syscall_exit
 272
 273 syscall_exit_work:
 274         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 275          If TIF_NOERROR is set, just save r3 as it is. */
 276
 277         andi.   r0,r9,_TIF_RESTOREALL
 278         beq+    0f
 279         REST_NVGPRS(r1)
 280         b       2f
 281 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 282         blt+    1f
 283         andi.   r0,r9,_TIF_NOERROR
 284         bne-    1f
 285         ld      r5,_CCR(r1)
 286         neg     r3,r3
 287         oris    r5,r5,0x1000    /* Set SO bit in CR */
 288         std     r5,_CCR(r1)
 289 1:      std     r3,GPR3(r1)
 290 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 291         beq     4f
 292
 293         /* Clear per-syscall TIF flags if any are set.  */
 294
 295         li      r11,_TIF_PERSYSCALL_MASK
 296         addi    r12,r12,TI_FLAGS
 297 3:      ldarx   r10,0,r12
 298         andc    r10,r10,r11
 299         stdcx.  r10,0,r12
 300         bne-    3b
 301         subi    r12,r12,TI_FLAGS
 302
 303 4:      /* Anything else left to do? */
 304         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 305         beq     .ret_from_except_lite
 306
 307         /* Re-enable interrupts */
 308 #ifdef CONFIG_PPC_BOOK3E
 309         wrteei  1
 310 #else
 311         ld      r10,PACAKMSR(r13)
 312         ori     r10,r10,MSR_EE
 313         mtmsrd  r10,1
 314 #endif /* CONFIG_PPC_BOOK3E */
 315
 316         bl      .save_nvgprs
 317         addi    r3,r1,STACK_FRAME_OVERHEAD
 318         bl      .do_syscall_trace_leave
 319         b       .ret_from_except
 320
 321 /* Save non-volatile GPRs, if not already saved. */
 322 _GLOBAL(save_nvgprs)
 323         ld      r11,_TRAP(r1)
 324         andi.   r0,r11,1
 325         beqlr-
 326         SAVE_NVGPRS(r1)
 327         clrrdi  r0,r11,1
 328         std     r0,_TRAP(r1)
 329         blr
 330
 331
 332 /*
 333  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 334  * and thus put the process into the stopped state where we might
 335  * want to examine its user state with ptrace.  Therefore we need
 336  * to save all the nonvolatile registers (r14 - r31) before calling
 337  * the C code.  Similarly, fork, vfork and clone need the full
 338  * register state on the stack so that it can be copied to the child.
 339  */
 340
 341 _GLOBAL(ppc_fork)
 342         bl      .save_nvgprs
 343         bl      .sys_fork
 344         b       syscall_exit
 345
 346 _GLOBAL(ppc_vfork)
 347         bl      .save_nvgprs
 348         bl      .sys_vfork
 349         b       syscall_exit
 350
 351 _GLOBAL(ppc_clone)
 352         bl      .save_nvgprs
 353         bl      .sys_clone
 354         b       syscall_exit
 355
 356 _GLOBAL(ppc32_swapcontext)
 357         bl      .save_nvgprs
 358         bl      .compat_sys_swapcontext
 359         b       syscall_exit
 360
 361 _GLOBAL(ppc64_swapcontext)
 362         bl      .save_nvgprs
 363         bl      .sys_swapcontext
 364         b       syscall_exit
 365
 366 _GLOBAL(ret_from_fork)
 367         bl      .schedule_tail
 368         REST_NVGPRS(r1)
 369         li      r3,0
 370         b       syscall_exit
 371
 372 /*
 373  * This routine switches between two different tasks.  The process
 374  * state of one is saved on its kernel stack.  Then the state
 375  * of the other is restored from its kernel stack.  The memory
 376  * management hardware is updated to the second process's state.
 377  * Finally, we can return to the second process, via ret_from_except.
 378  * On entry, r3 points to the THREAD for the current task, r4
 379  * points to the THREAD for the new task.
 380  *
 381  * Note: there are two ways to get to the "going out" portion
 382  * of this code; either by coming in via the entry (_switch)
 383  * or via "fork" which must set up an environment equivalent
 384  * to the "_switch" path.  If you change this you'll have to change
 385  * the fork code also.
 386  *
 387  * The code which creates the new task context is in 'copy_thread'
 388  * in arch/powerpc/kernel/process.c
 389  */
 390         .align  7
 391 _GLOBAL(_switch)
 392         mflr    r0
 393         std     r0,16(r1)
 394         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 395         /* r3-r13 are caller saved -- Cort */
 396         SAVE_8GPRS(14, r1)
 397         SAVE_10GPRS(22, r1)
 398         mflr    r20             /* Return to switch caller */
 399         mfmsr   r22
 400         li      r0, MSR_FP
 401 #ifdef CONFIG_VSX
 402 BEGIN_FTR_SECTION
 403         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 404 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 405 #endif /* CONFIG_VSX */
 406 #ifdef CONFIG_ALTIVEC
 407 BEGIN_FTR_SECTION
 408         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 409         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 410         std     r24,THREAD_VRSAVE(r3)
 411 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 412 #endif /* CONFIG_ALTIVEC */
 413 #ifdef CONFIG_PPC64
 414 BEGIN_FTR_SECTION
 415         mfspr   r25,SPRN_DSCR
 416         std     r25,THREAD_DSCR(r3)
 417 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 418 #endif
 419         and.    r0,r0,r22
 420         beq+    1f
 421         andc    r22,r22,r0
 422         MTMSRD(r22)
 423         isync
 424 1:      std     r20,_NIP(r1)
 425         mfcr    r23
 426         std     r23,_CCR(r1)
 427         std     r1,KSP(r3)      /* Set old stack pointer */
 428
 429 #ifdef CONFIG_SMP
 430         /* We need a sync somewhere here to make sure that if the
 431          * previous task gets rescheduled on another CPU, it sees all
 432          * stores it has performed on this one.
 433          */
 434         sync
 435 #endif /* CONFIG_SMP */
 436
 437         /*
 438          * If we optimise away the clear of the reservation in system
 439          * calls because we know the CPU tracks the address of the
 440          * reservation, then we need to clear it here to cover the
 441          * case that the kernel context switch path has no larx
 442          * instructions.
 443          */
 444 BEGIN_FTR_SECTION
 445         ldarx   r6,0,r1
 446 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 447
 448         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 449         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 450
 451         ld      r8,KSP(r4)      /* new stack pointer */
 452 #ifdef CONFIG_PPC_BOOK3S
 453 BEGIN_FTR_SECTION
 454   BEGIN_FTR_SECTION_NESTED(95)
 455         clrrdi  r6,r8,28        /* get its ESID */
 456         clrrdi  r9,r1,28        /* get current sp ESID */
 457   FTR_SECTION_ELSE_NESTED(95)
 458         clrrdi  r6,r8,40        /* get its 1T ESID */
 459         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 460   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 461 FTR_SECTION_ELSE
 462         b       2f
 463 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 464         clrldi. r0,r6,2         /* is new ESID c00000000? */
 465         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 466         cror    eq,4*cr1+eq,eq
 467         beq     2f              /* if yes, don't slbie it */
 468
 469         /* Bolt in the new stack SLB entry */
 470         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 471         oris    r0,r6,(SLB_ESID_V)@h
 472         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 473 BEGIN_FTR_SECTION
 474         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 475         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 476         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 477 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 478
 479         /* Update the last bolted SLB.  No write barriers are needed
 480          * here, provided we only update the current CPU's SLB shadow
 481          * buffer.
 482          */
 483         ld      r9,PACA_SLBSHADOWPTR(r13)
 484         li      r12,0
 485         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 486         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 487         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 488
 489         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 490          * we have 1TB segments, the only CPUs known to have the errata
 491          * only support less than 1TB of system memory and we'll never
 492          * actually hit this code path.
 493          */
 494
 495         slbie   r6
 496         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 497         slbmte  r7,r0
 498         isync
 499 2:
 500 #endif /* !CONFIG_PPC_BOOK3S */
 501
 502         clrrdi  r7,r8,THREAD_SHIFT      /* base of new stack */
 503         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 504            because we don't need to leave the 288-byte ABI gap at the
 505            top of the kernel stack. */
 506         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 507
 508         mr      r1,r8           /* start using new stack pointer */
 509         std     r7,PACAKSAVE(r13)
 510
 511         ld      r6,_CCR(r1)
 512         mtcrf   0xFF,r6
 513
 514 #ifdef CONFIG_ALTIVEC
 515 BEGIN_FTR_SECTION
 516         ld      r0,THREAD_VRSAVE(r4)
 517         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 518 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 519 #endif /* CONFIG_ALTIVEC */
 520 #ifdef CONFIG_PPC64
 521 BEGIN_FTR_SECTION
 522         ld      r0,THREAD_DSCR(r4)
 523         cmpd    r0,r25
 524         beq     1f
 525         mtspr   SPRN_DSCR,r0
 526 1:
 527 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 528 #endif
 529
 530         /* r3-r13 are destroyed -- Cort */
 531         REST_8GPRS(14, r1)
 532         REST_10GPRS(22, r1)
 533
 534         /* convert old thread to its task_struct for return value */
 535         addi    r3,r3,-THREAD
 536         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 537         mtlr    r7
 538         addi    r1,r1,SWITCH_FRAME_SIZE
 539         blr
 540
 541         .align  7
 542 _GLOBAL(ret_from_except)
 543         ld      r11,_TRAP(r1)
 544         andi.   r0,r11,1
 545         bne     .ret_from_except_lite
 546         REST_NVGPRS(r1)
 547
 548 _GLOBAL(ret_from_except_lite)
 549         /*
 550          * Disable interrupts so that current_thread_info()->flags
 551          * can't change between when we test it and when we return
 552          * from the interrupt.
 553          */
 554 #ifdef CONFIG_PPC_BOOK3E
 555         wrteei  0
 556 #else
 557         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 558         mtmsrd  r10,1             /* Update machine state */
 559 #endif /* CONFIG_PPC_BOOK3E */
 560
 561 #ifdef CONFIG_PREEMPT
 562         clrrdi  r9,r1,THREAD_SHIFT      /* current_thread_info() */
 563         li      r0,_TIF_NEED_RESCHED    /* bits to check */
 564         ld      r3,_MSR(r1)
 565         ld      r4,TI_FLAGS(r9)
 566         /* Move MSR_PR bit in r3 to _TIF_SIGPENDING position in r0 */
 567         rlwimi  r0,r3,32+TIF_SIGPENDING-MSR_PR_LG,_TIF_SIGPENDING
 568         and.    r0,r4,r0        /* check NEED_RESCHED and maybe SIGPENDING */
 569         bne     do_work
 570
 571 #else /* !CONFIG_PREEMPT */
 572         ld      r3,_MSR(r1)     /* Returning to user mode? */
 573         andi.   r3,r3,MSR_PR
 574         beq     restore         /* if not, just restore regs and return */
 575
 576         /* Check current_thread_info()->flags */
 577         clrrdi  r9,r1,THREAD_SHIFT
 578         ld      r4,TI_FLAGS(r9)
 579         andi.   r0,r4,_TIF_USER_WORK_MASK
 580         bne     do_work
 581 #endif /* !CONFIG_PREEMPT */
 582
 583         .globl  fast_exc_return_irq
 584 fast_exc_return_irq:
 585 restore:
 586         /*
 587          * This is the main kernel exit path. First we check if we
 588          * are about to re-enable interrupts
 589          */
 590         ld      r5,SOFTE(r1)
 591         lbz     r6,PACASOFTIRQEN(r13)
 592         cmpwi   cr0,r5,0
 593         beq     restore_irq_off
 594
 595         /* We are enabling, were we already enabled ? Yes, just return */
 596         cmpwi   cr0,r6,1
 597         beq     cr0,do_restore
 598
 599         /*
 600          * We are about to soft-enable interrupts (we are hard disabled
 601          * at this point). We check if there's anything that needs to
 602          * be replayed first.
 603          */
 604         lbz     r0,PACAIRQHAPPENED(r13)
 605         cmpwi   cr0,r0,0
 606         bne-    restore_check_irq_replay
 607
 608         /*
 609          * Get here when nothing happened while soft-disabled, just
 610          * soft-enable and move-on. We will hard-enable as a side
 611          * effect of rfi
 612          */
 613 restore_no_replay:
 614         TRACE_ENABLE_INTS
 615         li      r0,1
 616         stb     r0,PACASOFTIRQEN(r13);
 617
 618         /*
 619          * Final return path. BookE is handled in a different file
 620          */
 621 do_restore:
 622 #ifdef CONFIG_PPC_BOOK3E
 623         b       .exception_return_book3e
 624 #else
 625         /*
 626          * Clear the reservation. If we know the CPU tracks the address of
 627          * the reservation then we can potentially save some cycles and use
 628          * a larx. On POWER6 and POWER7 this is significantly faster.
 629          */
 630 BEGIN_FTR_SECTION
 631         stdcx.  r0,0,r1         /* to clear the reservation */
 632 FTR_SECTION_ELSE
 633         ldarx   r4,0,r1
 634 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 635
 636         /*
 637          * Some code path such as load_up_fpu or altivec return directly
 638          * here. They run entirely hard disabled and do not alter the
 639          * interrupt state. They also don't use lwarx/stwcx. and thus
 640          * are known not to leave dangling reservations.
 641          */
 642         .globl  fast_exception_return
 643 fast_exception_return:
 644         ld      r3,_MSR(r1)
 645         ld      r4,_CTR(r1)
 646         ld      r0,_LINK(r1)
 647         mtctr   r4
 648         mtlr    r0
 649         ld      r4,_XER(r1)
 650         mtspr   SPRN_XER,r4
 651
 652         REST_8GPRS(5, r1)
 653
 654         andi.   r0,r3,MSR_RI
 655         beq-    unrecov_restore
 656
 657         /*
 658          * Clear RI before restoring r13.  If we are returning to
 659          * userspace and we take an exception after restoring r13,
 660          * we end up corrupting the userspace r13 value.
 661          */
 662         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 663         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 664         mtmsrd  r4,1
 665
 666         /*
 667          * r13 is our per cpu area, only restore it if we are returning to
 668          * userspace the value stored in the stack frame may belong to
 669          * another CPU.
 670          */
 671         andi.   r0,r3,MSR_PR
 672         beq     1f
 673         ACCOUNT_CPU_USER_EXIT(r2, r4)
 674         REST_GPR(13, r1)
 675 1:
 676         mtspr   SPRN_SRR1,r3
 677
 678         ld      r2,_CCR(r1)
 679         mtcrf   0xFF,r2
 680         ld      r2,_NIP(r1)
 681         mtspr   SPRN_SRR0,r2
 682
 683         ld      r0,GPR0(r1)
 684         ld      r2,GPR2(r1)
 685         ld      r3,GPR3(r1)
 686         ld      r4,GPR4(r1)
 687         ld      r1,GPR1(r1)
 688
 689         rfid
 690         b       .       /* prevent speculative execution */
 691
 692 #endif /* CONFIG_PPC_BOOK3E */
 693
 694         /*
 695          * We are returning to a context with interrupts soft disabled.
 696          *
 697          * However, we may also about to hard enable, so we need to
 698          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 699          * or that bit can get out of sync and bad things will happen
 700          */
 701 restore_irq_off:
 702         ld      r3,_MSR(r1)
 703         lbz     r7,PACAIRQHAPPENED(r13)
 704         andi.   r0,r3,MSR_EE
 705         beq     1f
 706         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 707         stb     r7,PACAIRQHAPPENED(r13)
 708 1:      li      r0,0
 709         stb     r0,PACASOFTIRQEN(r13);
 710         TRACE_DISABLE_INTS
 711         b       do_restore
 712
 713         /*
 714          * Something did happen, check if a re-emit is needed
 715          * (this also clears paca->irq_happened)
 716          */
 717 restore_check_irq_replay:
 718         /* XXX: We could implement a fast path here where we check
 719          * for irq_happened being just 0x01, in which case we can
 720          * clear it and return. That means that we would potentially
 721          * miss a decrementer having wrapped all the way around.
 722          *
 723          * Still, this might be useful for things like hash_page
 724          */
 725         bl      .__check_irq_replay
 726         cmpwi   cr0,r3,0
 727         beq     restore_no_replay
 728
 729         /*
 730          * We need to re-emit an interrupt. We do so by re-using our
 731          * existing exception frame. We first change the trap value,
 732          * but we need to ensure we preserve the low nibble of it
 733          */
 734         ld      r4,_TRAP(r1)
 735         clrldi  r4,r4,60
 736         or      r4,r4,r3
 737         std     r4,_TRAP(r1)
 738
 739         /*
 740          * Then find the right handler and call it. Interrupts are
 741          * still soft-disabled and we keep them that way.
 742         */
 743         cmpwi   cr0,r3,0x500
 744         bne     1f
 745         addi    r3,r1,STACK_FRAME_OVERHEAD;
 746         bl      .do_IRQ
 747         b       .ret_from_except
 748 1:      cmpwi   cr0,r3,0x900
 749         bne     1f
 750         addi    r3,r1,STACK_FRAME_OVERHEAD;
 751         bl      .timer_interrupt
 752         b       .ret_from_except
 753 #ifdef CONFIG_PPC_BOOK3E
 754 1:      cmpwi   cr0,r3,0x280
 755         bne     1f
 756         addi    r3,r1,STACK_FRAME_OVERHEAD;
 757         bl      .doorbell_exception
 758         b       .ret_from_except
 759 #endif /* CONFIG_PPC_BOOK3E */
 760 1:      b       .ret_from_except /* What else to do here ? */
 761
 762
 763
 764 3:
 765 do_work:
 766 #ifdef CONFIG_PREEMPT
 767         andi.   r0,r3,MSR_PR    /* Returning to user mode? */
 768         bne     user_work
 769         /* Check that preempt_count() == 0 and interrupts are enabled */
 770         lwz     r8,TI_PREEMPT(r9)
 771         cmpwi   cr1,r8,0
 772         ld      r0,SOFTE(r1)
 773         cmpdi   r0,0
 774         crandc  eq,cr1*4+eq,eq
 775         bne     restore
 776
 777         /*
 778          * Here we are preempting the current task. We want to make
 779          * sure we are soft-disabled first
 780          */
 781         SOFT_DISABLE_INTS(r3,r4)
 782 1:      bl      .preempt_schedule_irq
 783
 784         /* Re-test flags and eventually loop */
 785         clrrdi  r9,r1,THREAD_SHIFT
 786         ld      r4,TI_FLAGS(r9)
 787         andi.   r0,r4,_TIF_NEED_RESCHED
 788         bne     1b
 789         b       restore
 790
 791 user_work:
 792 #endif /* CONFIG_PREEMPT */
 793
 794         andi.   r0,r4,_TIF_NEED_RESCHED
 795         beq     1f
 796         bl      .restore_interrupts
 797         bl      .schedule
 798         b       .ret_from_except_lite
 799
 800 1:      bl      .save_nvgprs
 801         bl      .restore_interrupts
 802         addi    r3,r1,STACK_FRAME_OVERHEAD
 803         bl      .do_notify_resume
 804         b       .ret_from_except
 805
 806 unrecov_restore:
 807         addi    r3,r1,STACK_FRAME_OVERHEAD
 808         bl      .unrecoverable_exception
 809         b       unrecov_restore
 810
 811 #ifdef CONFIG_PPC_RTAS
 812 /*
 813  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 814  * called with the MMU off.
 815  *
 816  * In addition, we need to be in 32b mode, at least for now.
 817  *
 818  * Note: r3 is an input parameter to rtas, so don't trash it...
 819  */
 820 _GLOBAL(enter_rtas)
 821         mflr    r0
 822         std     r0,16(r1)
 823         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 824
 825         /* Because RTAS is running in 32b mode, it clobbers the high order half
 826          * of all registers that it saves.  We therefore save those registers
 827          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 828          */
 829         SAVE_GPR(2, r1)                 /* Save the TOC */
 830         SAVE_GPR(13, r1)                /* Save paca */
 831         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 832         SAVE_10GPRS(22, r1)             /* ditto */
 833
 834         mfcr    r4
 835         std     r4,_CCR(r1)
 836         mfctr   r5
 837         std     r5,_CTR(r1)
 838         mfspr   r6,SPRN_XER
 839         std     r6,_XER(r1)
 840         mfdar   r7
 841         std     r7,_DAR(r1)
 842         mfdsisr r8
 843         std     r8,_DSISR(r1)
 844
 845         /* Temporary workaround to clear CR until RTAS can be modified to
 846          * ignore all bits.
 847          */
 848         li      r0,0
 849         mtcr    r0
 850
 851 #ifdef CONFIG_BUG
 852         /* There is no way it is acceptable to get here with interrupts enabled,
 853          * check it with the asm equivalent of WARN_ON
 854          */
 855         lbz     r0,PACASOFTIRQEN(r13)
 856 1:      tdnei   r0,0
 857         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 858 #endif
 859
 860         /* Hard-disable interrupts */
 861         mfmsr   r6
 862         rldicl  r7,r6,48,1
 863         rotldi  r7,r7,16
 864         mtmsrd  r7,1
 865
 866         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 867          * so they are saved in the PACA which allows us to restore
 868          * our original state after RTAS returns.
 869          */
 870         std     r1,PACAR1(r13)
 871         std     r6,PACASAVEDMSR(r13)
 872
 873         /* Setup our real return addr */
 874         LOAD_REG_ADDR(r4,.rtas_return_loc)
 875         clrldi  r4,r4,2                 /* convert to realmode address */
 876         mtlr    r4
 877
 878         li      r0,0
 879         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 880         andc    r0,r6,r0
 881
 882         li      r9,1
 883         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 884         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 885         andc    r6,r0,r9
 886         sync                            /* disable interrupts so SRR0/1 */
 887         mtmsrd  r0                      /* don't get trashed */
 888
 889         LOAD_REG_ADDR(r4, rtas)
 890         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 891         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 892
 893         mtspr   SPRN_SRR0,r5
 894         mtspr   SPRN_SRR1,r6
 895         rfid
 896         b       .       /* prevent speculative execution */
 897
 898 _STATIC(rtas_return_loc)
 899         /* relocation is off at this point */
 900         GET_PACA(r4)
 901         clrldi  r4,r4,2                 /* convert to realmode address */
 902
 903         bcl     20,31,$+4
 904 0:      mflr    r3
 905         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
 906
 907         mfmsr   r6
 908         li      r0,MSR_RI
 909         andc    r6,r6,r0
 910         sync
 911         mtmsrd  r6
 912
 913         ld      r1,PACAR1(r4)           /* Restore our SP */
 914         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 915
 916         mtspr   SPRN_SRR0,r3
 917         mtspr   SPRN_SRR1,r4
 918         rfid
 919         b       .       /* prevent speculative execution */
 920
 921         .align  3
 922 1:      .llong  .rtas_restore_regs
 923
 924 _STATIC(rtas_restore_regs)
 925         /* relocation is on at this point */
 926         REST_GPR(2, r1)                 /* Restore the TOC */
 927         REST_GPR(13, r1)                /* Restore paca */
 928         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 929         REST_10GPRS(22, r1)             /* ditto */
 930
 931         GET_PACA(r13)
 932
 933         ld      r4,_CCR(r1)
 934         mtcr    r4
 935         ld      r5,_CTR(r1)
 936         mtctr   r5
 937         ld      r6,_XER(r1)
 938         mtspr   SPRN_XER,r6
 939         ld      r7,_DAR(r1)
 940         mtdar   r7
 941         ld      r8,_DSISR(r1)
 942         mtdsisr r8
 943
 944         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 945         ld      r0,16(r1)               /* get return address */
 946
 947         mtlr    r0
 948         blr                             /* return to caller */
 949
 950 #endif /* CONFIG_PPC_RTAS */
 951
 952 _GLOBAL(enter_prom)
 953         mflr    r0
 954         std     r0,16(r1)
 955         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 956
 957         /* Because PROM is running in 32b mode, it clobbers the high order half
 958          * of all registers that it saves.  We therefore save those registers
 959          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
 960          */
 961         SAVE_GPR(2, r1)
 962         SAVE_GPR(13, r1)
 963         SAVE_8GPRS(14, r1)
 964         SAVE_10GPRS(22, r1)
 965         mfcr    r10
 966         mfmsr   r11
 967         std     r10,_CCR(r1)
 968         std     r11,_MSR(r1)
 969
 970         /* Get the PROM entrypoint */
 971         mtlr    r4
 972
 973         /* Switch MSR to 32 bits mode
 974          */
 975 #ifdef CONFIG_PPC_BOOK3E
 976         rlwinm  r11,r11,0,1,31
 977         mtmsr   r11
 978 #else /* CONFIG_PPC_BOOK3E */
 979         mfmsr   r11
 980         li      r12,1
 981         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
 982         andc    r11,r11,r12
 983         li      r12,1
 984         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
 985         andc    r11,r11,r12
 986         mtmsrd  r11
 987 #endif /* CONFIG_PPC_BOOK3E */
 988         isync
 989
 990         /* Enter PROM here... */
 991         blrl
 992
 993         /* Just make sure that r1 top 32 bits didn't get
 994          * corrupt by OF
 995          */
 996         rldicl  r1,r1,0,32
 997
 998         /* Restore the MSR (back to 64 bits) */
 999         ld      r0,_MSR(r1)
1000         MTMSRD(r0)
1001         isync
1002
1003         /* Restore other registers */
1004         REST_GPR(2, r1)
1005         REST_GPR(13, r1)
1006         REST_8GPRS(14, r1)
1007         REST_10GPRS(22, r1)
1008         ld      r4,_CCR(r1)
1009         mtcr    r4
1010
1011         addi    r1,r1,PROM_FRAME_SIZE
1012         ld      r0,16(r1)
1013         mtlr    r0
1014         blr
1015
1016 #ifdef CONFIG_FUNCTION_TRACER
1017 #ifdef CONFIG_DYNAMIC_FTRACE
1018 _GLOBAL(mcount)
1019 _GLOBAL(_mcount)
1020         blr
1021
1022 _GLOBAL(ftrace_caller)
1023         /* Taken from output of objdump from lib64/glibc */
1024         mflr    r3
1025         ld      r11, 0(r1)
1026         stdu    r1, -112(r1)
1027         std     r3, 128(r1)
1028         ld      r4, 16(r11)
1029         subi    r3, r3, MCOUNT_INSN_SIZE
1030 .globl ftrace_call
1031 ftrace_call:
1032         bl      ftrace_stub
1033         nop
1034 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1035 .globl ftrace_graph_call
1036 ftrace_graph_call:
1037         b       ftrace_graph_stub
1038 _GLOBAL(ftrace_graph_stub)
1039 #endif
1040         ld      r0, 128(r1)
1041         mtlr    r0
1042         addi    r1, r1, 112
1043 _GLOBAL(ftrace_stub)
1044         blr
1045 #else
1046 _GLOBAL(mcount)
1047         blr
1048
1049 _GLOBAL(_mcount)
1050         /* Taken from output of objdump from lib64/glibc */
1051         mflr    r3
1052         ld      r11, 0(r1)
1053         stdu    r1, -112(r1)
1054         std     r3, 128(r1)
1055         ld      r4, 16(r11)
1056
1057         subi    r3, r3, MCOUNT_INSN_SIZE
1058         LOAD_REG_ADDR(r5,ftrace_trace_function)
1059         ld      r5,0(r5)
1060         ld      r5,0(r5)
1061         mtctr   r5
1062         bctrl
1063         nop
1064
1065
1066 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1067         b       ftrace_graph_caller
1068 #endif
1069         ld      r0, 128(r1)
1070         mtlr    r0
1071         addi    r1, r1, 112
1072 _GLOBAL(ftrace_stub)
1073         blr
1074
1075 #endif /* CONFIG_DYNAMIC_FTRACE */
1076
1077 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1078 _GLOBAL(ftrace_graph_caller)
1079         /* load r4 with local address */
1080         ld      r4, 128(r1)
1081         subi    r4, r4, MCOUNT_INSN_SIZE
1082
1083         /* get the parent address */
1084         ld      r11, 112(r1)
1085         addi    r3, r11, 16
1086
1087         bl      .prepare_ftrace_return
1088         nop
1089
1090         ld      r0, 128(r1)
1091         mtlr    r0
1092         addi    r1, r1, 112
1093         blr
1094
1095 _GLOBAL(return_to_handler)
1096         /* need to save return values */
1097         std     r4,  -24(r1)
1098         std     r3,  -16(r1)
1099         std     r31, -8(r1)
1100         mr      r31, r1
1101         stdu    r1, -112(r1)
1102
1103         bl      .ftrace_return_to_handler
1104         nop
1105
1106         /* return value has real return address */
1107         mtlr    r3
1108
1109         ld      r1, 0(r1)
1110         ld      r4,  -24(r1)
1111         ld      r3,  -16(r1)
1112         ld      r31, -8(r1)
1113
1114         /* Jump back to real return address */
1115         blr
1116
1117 _GLOBAL(mod_return_to_handler)
1118         /* need to save return values */
1119         std     r4,  -32(r1)
1120         std     r3,  -24(r1)
1121         /* save TOC */
1122         std     r2,  -16(r1)
1123         std     r31, -8(r1)
1124         mr      r31, r1
1125         stdu    r1, -112(r1)
1126
1127         /*
1128          * We are in a module using the module's TOC.
1129          * Switch to our TOC to run inside the core kernel.
1130          */
1131         ld      r2, PACATOC(r13)
1132
1133         bl      .ftrace_return_to_handler
1134         nop
1135
1136         /* return value has real return address */
1137         mtlr    r3
1138
1139         ld      r1, 0(r1)
1140         ld      r4,  -32(r1)
1141         ld      r3,  -24(r1)
1142         ld      r2,  -16(r1)
1143         ld      r31, -8(r1)
1144
1145         /* Jump back to real return address */
1146         blr
1147 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1148 #endif /* CONFIG_FUNCTION_TRACER */