Pileus Git - ~andy/sunrise/blob - app-office/pyroom/pyroom-0.4.1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=4
   6 # written for 2.6, works on 2.7 as well
   7 PYTHON_DEPEND="2:2.6"
   8 SUPPORT_PYTHON_ABIS="1"
   9 RESTRICT_PYTHON_ABIS="2.5 3.*"
  10 PYTHON_MODNAME="PyRoom"
  11
  12 inherit distutils versionator
  13
  14 MY_PV=$(get_version_component_range 1-2)
  15
  16 DESCRIPTION="A minimal word processor that lets you focus on writing"
  17 HOMEPAGE="http://www.pyroom.org/"
  18 SRC_URI="http://launchpad.net/${PN}/${MY_PV}/${PV}/+download/${P}.tar.gz"
  19
  20 LICENSE="GPL-3"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~x86"
  23 IUSE="gnome"
  24
  25 RDEPEND="dev-python/pygobject:2
  26         dev-python/pygtk:2
  27         dev-python/pyxdg
  28         gnome? ( dev-python/gconf-python:2 )"
  29 DEPEND="sys-devel/gettext"
  30
  31 DOCS="AUTHORS CHANGELOG"
  32
  33 LANGS="ar bg br ca cy da de el en_GB eo es eu fi fr ga gu hr hu id it
  34 ja ku lt lv mk nb nl nn pl pt pt_BR ro ru sco sk sl sr sv tr zh_CN"
  35 for l in ${LANGS}; do
  36         IUSE="$IUSE linguas_${l}"
  37 done
  38 unset l
  39
  40 src_prepare() {
  41         distutils_src_prepare
  42
  43         # build system does not filter translations
  44         local l
  45         for l in ${LANGS} ; do
  46                 if ! use linguas_${l} ; then
  47                         rm locales/${PN}-${l}.po || die
  48                 fi
  49         done
  50
  51         # fix icon-destination
  52         sed -i -e \
  53                 "/${PN}.png/s:/usr/share/${PN}:/usr/share/pixmaps/:" \
  54                 setup.py || die
  55
  56         # fix .desktop file
  57         sed -i -e \
  58                 "/Icon/s:/usr/share/${PN}:/usr/share/pixmaps:" \
  59                 ${PN}.desktop || die
  60 }
  61
  62 src_install() {
  63         distutils_src_install
  64         doman ${PN}.1
  65 }
  66
  67 pkg_postinst() {
  68         distutils_pkg_postinst
  69
  70         elog "If you get an Error like"
  71         elog "\"AttributeError: 'list' object has no attribute 'encode'\""
  72         elog "you need to create a startup-script like the following:"
  73         elog ""
  74         elog "#!/bin/sh"
  75         elog "#Script for starting PyRoom"
  76         elog "unset LANGUAGE"
  77         elog "${PN}"
  78 }