Pileus Git - ~andy/sunrise/blob - app-text/debiandoc-sgml/debiandoc-sgml-1.2.27.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="5"
   6
   7 inherit perl-module sgml-catalog
   8
   9 DESCRIPTION="DebianDoc SGML DTD and formatting tools"
  10 HOMEPAGE="http://packages.qa.debian.org/debiandoc-sgml"
  11 SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.gz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="cjk"
  17
  18 RDEPEND="app-text/openjade
  19         dev-lang/perl
  20         dev-libs/xml-core
  21         dev-perl/HTML-Parser
  22         dev-perl/Roman
  23         dev-perl/SGMLSpm
  24         dev-perl/Text-Format
  25         dev-perl/URI
  26         virtual/perl-i18n-langtags
  27         cjk? ( dev-tex/cjk-latex )"
  28
  29 sgml-catalog_cat_include "/etc/sgml/${P}.cat" \
  30         "/usr/share/sgml/debiandoc/dtd/sgml/1.0/catalog"
  31 sgml-catalog_cat_include "/etc/sgml/${P}.cat" \
  32         "/usr/share/sgml/debiandoc/entities/catalog"
  33
  34 pkg_pretend() {
  35         if [[ "${LINGUAS}" == *"zh_TW"* ]] && ! use cjk; then
  36                 ewarn "To have proper support for zh_TW in LINGUAS,"
  37                 ewarn "You should enable the cjk USE flag for this package."
  38         fi
  39 }
  40
  41 src_prepare() {
  42         perl-module_src_prep
  43         sed -e "s#\$(pkg_format_dir) \$(pkg_bin_dir)#${VENDOR_LIB}/DebianDoc_SGML/Format /usr/share/\$(pkg_name)#" \
  44                 -i Makefile || die
  45 }
  46
  47 src_compile() {
  48         emake prefix="${D}"/usr perl_dir="${D}${VENDOR_LIB}"
  49 }
  50
  51 src_install() {
  52         emake prefix="${D}"/usr perl_dir="${D}${VENDOR_LIB}" install
  53 }