Pileus Git - ~andy/linux/blob - arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9
  10 #include <asm/asm-offsets.h>
  11 #include <asm/unistd.h>
  12 #include <asm/errno.h>
  13 #include <asm/page.h>
  14 #include <asm/psw.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/assembly.h>
  17 #include <asm/processor.h>
  18
  19 #include <linux/linkage.h>
  20
  21         /* We fill the empty parts of the gateway page with
  22          * something that will kill the kernel or a
  23          * userspace application.
  24          */
  25 #define KILL_INSN       break   0,0
  26
  27         .level          LEVEL
  28
  29         .text
  30
  31         .import syscall_exit,code
  32         .import syscall_exit_rfi,code
  33
  34         /* Linux gateway page is aliased to virtual page 0 in the kernel
  35          * address space. Since it is a gateway page it cannot be
  36          * dereferenced, so null pointers will still fault. We start
  37          * the actual entry point at 0x100. We put break instructions
  38          * at the beginning of the page to trap null indirect function
  39          * pointers.
  40          */
  41
  42         .align PAGE_SIZE
  43 ENTRY(linux_gateway_page)
  44
  45         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  46         .rept 44
  47         KILL_INSN
  48         .endr
  49
  50         /* ADDRESS 0xb0 to 0xb8, lws uses two insns for entry */
  51         /* Light-weight-syscall entry must always be located at 0xb0 */
  52         /* WARNING: Keep this number updated with table size changes */
  53 #define __NR_lws_entries (2)
  54
  55 lws_entry:
  56         gate    lws_start, %r0          /* increase privilege */
  57         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  58
  59         /* Fill from 0xb8 to 0xe0 */
  60         .rept 10
  61         KILL_INSN
  62         .endr
  63
  64         /* This function MUST be located at 0xe0 for glibc's threading
  65         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  66 set_thread_pointer:
  67         gate    .+8, %r0                /* increase privilege */
  68         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  69         be      0(%sr7,%r31)            /* return to user space */
  70         mtctl   %r26, %cr27             /* move arg0 to the control register */
  71
  72         /* Increase the chance of trapping if random jumps occur to this
  73         address, fill from 0xf0 to 0x100 */
  74         .rept 4
  75         KILL_INSN
  76         .endr
  77
  78 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  79         .align 256
  80 linux_gateway_entry:
  81         gate    .+8, %r0                        /* become privileged */
  82         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
  83         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
  84         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
  85         mfsp    %sr7,%r1                        /* save user sr7 */
  86         mtsp    %r1,%sr3                        /* and store it in sr3 */
  87
  88 #ifdef CONFIG_64BIT
  89         /* for now we can *always* set the W bit on entry to the syscall
  90          * since we don't support wide userland processes.  We could
  91          * also save the current SM other than in r0 and restore it on
  92          * exit from the syscall, and also use that value to know
  93          * whether to do narrow or wide syscalls. -PB
  94          */
  95         ssm     PSW_SM_W, %r1
  96         extrd,u %r1,PSW_W_BIT,1,%r1
  97         /* sp must be aligned on 4, so deposit the W bit setting into
  98          * the bottom of sp temporarily */
  99         or,ev   %r1,%r30,%r30
 100         b,n     1f
 101         /* The top halves of argument registers must be cleared on syscall
 102          * entry from narrow executable.
 103          */
 104         depdi   0, 31, 32, %r26
 105         depdi   0, 31, 32, %r25
 106         depdi   0, 31, 32, %r24
 107         depdi   0, 31, 32, %r23
 108         depdi   0, 31, 32, %r22
 109         depdi   0, 31, 32, %r21
 110 1:
 111 #endif
 112         mfctl   %cr30,%r1
 113         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 114         xor     %r1,%r30,%r1
 115         xor     %r1,%r30,%r30
 116
 117         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 118
 119         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 120          *       contains a valid kernel stack pointer. It is also
 121          *       critical that we don't start using the kernel stack
 122          *       until after sr7 has been set to 0.
 123          */
 124
 125         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 126         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 127         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 128         LDREG   TI_TASK(%r1),%r1
 129
 130         /* Save some registers for sigcontext and potential task
 131            switch (see entry.S for the details of which ones are
 132            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 133            a process is on a syscall or not.  For an interrupt the real
 134            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 135         STREG   %r0,  TASK_PT_PSW(%r1)
 136         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 137         STREG   %r19, TASK_PT_GR19(%r1)
 138
 139         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 140 #ifdef CONFIG_64BIT
 141         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 142 #if 0
 143         xor     %r19,%r2,%r2                    /* clear bottom bit */
 144         depd,z  %r19,1,1,%r19
 145         std     %r19,TASK_PT_PSW(%r1)
 146 #endif
 147 #endif
 148         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 149
 150         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 151         STREG   %r21, TASK_PT_GR21(%r1)
 152         STREG   %r22, TASK_PT_GR22(%r1)
 153         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 154         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 155         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 156         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 157         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 158         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 159         STREG   %r0, TASK_PT_ORIG_R28(%r1)      /* don't prohibit restarts */
 160         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 161         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 162
 163         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 164         save_fp %r27                            /* or potential task switch  */
 165
 166         mfctl   %cr11, %r27                     /* i.e. SAR */
 167         STREG   %r27, TASK_PT_SAR(%r1)
 168
 169         loadgp
 170
 171 #ifdef CONFIG_64BIT
 172         ldo     -16(%r30),%r29                  /* Reference param save area */
 173         copy    %r19,%r2                        /* W bit back to r2 */
 174 #else
 175         /* no need to save these on stack in wide mode because the first 8
 176          * args are passed in registers */
 177         stw     %r22, -52(%r30)                 /* 5th argument */
 178         stw     %r21, -56(%r30)                 /* 6th argument */
 179 #endif
 180
 181         /* Are we being ptraced? */
 182         mfctl   %cr30, %r1
 183         LDREG   TI_FLAGS(%r1),%r1
 184         ldi     _TIF_SYSCALL_TRACE_MASK, %r19
 185         and,COND(=) %r1, %r19, %r0
 186         b,n     .Ltracesys
 187
 188         /* Note!  We cannot use the syscall table that is mapped
 189         nearby since the gateway page is mapped execute-only. */
 190
 191 #ifdef CONFIG_64BIT
 192         ldil    L%sys_call_table, %r1
 193         or,=    %r2,%r2,%r2
 194         addil   L%(sys_call_table64-sys_call_table), %r1
 195         ldo     R%sys_call_table(%r1), %r19
 196         or,=    %r2,%r2,%r2
 197         ldo     R%sys_call_table64(%r1), %r19
 198 #else
 199         ldil    L%sys_call_table, %r1
 200         ldo     R%sys_call_table(%r1), %r19
 201 #endif
 202         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 203         b,n     .Lsyscall_nosys
 204
 205         LDREGX  %r20(%r19), %r19
 206
 207         /* If this is a sys_rt_sigreturn call, and the signal was received
 208          * when not in_syscall, then we want to return via syscall_exit_rfi,
 209          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 210          * trampoline code in signal.c).
 211          */
 212         ldi     __NR_rt_sigreturn,%r2
 213         comb,=  %r2,%r20,.Lrt_sigreturn
 214 .Lin_syscall:
 215         ldil    L%syscall_exit,%r2
 216         be      0(%sr7,%r19)
 217         ldo     R%syscall_exit(%r2),%r2
 218 .Lrt_sigreturn:
 219         comib,<> 0,%r25,.Lin_syscall
 220         ldil    L%syscall_exit_rfi,%r2
 221         be      0(%sr7,%r19)
 222         ldo     R%syscall_exit_rfi(%r2),%r2
 223
 224         /* Note!  Because we are not running where we were linked, any
 225         calls to functions external to this file must be indirect.  To
 226         be safe, we apply the opposite rule to functions within this
 227         file, with local labels given to them to ensure correctness. */
 228
 229 .Lsyscall_nosys:
 230 syscall_nosys:
 231         ldil    L%syscall_exit,%r1
 232         be      R%syscall_exit(%sr7,%r1)
 233         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 234
 235
 236 /* Warning! This trace code is a virtual duplicate of the code above so be
 237  * sure to maintain both! */
 238 .Ltracesys:
 239 tracesys:
 240         /* Need to save more registers so the debugger can see where we
 241          * are.  This saves only the lower 8 bits of PSW, so that the C
 242          * bit is still clear on syscalls, and the D bit is set if this
 243          * full register save path has been executed.  We check the D
 244          * bit on syscall_return_rfi to determine which registers to
 245          * restore.  An interrupt results in a full PSW saved with the
 246          * C bit set, a non-straced syscall entry results in C and D clear
 247          * in the saved PSW.
 248          */
 249         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 250         LDREG   TI_TASK(%r1), %r1
 251         ssm     0,%r2
 252         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 253         mfsp    %sr0,%r2
 254         STREG   %r2,TASK_PT_SR0(%r1)
 255         mfsp    %sr1,%r2
 256         STREG   %r2,TASK_PT_SR1(%r1)
 257         mfsp    %sr2,%r2
 258         STREG   %r2,TASK_PT_SR2(%r1)
 259         mfsp    %sr3,%r2
 260         STREG   %r2,TASK_PT_SR3(%r1)
 261         STREG   %r2,TASK_PT_SR4(%r1)
 262         STREG   %r2,TASK_PT_SR5(%r1)
 263         STREG   %r2,TASK_PT_SR6(%r1)
 264         STREG   %r2,TASK_PT_SR7(%r1)
 265         STREG   %r2,TASK_PT_IASQ0(%r1)
 266         STREG   %r2,TASK_PT_IASQ1(%r1)
 267         LDREG   TASK_PT_GR31(%r1),%r2
 268         STREG   %r2,TASK_PT_IAOQ0(%r1)
 269         ldo     4(%r2),%r2
 270         STREG   %r2,TASK_PT_IAOQ1(%r1)
 271         ldo     TASK_REGS(%r1),%r2
 272         /* reg_save %r2 */
 273         STREG   %r3,PT_GR3(%r2)
 274         STREG   %r4,PT_GR4(%r2)
 275         STREG   %r5,PT_GR5(%r2)
 276         STREG   %r6,PT_GR6(%r2)
 277         STREG   %r7,PT_GR7(%r2)
 278         STREG   %r8,PT_GR8(%r2)
 279         STREG   %r9,PT_GR9(%r2)
 280         STREG   %r10,PT_GR10(%r2)
 281         STREG   %r11,PT_GR11(%r2)
 282         STREG   %r12,PT_GR12(%r2)
 283         STREG   %r13,PT_GR13(%r2)
 284         STREG   %r14,PT_GR14(%r2)
 285         STREG   %r15,PT_GR15(%r2)
 286         STREG   %r16,PT_GR16(%r2)
 287         STREG   %r17,PT_GR17(%r2)
 288         STREG   %r18,PT_GR18(%r2)
 289         /* Finished saving things for the debugger */
 290
 291         copy    %r2,%r26
 292         ldil    L%do_syscall_trace_enter,%r1
 293         ldil    L%tracesys_next,%r2
 294         be      R%do_syscall_trace_enter(%sr7,%r1)
 295         ldo     R%tracesys_next(%r2),%r2
 296
 297 tracesys_next:
 298         /* do_syscall_trace_enter either returned the syscallno, or -1L,
 299          *  so we skip restoring the PT_GR20 below, since we pulled it from
 300          *  task->thread.regs.gr[20] above.
 301          */
 302         copy    %ret0,%r20
 303         ldil    L%sys_call_table,%r1
 304         ldo     R%sys_call_table(%r1), %r19
 305
 306         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 307         LDREG   TI_TASK(%r1), %r1
 308         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 309         LDREG   TASK_PT_GR25(%r1), %r25
 310         LDREG   TASK_PT_GR24(%r1), %r24
 311         LDREG   TASK_PT_GR23(%r1), %r23
 312 #ifdef CONFIG_64BIT
 313         LDREG   TASK_PT_GR22(%r1), %r22
 314         LDREG   TASK_PT_GR21(%r1), %r21
 315         ldo     -16(%r30),%r29                  /* Reference param save area */
 316 #endif
 317
 318         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 319         b,n     .Lsyscall_nosys
 320
 321         LDREGX  %r20(%r19), %r19
 322
 323         /* If this is a sys_rt_sigreturn call, and the signal was received
 324          * when not in_syscall, then we want to return via syscall_exit_rfi,
 325          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 326          * trampoline code in signal.c).
 327          */
 328         ldi     __NR_rt_sigreturn,%r2
 329         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 330 .Ltrace_in_syscall:
 331         ldil    L%tracesys_exit,%r2
 332         be      0(%sr7,%r19)
 333         ldo     R%tracesys_exit(%r2),%r2
 334
 335         /* Do *not* call this function on the gateway page, because it
 336         makes a direct call to syscall_trace. */
 337
 338 tracesys_exit:
 339         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 340         LDREG   TI_TASK(%r1), %r1
 341 #ifdef CONFIG_64BIT
 342         ldo     -16(%r30),%r29                  /* Reference param save area */
 343 #endif
 344         ldo     TASK_REGS(%r1),%r26
 345         bl      do_syscall_trace_exit,%r2
 346         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 347         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 348         LDREG   TI_TASK(%r1), %r1
 349         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 350
 351         ldil    L%syscall_exit,%r1
 352         be,n    R%syscall_exit(%sr7,%r1)
 353
 354 .Ltrace_rt_sigreturn:
 355         comib,<> 0,%r25,.Ltrace_in_syscall
 356         ldil    L%tracesys_sigexit,%r2
 357         be      0(%sr7,%r19)
 358         ldo     R%tracesys_sigexit(%r2),%r2
 359
 360 tracesys_sigexit:
 361         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 362         LDREG   TI_TASK(%r1), %r1
 363 #ifdef CONFIG_64BIT
 364         ldo     -16(%r30),%r29                  /* Reference param save area */
 365 #endif
 366         bl      do_syscall_trace_exit,%r2
 367         ldo     TASK_REGS(%r1),%r26
 368
 369         ldil    L%syscall_exit_rfi,%r1
 370         be,n    R%syscall_exit_rfi(%sr7,%r1)
 371
 372
 373         /*********************************************************
 374                 32/64-bit Light-Weight-Syscall ABI
 375
 376                 * - Indicates a hint for userspace inline asm
 377                 implementations.
 378
 379                 Syscall number (caller-saves)
 380                 - %r20
 381                 * In asm clobber.
 382
 383                 Argument registers (caller-saves)
 384                 - %r26, %r25, %r24, %r23, %r22
 385                 * In asm input.
 386
 387                 Return registers (caller-saves)
 388                 - %r28 (return), %r21 (errno)
 389                 * In asm output.
 390
 391                 Caller-saves registers
 392                 - %r1, %r27, %r29
 393                 - %r2 (return pointer)
 394                 - %r31 (ble link register)
 395                 * In asm clobber.
 396
 397                 Callee-saves registers
 398                 - %r3-%r18
 399                 - %r30 (stack pointer)
 400                 * Not in asm clobber.
 401
 402                 If userspace is 32-bit:
 403                 Callee-saves registers
 404                 - %r19 (32-bit PIC register)
 405
 406                 Differences from 32-bit calling convention:
 407                 - Syscall number in %r20
 408                 - Additional argument register %r22 (arg4)
 409                 - Callee-saves %r19.
 410
 411                 If userspace is 64-bit:
 412                 Callee-saves registers
 413                 - %r27 (64-bit PIC register)
 414
 415                 Differences from 64-bit calling convention:
 416                 - Syscall number in %r20
 417                 - Additional argument register %r22 (arg4)
 418                 - Callee-saves %r27.
 419
 420                 Error codes returned by entry path:
 421
 422                 ENOSYS - r20 was an invalid LWS number.
 423
 424         *********************************************************/
 425 lws_start:
 426
 427 #ifdef CONFIG_64BIT
 428         /* FIXME: If we are a 64-bit kernel just
 429          *        turn this on unconditionally.
 430          */
 431         ssm     PSW_SM_W, %r1
 432         extrd,u %r1,PSW_W_BIT,1,%r1
 433         /* sp must be aligned on 4, so deposit the W bit setting into
 434          * the bottom of sp temporarily */
 435         or,ev   %r1,%r30,%r30
 436
 437         /* Clip LWS number to a 32-bit value always */
 438         depdi   0, 31, 32, %r20
 439 #endif
 440
 441         /* Is the lws entry number valid? */
 442         comiclr,>>      __NR_lws_entries, %r20, %r0
 443         b,n     lws_exit_nosys
 444
 445         /* WARNING: Trashing sr2 and sr3 */
 446         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 447         mtsp    %r1,%sr3
 448         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 449
 450         /* Load table start */
 451         ldil    L%lws_table, %r1
 452         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 453         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 454
 455         /* Jump to lws, lws table pointers already relocated */
 456         be,n    0(%sr2,%r21)
 457
 458 lws_exit_nosys:
 459         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 460         /* Fall through: Return to userspace */
 461
 462 lws_exit:
 463 #ifdef CONFIG_64BIT
 464         /* decide whether to reset the wide mode bit
 465          *
 466          * For a syscall, the W bit is stored in the lowest bit
 467          * of sp.  Extract it and reset W if it is zero */
 468         extrd,u,*<>     %r30,63,1,%r1
 469         rsm     PSW_SM_W, %r0
 470         /* now reset the lowest bit of sp if it was set */
 471         xor     %r30,%r1,%r30
 472 #endif
 473         be,n    0(%sr7, %r31)
 474
 475
 476
 477         /***************************************************
 478                 Implementing CAS as an atomic operation:
 479
 480                 %r26 - Address to examine
 481                 %r25 - Old value to check (old)
 482                 %r24 - New value to set (new)
 483                 %r28 - Return prev through this register.
 484                 %r21 - Kernel error code
 485
 486                 If debugging is DISabled:
 487
 488                 %r21 has the following meanings:
 489
 490                 EAGAIN - CAS is busy, ldcw failed, try again.
 491                 EFAULT - Read or write failed.
 492
 493                 If debugging is enabled:
 494
 495                 EDEADLOCK - CAS called recursively.
 496                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 497                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 498                 EFAULT - Read or write failed.
 499
 500                 Scratch: r20, r28, r1
 501
 502         ****************************************************/
 503
 504         /* Do not enable LWS debugging */
 505 #define ENABLE_LWS_DEBUG 0
 506
 507         /* ELF64 Process entry path */
 508 lws_compare_and_swap64:
 509 #ifdef CONFIG_64BIT
 510         b,n     lws_compare_and_swap
 511 #else
 512         /* If we are not a 64-bit kernel, then we don't
 513          * have 64-bit input registers, and calling
 514          * the 64-bit LWS CAS returns ENOSYS.
 515          */
 516         b,n     lws_exit_nosys
 517 #endif
 518
 519         /* ELF32 Process entry path */
 520 lws_compare_and_swap32:
 521 #ifdef CONFIG_64BIT
 522         /* Clip all the input registers */
 523         depdi   0, 31, 32, %r26
 524         depdi   0, 31, 32, %r25
 525         depdi   0, 31, 32, %r24
 526 #endif
 527
 528 lws_compare_and_swap:
 529         /* Load start of lock table */
 530         ldil    L%lws_lock_start, %r20
 531         ldo     R%lws_lock_start(%r20), %r28
 532
 533         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 534         extru  %r26, 27, 4, %r20
 535
 536         /* Find lock to use, the hash is either one of 0 to
 537            15, multiplied by 16 (keep it 16-byte aligned)
 538            and add to the lock table offset. */
 539         shlw    %r20, 4, %r20
 540         add     %r20, %r28, %r20
 541
 542 # if ENABLE_LWS_DEBUG
 543         /*
 544                 DEBUG, check for deadlock!
 545                 If the thread register values are the same
 546                 then we were the one that locked it last and
 547                 this is a recurisve call that will deadlock.
 548                 We *must* giveup this call and fail.
 549         */
 550         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 551         /* WARNING: If cr27 cycles to the same value we have problems */
 552         mfctl   %cr27, %r21                             /* Get current thread register */
 553         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 554         b       lws_exit                                /* Return error! */
 555         ldo     -EDEADLOCK(%r0), %r21
 556 cas_lock:
 557         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 558         ldo     1(%r0), %r28                            /* 1st case */
 559         b       lws_exit                                /* Contended... */
 560         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 561 cas_nocontend:
 562 # endif
 563 /* ENABLE_LWS_DEBUG */
 564
 565         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 566         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 567 cas_wouldblock:
 568         ldo     2(%r0), %r28                            /* 2nd case */
 569         b       lws_exit                                /* Contended... */
 570         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 571
 572         /*
 573                 prev = *addr;
 574                 if ( prev == old )
 575                   *addr = new;
 576                 return prev;
 577         */
 578
 579         /* NOTES:
 580                 This all works becuse intr_do_signal
 581                 and schedule both check the return iasq
 582                 and see that we are on the kernel page
 583                 so this process is never scheduled off
 584                 or is ever sent any signal of any sort,
 585                 thus it is wholly atomic from usrspaces
 586                 perspective
 587         */
 588 cas_action:
 589 #if defined CONFIG_SMP && ENABLE_LWS_DEBUG
 590         /* DEBUG */
 591         mfctl   %cr27, %r1
 592         stw     %r1, 4(%sr2,%r20)
 593 #endif
 594         /* The load and store could fail */
 595 1:      ldw     0(%sr3,%r26), %r28
 596         sub,<>  %r28, %r25, %r0
 597 2:      stw     %r24, 0(%sr3,%r26)
 598         /* Free lock */
 599         stw     %r20, 0(%sr2,%r20)
 600 #if ENABLE_LWS_DEBUG
 601         /* Clear thread register indicator */
 602         stw     %r0, 4(%sr2,%r20)
 603 #endif
 604         /* Return to userspace, set no error */
 605         b       lws_exit
 606         copy    %r0, %r21
 607
 608 3:
 609         /* Error occurred on load or store */
 610         /* Free lock */
 611         stw     %r20, 0(%sr2,%r20)
 612 #if ENABLE_LWS_DEBUG
 613         stw     %r0, 4(%sr2,%r20)
 614 #endif
 615         b       lws_exit
 616         ldo     -EFAULT(%r0),%r21       /* set errno */
 617         nop
 618         nop
 619         nop
 620         nop
 621
 622         /* Two exception table entries, one for the load,
 623            the other for the store. Either return -EFAULT.
 624            Each of the entries must be relocated. */
 625         .section __ex_table,"aw"
 626         ASM_ULONG_INSN (1b - linux_gateway_page), (3b - linux_gateway_page)
 627         ASM_ULONG_INSN (2b - linux_gateway_page), (3b - linux_gateway_page)
 628         .previous
 629
 630
 631         /* Make sure nothing else is placed on this page */
 632         .align PAGE_SIZE
 633 END(linux_gateway_page)
 634 ENTRY(end_linux_gateway_page)
 635
 636         /* Relocate symbols assuming linux_gateway_page is mapped
 637            to virtual address 0x0 */
 638
 639 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 640
 641         .section .rodata,"a"
 642
 643         .align PAGE_SIZE
 644         /* Light-weight-syscall table */
 645         /* Start of lws table. */
 646 ENTRY(lws_table)
 647         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 648         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 649 END(lws_table)
 650         /* End of lws table */
 651
 652         .align PAGE_SIZE
 653 ENTRY(sys_call_table)
 654 #include "syscall_table.S"
 655 END(sys_call_table)
 656
 657 #ifdef CONFIG_64BIT
 658         .align PAGE_SIZE
 659 ENTRY(sys_call_table64)
 660 #define SYSCALL_TABLE_64BIT
 661 #include "syscall_table.S"
 662 END(sys_call_table64)
 663 #endif
 664
 665         /*
 666                 All light-weight-syscall atomic operations
 667                 will use this set of locks
 668
 669                 NOTE: The lws_lock_start symbol must be
 670                 at least 16-byte aligned for safe use
 671                 with ldcw.
 672         */
 673         .section .data
 674         .align  PAGE_SIZE
 675 ENTRY(lws_lock_start)
 676         /* lws locks */
 677         .rept 16
 678         /* Keep locks aligned at 16-bytes */
 679         .word 1
 680         .word 0
 681         .word 0
 682         .word 0
 683         .endr
 684 END(lws_lock_start)
 685         .previous
 686
 687 .end
 688
 689