Pileus Git - ~andy/linux/blob - arch/arm/mach-tegra/sleep-tegra20.S

   1 /*
   2  * Copyright (c) 2010-2012, NVIDIA Corporation. All rights reserved.
   3  * Copyright (c) 2011, Google, Inc.
   4  *
   5  * Author: Colin Cross <ccross@android.com>
   6  *         Gary King <gking@nvidia.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify it
   9  * under the terms and conditions of the GNU General Public License,
  10  * version 2, as published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  15  * more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/linkage.h>
  22
  23 #include <asm/assembler.h>
  24
  25 #include "sleep.h"
  26 #include "flowctrl.h"
  27
  28 #if defined(CONFIG_HOTPLUG_CPU) || defined(CONFIG_PM_SLEEP)
  29 /*
  30  * tegra20_hotplug_shutdown(void)
  31  *
  32  * puts the current cpu in reset
  33  * should never return
  34  */
  35 ENTRY(tegra20_hotplug_shutdown)
  36         /* Put this CPU down */
  37         cpu_id  r0
  38         bl      tegra20_cpu_shutdown
  39         mov     pc, lr                  @ should never get here
  40 ENDPROC(tegra20_hotplug_shutdown)
  41
  42 /*
  43  * tegra20_cpu_shutdown(int cpu)
  44  *
  45  * r0 is cpu to reset
  46  *
  47  * puts the specified CPU in wait-for-event mode on the flow controller
  48  * and puts the CPU in reset
  49  * can be called on the current cpu or another cpu
  50  * if called on the current cpu, does not return
  51  * MUST NOT BE CALLED FOR CPU 0.
  52  *
  53  * corrupts r0-r3, r12
  54  */
  55 ENTRY(tegra20_cpu_shutdown)
  56         cmp     r0, #0
  57         moveq   pc, lr                  @ must not be called for CPU 0
  58
  59         cpu_to_halt_reg r1, r0
  60         ldr     r3, =TEGRA_FLOW_CTRL_VIRT
  61         mov     r2, #FLOW_CTRL_WAITEVENT | FLOW_CTRL_JTAG_RESUME
  62         str     r2, [r3, r1]            @ put flow controller in wait event mode
  63         ldr     r2, [r3, r1]
  64         isb
  65         dsb
  66         movw    r1, 0x1011
  67         mov     r1, r1, lsl r0
  68         ldr     r3, =TEGRA_CLK_RESET_VIRT
  69         str     r1, [r3, #0x340]        @ put slave CPU in reset
  70         isb
  71         dsb
  72         cpu_id  r3
  73         cmp     r3, r0
  74         beq     .
  75         mov     pc, lr
  76 ENDPROC(tegra20_cpu_shutdown)
  77 #endif